DataProviderを変更するときに、フラッシュタリリストから未処理の＃2044エラーを処理する方法

Question

カスタムImageCellベースのアイテムレンダラを使用してTILLISTコンポーネントを持っています。私はそれが取得しようとしているイメージのいくつかが見つからないことを知っていて、私はカスタムImageCellローダーのIEORRORリスナーを介してこれを処理することができます。

しかし、データプロバイダを設定した場合、すべての画像がロードまたはエラープロセスが完了した前に変更され、フラッシュデバッグプレーヤーはFirefoxで未処理の＃2044エラーをスローしています。デバッグプレーヤーを使用したオペラでは、ロードが完了しないことを示す＃2044をスローします。

これらのエラーを罠にかけて無視する方法は見つかりませんので、デバッガープレーヤーのダイアログを投げません。また、Flash Builder IDEをデバッグするときに、デバッガはまったくこれらのエラーを壊しません。問題なく他のエラーを折りたたむことができる間、それはプレーヤーのみです。

データプローバが変わったときにエラーリスナーが廃棄されているかのように、ローダは継続し、未処理の＃2044をスローします。

エフェクト証化を処理する方法についてのアイデア？あなたの時間と支援のために事前にありがとう -

b

Answer 1

カスタムセルレンダラのコンストラクタでは、プロテクトされた loader インスタンスにイベントリスナーを追加してioErrorを処理する必要があります。

これは例です：

package
{
    import fl.controls.listClasses.ICellRenderer;
    import fl.controls.listClasses.ImageCell;
    import fl.controls.TileList;
    import fl.data.DataProvider;
    import fl.managers.StyleManager;
    import flash.events.EventDispatcher;
    import flash.events.*;
    import fl.containers.UILoader;

    public class CustomImageCell extends ImageCell implements ICellRenderer
    {  

        public function CustomImageCell() 
        {
            super();

            //do other stuff here

            loader.scaleContent = false;
            loader.addEventListener(IOErrorEvent.IO_ERROR, handleErrorEvent, false, 0, true);

            useHandCursor = true;
        }

        override protected function drawLayout():void
        {
            var imagePadding:Number = getStyleValue("imagePadding") as Number;
            loader.move(11, 5);

            var w:Number = width-(imagePadding*2);
            var h:Number = height-imagePadding*2;
            if (loader.width != w && loader.height != h)
            {
                loader.setSize(w,h);
            }
            loader.drawNow(); // Force validation!

        }
        override protected function handleErrorEvent(event:IOErrorEvent):void {
            trace('ioError: ' + event);
            //dispatchEvent(event);
        }
    }
}

.

これは私がデータプロバイダが更新されたときに何が起こるかを見るために私がした簡単なテストです：

import fl.controls.*;
import fl.data.DataProvider;
import fl.controls.listClasses.CellRenderer;

stage.scaleMode = StageScaleMode.NO_SCALE;
stage.align = StageAlign.TOP_LEFT;

var tileList:TileList = new TileList ();
tileList.move(220,40);
tileList.setSize(215, 400);
tileList.columnWidth = 215;
tileList.rowHeight = 86;
tileList.direction = ScrollBarDirection.VERTICAL;
tileList.setStyle("cellRenderer", CustomImageCell);
addChild(tileList);

tileList.dataProvider = getRandomDP(10);
setTimeout(resetDP,3000);

function resetDP():void {
    tileList.dataProvider = getRandomDP(10);
}
function getRandomDP(size:int):DataProvider {
    var result:DataProvider = new DataProvider();
    for(var i:int = 0; i < size; i++)   result.addItem({label:'item'+i,source:'wrong.url/'+Math.random()});
    return result;
}

.

hth