Gerando permutações em VBA
Pergunta
Esta pergunta já foi feita antes, mas não consigo encontrar uma resposta que seja facilmente aplicável ao Excel VBA.
Basicamente, quero fazer exatamente o que este autor da postagem pediu, mas em VBA.Quero criar um array, n x 2^n, onde cada linha representa uma permutação diferente de n variáveis que podem ser 0 ou 1.
Eu brinquei com isso há muito tempo e é bastante fácil de fazer para um conjunto n com muitos loops, mas para uma variável n não consigo encontrar nada que funcione.
Qualquer código ou apenas sugestões de maneiras de fazer isso seria muito apreciado!
Solução
Isso listará o valor na coluna A
Sub EasyAsCounting()
Dim N As Long, M As Long, K As Long
N = Application.InputBox(Prompt:="Enter N", Type:=1)
M = 2 ^ N - 1
For K = 0 To M
Cells(K + 1, 1) = "'" & Application.WorksheetFunction.Dec2Bin(K, N)
Next K
End Sub
EDITAR#1
Isso armazena a matriz em VBA apenas:
Sub EasyAsCounting()
Dim N As Long, M As Long, K As Long, ary, s As String
Dim J As Long
N = Application.InputBox(Prompt:="Enter N", Type:=1)
M = 2 ^ N - 1
ReDim ary(1 To M + 1, 1 To N)
For K = 0 To M
s = Application.WorksheetFunction.Dec2Bin(K, N)
For J = 1 To N
ary(K + 1, J) = Mid(s, J, 1)
Next J
Next K
'
'display the array
'
msg = ""
For K = 1 To M + 1
For J = 1 To N
msg = msg & " " & ary(K, J)
Next J
msg = msg & vbCrLf
Next K
MsgBox msg
End Sub
Outras dicas
Aqui está um caso você não esteja no Excel e não tenha acesso às funções.Ou se você tiver um número maior que 511.
Sub MakePerms()
Dim i As Long, j As Long
Dim n As Long
Dim aPerms() As Byte
Dim lCnt As Long
Dim sOutput As String
Const lVar As Long = 4
ReDim aPerms(1 To 2 ^ lVar, 1 To lVar)
For i = 0 To UBound(aPerms, 1) - 1
n = i
lCnt = lVar
aPerms(i + 1, lCnt) = CByte(n Mod 2)
n = n \ 2
Do While n > 0
lCnt = lCnt - 1
aPerms(i + 1, lCnt) = CByte(n Mod 2)
n = n \ 2
Loop
Next i
For i = LBound(aPerms, 1) To UBound(aPerms, 1)
sOutput = vbNullString
For j = LBound(aPerms, 2) To UBound(aPerms, 2)
sOutput = sOutput & Space(1) & aPerms(i, j)
Next j
Debug.Print sOutput
Next i
End Sub