Como lidar com não Processada #2044 erros de Flash tilelist quando alterar o provedor de dados?
-
13-09-2020 - |
Pergunta
Eu tenho uma componente tilelist usando um personalizado ImageCell item com o processador.Eu sei que às vezes algumas das imagens que ele está tentando recuperar não será encontrado e eu sou capaz de lidar com isso através de um IEOrror ouvinte sobre o costume ImageCell carregador.
No entanto, se eu definir o provedor de dados e, em seguida, é alterada antes de todas as imagens tenham concluído o carregamento de erro ou processo, o flash debug player joga-se não tratada #2044 erro no firefox afirmando que uma imagem não pode ser encontrado.Na ópera, com a depuração do jogador lança um #2044 afirmando que uma carga nunca foi concluída.
Eu não consigo encontrar uma maneira para interceptar e ignorar estes erros, de modo que eles não jogam o depurador leitor de diálogo acima.Além disso, quando utilizar o Flash Builder IDE para depuração, o depurador não quebra sobre estes erros em tudo, é apenas no leitor, enquanto eu sou capaz de quebrar em outros erros, sem problema.
É como se o erro ouvinte está sendo descartados quando o provedor de dados muda, mas o carregador continua e lança uma não tratada #2044.
Quaisquer ideias sobre como lidar com effectivel?Obrigado pelo seu tempo e de assistência -
b
Solução
No construtor do seu Renderizador de Célula Personalizado, você precisará adicionar um ouvinte de evento para a protegida carregador instância e lidar com o IOError.
Aqui está um exemplo:
package
{
import fl.controls.listClasses.ICellRenderer;
import fl.controls.listClasses.ImageCell;
import fl.controls.TileList;
import fl.data.DataProvider;
import fl.managers.StyleManager;
import flash.events.EventDispatcher;
import flash.events.*;
import fl.containers.UILoader;
public class CustomImageCell extends ImageCell implements ICellRenderer
{
public function CustomImageCell()
{
super();
//do other stuff here
loader.scaleContent = false;
loader.addEventListener(IOErrorEvent.IO_ERROR, handleErrorEvent, false, 0, true);
useHandCursor = true;
}
override protected function drawLayout():void
{
var imagePadding:Number = getStyleValue("imagePadding") as Number;
loader.move(11, 5);
var w:Number = width-(imagePadding*2);
var h:Number = height-imagePadding*2;
if (loader.width != w && loader.height != h)
{
loader.setSize(w,h);
}
loader.drawNow(); // Force validation!
}
override protected function handleErrorEvent(event:IOErrorEvent):void {
trace('ioError: ' + event);
//dispatchEvent(event);
}
}
}
aqui é um teste simples que eu fiz para ver o que acontece quando o provedor de dados é atualizado:
import fl.controls.*;
import fl.data.DataProvider;
import fl.controls.listClasses.CellRenderer;
stage.scaleMode = StageScaleMode.NO_SCALE;
stage.align = StageAlign.TOP_LEFT;
var tileList:TileList = new TileList ();
tileList.move(220,40);
tileList.setSize(215, 400);
tileList.columnWidth = 215;
tileList.rowHeight = 86;
tileList.direction = ScrollBarDirection.VERTICAL;
tileList.setStyle("cellRenderer", CustomImageCell);
addChild(tileList);
tileList.dataProvider = getRandomDP(10);
setTimeout(resetDP,3000);
function resetDP():void {
tileList.dataProvider = getRandomDP(10);
}
function getRandomDP(size:int):DataProvider {
var result:DataProvider = new DataProvider();
for(var i:int = 0; i < size; i++) result.addItem({label:'item'+i,source:'wrong.url/'+Math.random()});
return result;
}
HTH