How to get desired XML ouput from two XMLs using XSLT
https://stackoverflow.com/questions/4084884
italiano
english
français
española
中国
日本の
العربية
Deutsch
한국어
Português
RussianPergunta
I am using XSLT and XML.
First thing I am going to work on two xml.
First XML:
<?xml version="1.0"?>
<tcm:ListItems xmlns:tcm="http://www.tridion.com/ContentManager/5.0" ID="tcm:232-83752-2" Managed="10682">
<tcm:Item ID="tcm:232-564598" Title="010 News Mapping"/>
<tcm:Item ID="tcm:232-564599" Title="020 CUGOs"/>
<tcm:Item ID="tcm:232-614307" Title="030 Reserved Urls"/>
</tcm:ListItems>
The Second XML we will get it using above ID i.e. tcm:232-564598 etc, below is one of the xml for ID tcm:232-564598 and other IDs will be having same type of XML.
<tcm:Component ID="tcm:229-564598" IsEditable="false" xmlns:tcm="http://www.tridion.com/ContentManager/5.0" xmlns:xlink="http://www.w3.org/1999/xlink">
<tcm:Data>
<tcm:Content>
<MappingCollection xmlns="uuid:922EEC29-2DE3-4BA1-A46A-A300CB8FA85F">
<VanityUrl>
<old>mbp</old>
<new>/SessionHandler.aspx?pageurl=/BP.aspx&pub=/english&section=IBE&j=f</new>
<dateAdded>2010-05-03T14:45:00</dateAdded>
<comments> News mapping </comments>
</VanityUrl>
<VanityUrl>
<old>about/news</old>
<new>about/news/news.aspx</new>
<dateAdded>2010-05-03T14:45:00</dateAdded>
<comments> News mapping </comments>
</VanityUrl>
</MappingCollection>
</tcm:Content>
</tcm:Data>
</tcm:Component>
I trying to get below format XML using above both XMLs.
<?xml version="1.0" encoding="UTF-8"?>
<mappings>
<!-- News mapping -->
<mapping old="mbp" new="/SessionHandler.aspx?pageurl=/BP.aspx&pub=/english&section=IBE&j=f"/>
<mapping old="about/news" new="about/news/news.aspx"/>
<!-- CUGO's-->
<mapping old="/nhs" new="/cugo.aspx?promoCode=UKNHS01&pub=/uk/english"/>
<mapping old="/hk/ukstudentfare" new="/cugo.aspx?promoCode=HKSTU10&pub=/hk/Chinese"/>
</mappings>
And Here is my XSLT where I am trying to generated the above format XML but it is not working for me. please note first xml is primary xml which will be transformed using below XSLT
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform" xmlns:tcm="http://www.tridion.com/ContentManager/5.0" xmlns:xlink="http://www.w3.org/1999/xlink" xmlns:em="http://www.espire.com/tridion/schemas" xmlns:tcmse="http://www.tridion.com/ContentManager/5.1/TcmScriptAssistant" exclude-result-prefixes="em xlink tcmse tcm">
<xsl:output method="xml" version="1.0" encoding="UTF-16" indent="yes"/>
<!-- root match-->
<xsl:template match="tcm:ListItems">
<mappings>
<xsl:apply-templates select="tcm:Item"/>
</mappings>
</xsl:template>
<xsl:template match="tcm:Item">
<xsl:variable name="doc" select="document(@ID)"/>
<xsl:if test="$doc/tcm:Component/tcm:Data/tcm:Content/em:MappingCollection/em:VanityUrl/em:comments">
<xsl:comment>
<xsl:value-of select="$doc/tcm:Component/tcm:Data/tcm:Content/em:MappingCollection/em:VanityUrl/em:comments"/>
</xsl:comment>
</xsl:if>
<xsl:for-each select="$doc/tcm:Component/tcm:Data/tcm:Content/em:MappingCollection/em:VanityUrl">
<xsl:element name="mapping">
<xsl:if test="$doc/tcm:Component/tcm:Data/tcm:Content/em:MappingCollection/em:VanityUrl/em:old">
<xsl:attribute name="old">
<xsl:value-of select="$doc/tcm:Component/tcm:Data/tcm:Content/em:MappingCollection/em:VanityUrl/em:old"/>
</xsl:attribute>
</xsl:if>
<xsl:if test="$doc/tcm:Component/tcm:Data/tcm:Content/em:MappingCollection/em:VanityUrl/em:new">
<xsl:attribute name="new">
<xsl:value-of select="$doc/tcm:Component/tcm:Data/tcm:Content/em:MappingCollection/em:VanityUrl/em:new"/>
</xsl:attribute>
</xsl:if>
<xsl:if test="$doc/tcm:Component/tcm:Data/tcm:Content/em:MappingCollection/em:VanityUrl/em:dateAdded">
<xsl:attribute name="dateAdded">
<xsl:value-of select="$doc/tcm:Component/tcm:Data/tcm:Content/em:MappingCollection/em:VanityUrl/em:dateAdded"/>
</xsl:attribute>
</xsl:if>
</xsl:element>
</xsl:for-each>
</xsl:template>
</xsl:stylesheet>
In above xslt I am able to get the data loop is also going correct but the data which is been coming is same, I mean loop is performing correct, but the node value is same
Please Suggest!
Solução
This stylesheet:
<xsl:stylesheet version="1.0"
xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
xmlns:ns="uuid:922EEC29-2DE3-4BA1-A46A-A300CB8FA85F"
xmlns:tcm="http://www.tridion.com/ContentManager/5.0"
xmlns:msxsl="urn:schemas-microsoft-com:xslt"
exclude-result-prefixes="ns tcm msxsl">
<xsl:strip-space elements="*"/>
<xsl:key name="kVanityByComment" match="ns:VanityUrl" use="ns:comments"/>
<xsl:template match="/">
<xsl:variable name="vSourcesRTF">
<xsl:copy-of select="document(tcm:ListItems/tcm:Item/@ID)"/>
</xsl:variable>
<mappings>
<xsl:apply-templates select="msxsl:node-set($vSourcesRTF)/node()"/>
</mappings>
</xsl:template>
<xsl:template match="ns:VanityUrl"/>
<xsl:template match="ns:VanityUrl[generate-id()=
generate-id(key('kVanityByComment',
ns:comments)[1])]">
<xsl:comment>
<xsl:value-of select="ns:comments"/>
</xsl:comment>
<xsl:apply-templates select="key('kVanityByComment',
ns:comments)"
mode="output"/>
</xsl:template>
<xsl:template match="ns:VanityUrl" mode="output">
<mapping>
<xsl:apply-templates/>
</mapping>
</xsl:template>
<xsl:template match="ns:VanityUrl/ns:comments" priority="1"/>
<xsl:template match="ns:VanityUrl/*">
<xsl:attribute name="{local-name()}">
<xsl:value-of select="."/>
</xsl:attribute>
</xsl:template>
</xsl:stylesheet>
With this input:
<tcm:ListItems xmlns:tcm="http://www.tridion.com/ContentManager/5.0" ID="tcm:232-83752-2" Managed="10682">
<tcm:Item ID="229-564598" Title="010 News Mapping"/>
<tcm:Item ID="229-564598" Title="020 CUGOs"/>
<tcm:Item ID="229-564598" Title="030 Reserved Urls"/>
</tcm:ListItems>
And this external source with 229-564598 URI:
<tcm:Component ID="tcm:229-564598" IsEditable="false" xmlns:tcm="http://www.tridion.com/ContentManager/5.0" xmlns:xlink="http://www.w3.org/1999/xlink">
<tcm:Data>
<tcm:Content>
<MappingCollection xmlns="uuid:922EEC29-2DE3-4BA1-A46A-A300CB8FA85F">
<VanityUrl>
<old>mbp</old>
<new>/SessionHandler.aspx?pageurl=/BP.aspx&pub=/english&section=IBE&j=f</new>
<dateAdded>2010-05-03T14:45:00</dateAdded>
<comments> News mapping </comments>
</VanityUrl>
<VanityUrl>
<old>about/news</old>
<new>about/news/news.aspx</new>
<dateAdded>2010-05-03T14:45:00</dateAdded>
<comments> News mapping </comments>
</VanityUrl>
</MappingCollection>
</tcm:Content>
</tcm:Data>
</tcm:Component>
Output:
<mappings>
<!-- News mapping -->
<mapping old="mbp"
new="/SessionHandler.aspx?pageurl=/BP.aspx&pub=/english&section=IBE&j=f"
dateAdded="2010-05-03T14:45:00"></mapping>
<mapping old="about/news"
new="about/news/news.aspx"
dateAdded="2010-05-03T14:45:00"></mapping>
</mappings>
EDIT: Multiple input sources.
Outras dicas
Yes, the change you made is indeed critical. :-)
What the for-each loop does is select each <em:VanityUrl> element matching your XPath expression, make that element the context node for what's inside the for-each (called the template even though it's not an <xsl:template>), and then instantiate that inner template with the new context node.
When you were continuing to use "$doc/..." inside the for-each loop, you were throwing away the context node, so the for-each was having no effect (except to repeat n times).
Your <xsl:if test="$doc/..."> statements were evaluating whether there was any such node in the whole document instead of under the context element <em:VanityUrl>.
The <xsl:value-of> statement pays attention to only the first node in the selected nodeset, so you were always getting the value from the first <em:VanityUrl>, regardless of the context node.
When you started selecting and testing relative to the context node:
<xsl:if test="em:old">
everything became better. :-)
You asked for valuable input. For stylistic reasons, you may want to replace your <xsl:if> tests with <xsl:apply-templates>. (For one thing you'll make @Dimitre Novatchev happy. :-) So
<xsl:if test="$doc/tcm:Component/tcm:Data/tcm:Content/em:MappingCollection/em:VanityUrl/em:comments">
<xsl:comment>
<xsl:value-of select="$doc/tcm:Component/tcm:Data/tcm:Content/em:MappingCollection/em:VanityUrl/em:comments"/>
</xsl:comment>
</xsl:if>
becomes
<xsl:apply-templates select="$doc/tcm:Component/tcm:Data/tcm:Content/em:MappingCollection/em:VanityUrl/em:comments" />
and then you need a separate template for those:
<xsl:template match="em:comments">
<xsl:comment>
<xsl:value-of select="."/>
</xsl:comment>
</xsl:template>
There are several advantages to doing that. The biggest is that you don't have to duplicate that long XPath expression, which was error-prone if the expression ever needed to be modified. If there are no em:comment elements, the apply-templates will not do anything, so will not emit a comment.
It also modularizes your stylesheet, so that you can modify how em:comments are rendered, separately from wherever they may occur. That may not matter too much in simple XML documents where em:comments occurs in only one place, but it is the style that takes best advantage of XSLT's power. Also note that this modified version will output multiple comments if there are multiple em:comments, which your version will not. Again you probably don't have multiples in the input, so it may not matter.
Similarly for the output attributes:
<xsl:if test="em:old">
<xsl:attribute name="old">
<xsl:value-of select="em:old"/>
</xsl:attribute>
</xsl:if>
can become
<xsl:apply-templates select="em:old[1]" />
with a separate template
<xsl:template match="em:old">
<xsl:attribute name="old">
<xsl:value-of select="."/>
</xsl:attribute>
</xsl:template>
Note the [1], which avoids attempting to output multiple old="..." attributes for the same element if the input em:VanityUrl has multiple em:old elements. That would be cause your stylesheet to raise an error. But maybe you want to raise an error in that case. If so, you are probably already validating your input XML.
In fact, you can generalize the apply-templates and the template here to apply to all three attributes:
<xsl:apply-templates select="em:old[1] | em:new[1] | em:dateAdded[1]" />
Again, if any of these elements are not present, nothing will be done for them (no empty attribute will be produced). The template:
<xsl:template match="em:old | em:new | em:dateAdded">
<xsl:attribute name="{local-name()}">
<xsl:value-of select="."/>
</xsl:attribute>
</xsl:template>
local-name() gives us the name of the element, without the namespace prefix.
Update:
Another way to handle that would be to use a mode:
<xsl:apply-templates select="em:old[1] | em:new[1] | em:dateAdded[1]"
mode="make-attribute" />
<xsl:template match="em:*" mode="make-attribute">
<xsl:attribute name="{local-name()}">
<xsl:value-of select="."/>
</xsl:attribute>
</xsl:template>
Then your make-attribute template can be used from anywhere, and the match pattern doesn't have to be updated to match every possible element you might want to make an attribute from.
The only other thing I would say is that the use of namespaces above is confusing...it shouldn't work as-is. E.g. your stylesheet uses this namespace URI for elements like VanityURL:
"http://www.espire.com/tridion/schemas"
but the second input document uses this namespace URI for those elements:
"uuid:922EEC29-2DE3-4BA1-A46A-A300CB8FA85F"
It doesn't matter that the namespace prefixes are different ("em:" vs. default), but the namespace URIs have to match. I guess VanityURL's namespace URI must have changed, or else your stylesheet wouldn't work...
HTH!
You can try this also!!
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform" xmlns:tcm="http://www.tridion.com/ContentManager/5.0" xmlns:xlink="http://www.w3.org/1999/xlink" xmlns:em="http://www.espire.com/tridion/schemas" xmlns:tcmse="http://www.tridion.com/ContentManager/5.1/TcmScriptAssistant" exclude-result-prefixes="em xlink tcmse tcm">
<xsl:output method="xml" version="1.0" encoding="UTF-16" indent="yes"/>
<!-- root match-->
<xsl:template match="tcm:ListItems">
<mappings>
<xsl:apply-templates select="tcm:Item"/>
</mappings>
</xsl:template>
<xsl:template match="tcm:Item">
<xsl:variable name="doc" select="document(@ID)"/>
<xsl:if test="$doc/tcm:Component/tcm:Data/tcm:Content/em:MappingCollection/em:VanityUrl/em:comments">
<xsl:comment>
<xsl:value-of select="$doc/tcm:Component/tcm:Data/tcm:Content/em:MappingCollection/em:VanityUrl/em:comments"/>
</xsl:comment>
</xsl:if>
<xsl:for-each select="$doc/tcm:Component/tcm:Data/tcm:Content/em:MappingCollection/em:VanityUrl">
<xsl:element name="mapping">
<xsl:if test="em:old">
<xsl:attribute name="old">
<xsl:value-of select="em:old"/>
</xsl:attribute>
</xsl:if>
<xsl:if test="em:new">
<xsl:attribute name="new">
<xsl:value-of select="em:new"/>
</xsl:attribute>
</xsl:if>
<xsl:if test="em:dateAdded">
<xsl:attribute name="dateAdded">
<xsl:value-of select="em:dateAdded"/>
</xsl:attribute>
</xsl:if>
</xsl:element>
</xsl:for-each>
</xsl:template>
</xsl:stylesheet>
