XSLTを使用して2つのXMLから希望のXML OUPUTを取得する方法
質問
XSLTとXMLを使用しています。
最初に2つのXMLで作業するつもりです。
最初のXML:
<?xml version="1.0"?>
<tcm:ListItems xmlns:tcm="http://www.tridion.com/ContentManager/5.0" ID="tcm:232-83752-2" Managed="10682">
<tcm:Item ID="tcm:232-564598" Title="010 News Mapping"/>
<tcm:Item ID="tcm:232-564599" Title="020 CUGOs"/>
<tcm:Item ID="tcm:232-614307" Title="030 Reserved Urls"/>
</tcm:ListItems>
2番目のXML 上記のID IE TCM:232-564598などを使用して取得します。以下は、ID TCMのXMLの1つであり、他のIDは同じタイプのXMLを搭載します。
<tcm:Component ID="tcm:229-564598" IsEditable="false" xmlns:tcm="http://www.tridion.com/ContentManager/5.0" xmlns:xlink="http://www.w3.org/1999/xlink">
<tcm:Data>
<tcm:Content>
<MappingCollection xmlns="uuid:922EEC29-2DE3-4BA1-A46A-A300CB8FA85F">
<VanityUrl>
<old>mbp</old>
<new>/SessionHandler.aspx?pageurl=/BP.aspx&pub=/english&section=IBE&j=f</new>
<dateAdded>2010-05-03T14:45:00</dateAdded>
<comments> News mapping </comments>
</VanityUrl>
<VanityUrl>
<old>about/news</old>
<new>about/news/news.aspx</new>
<dateAdded>2010-05-03T14:45:00</dateAdded>
<comments> News mapping </comments>
</VanityUrl>
</MappingCollection>
</tcm:Content>
</tcm:Data>
</tcm:Component>
両方のXMLを上に使用してXMLを以下で取得しようとしています。
<?xml version="1.0" encoding="UTF-8"?>
<mappings>
<!-- News mapping -->
<mapping old="mbp" new="/SessionHandler.aspx?pageurl=/BP.aspx&pub=/english&section=IBE&j=f"/>
<mapping old="about/news" new="about/news/news.aspx"/>
<!-- CUGO's-->
<mapping old="/nhs" new="/cugo.aspx?promoCode=UKNHS01&pub=/uk/english"/>
<mapping old="/hk/ukstudentfare" new="/cugo.aspx?promoCode=HKSTU10&pub=/hk/Chinese"/>
</mappings>
そして、これが私が上記の形式XMLを生成しようとしている私のXSLTですが、それは私のためには機能していません。最初のXMLはプライマリXMLで、XSLT以下を使用して変換されます
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform" xmlns:tcm="http://www.tridion.com/ContentManager/5.0" xmlns:xlink="http://www.w3.org/1999/xlink" xmlns:em="http://www.espire.com/tridion/schemas" xmlns:tcmse="http://www.tridion.com/ContentManager/5.1/TcmScriptAssistant" exclude-result-prefixes="em xlink tcmse tcm">
<xsl:output method="xml" version="1.0" encoding="UTF-16" indent="yes"/>
<!-- root match-->
<xsl:template match="tcm:ListItems">
<mappings>
<xsl:apply-templates select="tcm:Item"/>
</mappings>
</xsl:template>
<xsl:template match="tcm:Item">
<xsl:variable name="doc" select="document(@ID)"/>
<xsl:if test="$doc/tcm:Component/tcm:Data/tcm:Content/em:MappingCollection/em:VanityUrl/em:comments">
<xsl:comment>
<xsl:value-of select="$doc/tcm:Component/tcm:Data/tcm:Content/em:MappingCollection/em:VanityUrl/em:comments"/>
</xsl:comment>
</xsl:if>
<xsl:for-each select="$doc/tcm:Component/tcm:Data/tcm:Content/em:MappingCollection/em:VanityUrl">
<xsl:element name="mapping">
<xsl:if test="$doc/tcm:Component/tcm:Data/tcm:Content/em:MappingCollection/em:VanityUrl/em:old">
<xsl:attribute name="old">
<xsl:value-of select="$doc/tcm:Component/tcm:Data/tcm:Content/em:MappingCollection/em:VanityUrl/em:old"/>
</xsl:attribute>
</xsl:if>
<xsl:if test="$doc/tcm:Component/tcm:Data/tcm:Content/em:MappingCollection/em:VanityUrl/em:new">
<xsl:attribute name="new">
<xsl:value-of select="$doc/tcm:Component/tcm:Data/tcm:Content/em:MappingCollection/em:VanityUrl/em:new"/>
</xsl:attribute>
</xsl:if>
<xsl:if test="$doc/tcm:Component/tcm:Data/tcm:Content/em:MappingCollection/em:VanityUrl/em:dateAdded">
<xsl:attribute name="dateAdded">
<xsl:value-of select="$doc/tcm:Component/tcm:Data/tcm:Content/em:MappingCollection/em:VanityUrl/em:dateAdded"/>
</xsl:attribute>
</xsl:if>
</xsl:element>
</xsl:for-each>
</xsl:template>
</xsl:stylesheet>
XSLTの上では、データループも正しく進んでいますが、来ているデータは同じです。ループが正しいことを意味しますが、ノード値は同じです
提案してください!
解決
このスタイルシート:
<xsl:stylesheet version="1.0"
xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
xmlns:ns="uuid:922EEC29-2DE3-4BA1-A46A-A300CB8FA85F"
xmlns:tcm="http://www.tridion.com/ContentManager/5.0"
xmlns:msxsl="urn:schemas-microsoft-com:xslt"
exclude-result-prefixes="ns tcm msxsl">
<xsl:strip-space elements="*"/>
<xsl:key name="kVanityByComment" match="ns:VanityUrl" use="ns:comments"/>
<xsl:template match="/">
<xsl:variable name="vSourcesRTF">
<xsl:copy-of select="document(tcm:ListItems/tcm:Item/@ID)"/>
</xsl:variable>
<mappings>
<xsl:apply-templates select="msxsl:node-set($vSourcesRTF)/node()"/>
</mappings>
</xsl:template>
<xsl:template match="ns:VanityUrl"/>
<xsl:template match="ns:VanityUrl[generate-id()=
generate-id(key('kVanityByComment',
ns:comments)[1])]">
<xsl:comment>
<xsl:value-of select="ns:comments"/>
</xsl:comment>
<xsl:apply-templates select="key('kVanityByComment',
ns:comments)"
mode="output"/>
</xsl:template>
<xsl:template match="ns:VanityUrl" mode="output">
<mapping>
<xsl:apply-templates/>
</mapping>
</xsl:template>
<xsl:template match="ns:VanityUrl/ns:comments" priority="1"/>
<xsl:template match="ns:VanityUrl/*">
<xsl:attribute name="{local-name()}">
<xsl:value-of select="."/>
</xsl:attribute>
</xsl:template>
</xsl:stylesheet>
この入力で:
<tcm:ListItems xmlns:tcm="http://www.tridion.com/ContentManager/5.0" ID="tcm:232-83752-2" Managed="10682">
<tcm:Item ID="229-564598" Title="010 News Mapping"/>
<tcm:Item ID="229-564598" Title="020 CUGOs"/>
<tcm:Item ID="229-564598" Title="030 Reserved Urls"/>
</tcm:ListItems>
とこの外部ソース 229-564598
URI:
<tcm:Component ID="tcm:229-564598" IsEditable="false" xmlns:tcm="http://www.tridion.com/ContentManager/5.0" xmlns:xlink="http://www.w3.org/1999/xlink">
<tcm:Data>
<tcm:Content>
<MappingCollection xmlns="uuid:922EEC29-2DE3-4BA1-A46A-A300CB8FA85F">
<VanityUrl>
<old>mbp</old>
<new>/SessionHandler.aspx?pageurl=/BP.aspx&pub=/english&section=IBE&j=f</new>
<dateAdded>2010-05-03T14:45:00</dateAdded>
<comments> News mapping </comments>
</VanityUrl>
<VanityUrl>
<old>about/news</old>
<new>about/news/news.aspx</new>
<dateAdded>2010-05-03T14:45:00</dateAdded>
<comments> News mapping </comments>
</VanityUrl>
</MappingCollection>
</tcm:Content>
</tcm:Data>
</tcm:Component>
出力:
<mappings>
<!-- News mapping -->
<mapping old="mbp"
new="/SessionHandler.aspx?pageurl=/BP.aspx&pub=/english&section=IBE&j=f"
dateAdded="2010-05-03T14:45:00"></mapping>
<mapping old="about/news"
new="about/news/news.aspx"
dateAdded="2010-05-03T14:45:00"></mapping>
</mappings>
編集: :複数の入力ソース。
他のヒント
はい、あなたが行った変更は確かに重要です。 :-)
それぞれのループが行うことは、それぞれを選択することです <em:VanityUrl>
Xpath式に一致する要素は、その要素を務める内部の内部のコンテキストノードにします( レンプレート ではありませんが <xsl:template>
)、その後、新しいコンテキストノードでその内部テンプレートをインスタンス化します。
for-for-for-loopの内部で「$ doc/...」を使用し続けていたとき、あなたはコンテキストノードを捨てていたので、それは効果がありませんでした(n回を繰り返すことを除く)。
あなたの <xsl:if test="$doc/...">
ステートメントは、そのようなノードがあるかどうかを評価していました ドキュメント全体で コンテキスト要素の下ではなく <em:VanityUrl>
.
<xsl:value-of>
ステートメントは、選択したノードセットの最初のノードのみに注意を払い、常にから値を取得していました 最初 <em:VanityUrl>
, 、コンテキストノードに関係なく。
コンテキストノードに対する選択とテストを開始したとき:
<xsl:if test="em:old">
すべてが良くなりました。 :-)
あなたは貴重な入力を求めました。文体的な理由から、あなたはあなたを交換したいかもしれません <xsl:if>
でテスト <xsl:apply-templates>
. 。 (1つは@dimitre novatchevを幸せにすることです。:-)
<xsl:if test="$doc/tcm:Component/tcm:Data/tcm:Content/em:MappingCollection/em:VanityUrl/em:comments">
<xsl:comment>
<xsl:value-of select="$doc/tcm:Component/tcm:Data/tcm:Content/em:MappingCollection/em:VanityUrl/em:comments"/>
</xsl:comment>
</xsl:if>
なります
<xsl:apply-templates select="$doc/tcm:Component/tcm:Data/tcm:Content/em:MappingCollection/em:VanityUrl/em:comments" />
そして、それらには別のテンプレートが必要です。
<xsl:template match="em:comments">
<xsl:comment>
<xsl:value-of select="."/>
</xsl:comment>
</xsl:template>
それを行うことにはいくつかの利点があります。最大のものは、その長いXPath式を複製する必要がないことです。これは、式を変更する必要がある場合にエラーが発生しやすいことです。 em:コメント要素がない場合、Apply-Templatesは何もしませんので、コメントは発生しません。
また、StyleSheetをモジュール化するため、EM:コメントのレンダリング方法を変更することができます。 EM:コメントは1つの場所で発生する単純なXMLドキュメントではそれほど重要ではないかもしれませんが、XSLTのパワーを最大限に活用するスタイルです。また、この変更されたバージョンは、複数のEMがある場合、複数のコメントを出力することに注意してください。コメントは、バージョンではありません。繰り返しますが、おそらく入力に倍数がないので、それは問題ではないかもしれません。
同様に、出力属性について:
<xsl:if test="em:old">
<xsl:attribute name="old">
<xsl:value-of select="em:old"/>
</xsl:attribute>
</xsl:if>
になることができる
<xsl:apply-templates select="em:old[1]" />
別のテンプレート付き
<xsl:template match="em:old">
<xsl:attribute name="old">
<xsl:value-of select="."/>
</xsl:attribute>
</xsl:template>
注意してください [1]
, 、複数の出力を試みないようにします old="..."
入力em:vanityurlが複数のem:古い要素を持っている場合、同じ要素の属性。これにより、スタイルシートがエラーを引き起こすことになります。しかし、多分あなた 欲しいです その場合にエラーを上げるため。もしそうなら、あなたはおそらくあなたの入力XMLをすでに検証しているでしょう。
実際、3つの属性すべてに適用するために、ここでアプリケーションとテンプレートを一般化することができます。
<xsl:apply-templates select="em:old[1] | em:new[1] | em:dateAdded[1]" />
繰り返しますが、これらの要素のいずれかが存在しない場合、それらのために何も行われません(空の属性は生成されません)。テンプレート:
<xsl:template match="em:old | em:new | em:dateAdded">
<xsl:attribute name="{local-name()}">
<xsl:value-of select="."/>
</xsl:attribute>
</xsl:template>
local-name()
名前空間プレフィックスなしで、要素の名前を教えてください。
アップデート:
それを処理する別の方法は、モードを使用することです。
<xsl:apply-templates select="em:old[1] | em:new[1] | em:dateAdded[1]"
mode="make-attribute" />
<xsl:template match="em:*" mode="make-attribute">
<xsl:attribute name="{local-name()}">
<xsl:value-of select="."/>
</xsl:attribute>
</xsl:template>
次に、Make-Attributeテンプレートをどこからでも使用でき、属性を作成する可能性のあるすべての要素に一致するように、マッチパターンを更新する必要はありません。
私が言う他の唯一のことは、上記の名前空間の使用が混乱しているということです...それはそのまま働くべきではありません。たとえば、StyleSheetは、VanityUrlのような要素にこの名前空間URIを使用しています。
"http://www.espire.com/tridion/schemas"
ただし、2番目の入力ドキュメントでは、これらの要素にこの名前空間URIを使用しています。
"uuid:922EEC29-2DE3-4BA1-A46A-A300CB8FA85F"
名前空間のプレフィックスが異なることは関係ありません( "em:" vs. default)が、名前空間URIは一致する必要があります。 Vanityurlの名前空間URIが変更されたに違いないと思います。
hth!
あなたもこれを試すことができます!!
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform" xmlns:tcm="http://www.tridion.com/ContentManager/5.0" xmlns:xlink="http://www.w3.org/1999/xlink" xmlns:em="http://www.espire.com/tridion/schemas" xmlns:tcmse="http://www.tridion.com/ContentManager/5.1/TcmScriptAssistant" exclude-result-prefixes="em xlink tcmse tcm">
<xsl:output method="xml" version="1.0" encoding="UTF-16" indent="yes"/>
<!-- root match-->
<xsl:template match="tcm:ListItems">
<mappings>
<xsl:apply-templates select="tcm:Item"/>
</mappings>
</xsl:template>
<xsl:template match="tcm:Item">
<xsl:variable name="doc" select="document(@ID)"/>
<xsl:if test="$doc/tcm:Component/tcm:Data/tcm:Content/em:MappingCollection/em:VanityUrl/em:comments">
<xsl:comment>
<xsl:value-of select="$doc/tcm:Component/tcm:Data/tcm:Content/em:MappingCollection/em:VanityUrl/em:comments"/>
</xsl:comment>
</xsl:if>
<xsl:for-each select="$doc/tcm:Component/tcm:Data/tcm:Content/em:MappingCollection/em:VanityUrl">
<xsl:element name="mapping">
<xsl:if test="em:old">
<xsl:attribute name="old">
<xsl:value-of select="em:old"/>
</xsl:attribute>
</xsl:if>
<xsl:if test="em:new">
<xsl:attribute name="new">
<xsl:value-of select="em:new"/>
</xsl:attribute>
</xsl:if>
<xsl:if test="em:dateAdded">
<xsl:attribute name="dateAdded">
<xsl:value-of select="em:dateAdded"/>
</xsl:attribute>
</xsl:if>
</xsl:element>
</xsl:for-each>
</xsl:template>
</xsl:stylesheet>