Obfuscation Puzzle: Você pode descobrir o que esta função Perl faz? [fechadas]
-
01-07-2019 - |
Pergunta
sub foo {[$#{$_[!$||$|]}*@{$_[!!$_^!$_]}?@{$_[!$..!!$.]}[$_[@--@+]%
@{$_[$==~/(?=)//!$`]}..$#{$_[$??!!$?:!$?]},($)?!$):!!$))..$_[$--$-]%@{
$_[$]/$]]}-(!!$++!$+)]:@{$_[!!$^^^!$^^]}]}
Atualização: Eu pensei que a palavra "puzzle" implicaria isso, mas: I sabe o que faz - eu o escrevi. Se o quebra-cabeça não lhe interessam, por favor, não perca tempo com isso.
Solução
Aqui está como você descobrir como a de-ofuscar essa sub-rotina.
Desculpem o comprimento
Primeiro vamos arrumar o código e adicionar comentários úteis.
sub foo {
[
(
# ($#{$_[1]})
$#{
$_[
! ( $| | $| )
# $OUTPUT_AUTOFLUSH === $|
# $| is usually 0
# ! ( $| | $| )
# ! ( 0 | 0 )
# ! ( 0 )
# 1
]
}
*
# @{$_[1]}
@{
$_[
!!$_ ^ !$_
# !! 1 ^ ! 1
# ! 0 ^ 0
# 1 ^ 0
# 1
# !! 0 ^ ! 0
# ! 1 ^ 1
# 0 ^ 1
# 1
]
}
)
?
# @{$_[1]}
@{
$_[
!$. . !!$.
# $INPUT_LINE_NUMBER === $.
# $. starts at 1
# !$. . !!$.
# ! 1 . !! 1
# 0 . ! 0
# 0 . 1
# 01
]
}
[
# $_[0]
$_[
# @LAST_MATCH_START - @LAST_MATCH_END
# 0
@- - @+
]
%
# @{$_[1]}
@{
$_[
$= =~ /(?=)/ / !$` #( fix highlighting )`/
# $= is usually 60
# /(?=)/ will match, returns 1
# $` will be ''
# 1 / ! ''
# 1 / ! 0
# 1 / 1
# 1
]
}
..
# $#{$_[1]}
$#{
$_[
$? ? !!$? : !$?
# $CHILD_ERROR === $?
# $? ? !!$? : !$?
# 0 ? !! 0 : ! 0
# 0 ? 0 : 1
# 1
# 1 ? !! 1 : ! 1
# 1 ? 1 : 0
# 1
]
}
,
# ( 0 )
(
$) ? !$) : !!$)
# $EFFECTIVE_GROUP_ID === $)
# $) ? !$) : !!$)
# 0 ? ! 0 : !! 0
# 0 ? 1 : 0
# 0
# 1 ? ! 1 : !! 1
# 1 ? 0 : 1
# 0
)
..
# $_[0]
$_[
$- - $- # 0
# $LAST_PAREN_MATCH = $-
# 1 - 1 == 0
# 5 - 5 == 0
]
%
# @{$_[1]}
@{
$_[
$] / $]
# $] === The version + patchlevel / 1000 of the Perl interpreter.
# 1 / 1 == 1
# 5 / 5 == 1
]
}
-
# ( 1 )
(
!!$+ + !$+
# !! 1 + ! 1
# ! 0 + 0
# 1 + 0
# 1
)
]
:
# @{$_[1]}
@{
$_[
!!$^^ ^ !$^^
# !! 1 ^ ! 1
# ! 0 ^ 0
# 1 ^ 0
# 1
# !! 0 ^ ! 0
# ! 1 ^ 1
# 0 ^ 1
# 1
]
}
]
}
Agora vamos remover parte da ofuscação.
sub foo{
[
(
$#{$_[1]} * @{$_[1]}
)
?
@{$_[1]}[
( $_[0] % @{$_[1]} ) .. $#{$_[1]}
,
0 .. ( $_[0] % @{$_[1]} - 1 )
]
:
@{$_[1]}
]
}
Agora que temos uma idéia do que está acontecendo, vamos citar as variáveis.
sub foo{
my( $item_0, $arr_1 ) = @_;
my $len_1 = @$arr_1;
[
# This essentially just checks that the length of $arr_1 is greater than 1
( ( $len_1 -1 ) * $len_1 )
# ( ( $len_1 -1 ) * $len_1 )
# ( ( 5 -1 ) * 5 )
# 4 * 5
# 20
# 20 ? 1 : 0 == 1
# ( ( $len_1 -1 ) * $len_1 )
# ( ( 2 -1 ) * 2 )
# 1 * 2
# 2
# 2 ? 1 : 0 == 1
# ( ( $len_1 -1 ) * $len_1 )
# ( ( 1 -1 ) * 1 )
# 0 * 1
# 0
# 0 ? 1 : 0 == 0
# ( ( $len_1 -1 ) * $len_1 )
# ( ( 0 -1 ) * 0 )
# -1 * 0
# 0
# 0 ? 1 : 0 == 0
?
@{$arr_1}[
( $item_0 % $len_1 ) .. ( $len_1 -1 ),
0 .. ( $item_0 % $len_1 - 1 )
]
:
# If we get here, @$arr_1 is either empty or has only one element
@$arr_1
]
}
Vamos refatorar o código para torná-lo um pouco mais legível.
sub foo{
my( $item_0, $arr_1 ) = @_;
my $len_1 = @$arr_1;
if( $len_1 > 1 ){
return [
@{$arr_1}[
( $item_0 % $len_1 ) .. ( $len_1 -1 ),
0 .. ( $item_0 % $len_1 - 1 )
]
];
}elsif( $len_1 ){
return [ @$arr_1 ];
}else{
return [];
}
}
Outras dicas
Eu encontrei este comando útil, quando se trabalha em minha outra resposta.
perl -MO=Concise,foo,-terse,-compact obpuz.pl > obpuz.out
É preciso dois arrayrefs e retorna uma nova ARRAYREF com o conteúdo da segunda matriz reorganizados de modo que a segunda parte vem antes da primeira parte, dividida em um ponto com base na localização de memória da primeira matriz. Quando a segunda matriz é vazio ou contém um item, apenas retorna uma cópia da segunda matriz. Equivalente ao seguinte:
sub foo {
my ($list1, $list2) = @_;
my @output;
if (@$list2 > 0) {
my $split = $list1 % @$list2;
@output = @$list2[$split .. $#$list2, 0 .. ($split - 1)];
} else {
@output = @$list2;
}
return \@output;
}
$list1 % @$list2
essencialmente escolhe um lugar aleatório para dividir a matriz, com base em $list
que avalia para o endereço de memória $ list quando avaliada em um contexto numérico.
O original principalmente usa um monte de tautologias envolvendo variáveis ??de pontuação para ofuscar. por exemplo.
-
!$| | $|
é sempre 1 -
@- - @+
é sempre 0
atualizada para mostrar que perltidy
foi decifração muito útil aqui, mas engasgou com !!$^^^!$^^
, que reformata a !!$^ ^ ^ !$^ ^
, que é inválido Perl; deve ser !!$^^ ^ !$^^
. Esta pode ser a causa de erro de compilação de RWendi.