Perlのハッシュに2次元配列を格納するにはどうすればよいですか？

Question

私はperlのオブジェクトを苦労しており、2D配列を作成してオブジェクトのハッシュフィールドに保存しようとしています。 2D配列を作成するには配列への参照の配列が必要であることを理解していますが、それを行おうとするとこのエラーが発生します：プッシュするarg 1のタイプは配列（ハッシュ要素ではない）でなければなりませんコンストラクターは正常に動作し、 set_seqs は正常に動作しますが、 create_matrix サブはこれらのエラーをスローします。

これは私がやっていることです：

sub new {
    my ($class) = @_;
    my $self = {};
    $self->{seq1} = undef;
    $self->{seq2} = undef;
    $self->{matrix} = ();
    bless($self, $class);
    return $self;
}
sub set_seqs {
    my $self = shift;
    $self->{seq1} = shift;
    $self->{seq2} = shift;
    print $self->{seq1};
}

sub create_matrix {
    my $self = shift;
    $self->set_seqs(shift, shift);
    #create the 2d array of scores
    #to create a matrix:
    #create a 2d array of length [lengthofseq1][lengthofseq2]
    for (my $i = 0; $i < length($self->{seq1}) - 1; $i++) {
        #push a new array reference onto the matrix
        #this line generates the error
        push(@$self->{matrix}, []);
    }
}

間違っていることについて何か考えがありますか？

Answer 1

$ selfを間接参照すると、余分なブレースが欠落しています。 push @ {$ self-＆gt; {matrix}}、[] を試してください。

疑わしい場合（複雑なデータ構造で正しい値を参照しているかどうかわからない場合）、ブレースを追加します。 :) perldoc perlreftut を参照してください。

Answer 2

Perlは、表現力豊かな 言語です。以下のステートメントですべてを行うことができます。

$self->{matrix} = [ map { [ (0) x $seq2 ] } 1..$seq1 ];

これはゴルフですか？たぶん、しかし、それはまた巧妙な push プロトタイプをいじるのを避けます。以下のステートメントを分解します。

$self->{matrix} = [     # we want an array reference
    map {               # create a derivative list from the list you will pass it
        [ (0) x $seq2 ] # another array reference, using the *repeat* operator 
                        # in it's list form, thus creating a list of 0's as 
                        # long as the value given by $seq2, to fill out the  
                        # reference's values.
   } 
   1..$seq1             # we're not using the indexes as anything more than  
                        # control, so, use them base-1.
];                       # a completed array of arrays.

テーブルを作成する標準サブルーチンがあります：

sub make_matrix { 
    my ( $dim1, $dim2 ) = @_;
    my @table = map { [ ( 0 ) x $dim2 ] } 1..$dim1;
    return wantarray? @table : \@table;
}

そして、より一般化された配列の配列関数があります：

sub multidimensional_array { 
    my $dim = shift;
    return [ ( 0 ) x $dim ] unless @_; # edge case

    my @table = map { scalar multidimensional_array( @_ ) } 1..$dim;
    return wantarray ? @table : \@table;
}

Answer 3

sub create_matrix {
    my($self,$seq1,$seq2) = @_;
    $self->set_seqs($seq2, $seq2);

    #create the 2d array of scores
    #to create a matrix:
    #create a 2d array of length [$seq1][$seq2]
    for( 1..$seq1 ){
        push @{$self->{matrix}}, [ (undef) x $seq2 ];
    }
}