Função Delphi comparando conteúdo de dois TStream?

Question

Eu preciso comparar se dois TStream descendente tem o mesmo conteúdo.O único resultado interessante para mim é o booleano Sim/Não.

vou codificar um laço simples verificando byte após byte o conteúdo do stream.

Mas eu curioso para saber se já existe uma função.Não encontrei nenhuma dentro das bibliotecas DelphiXE ou JCL/JVCL.

Claro, os dois fluxos têm o mesmo tamanho!

Answer 1

Exatamente, como Nickolay O. disse que você deve ler seu fluxo em blocos e usar o Comparemem. Aqui está um exemplo (incluindo teste de tamanho) ...

function IsIdenticalStreams(Source, Destination: TStream): boolean;
const Block_Size = 4096;

var Buffer_1: array[0..Block_Size-1] of byte;
    Buffer_2: array[0..Block_Size-1] of byte;
    Buffer_Length: integer;

begin
  Result := False;

  if Source.Size <> Destination.Size then
    Exit;

  while Source.Position < Source.Size do
    begin
      Buffer_Length := Source.Read(Buffer_1, Block_Size);
      Destination.Read(Buffer_2, Block_Size);

      if not CompareMem(@Buffer_1, @Buffer_2, Buffer_Length) then
        Exit;
    end;

  Result := True;
end;

Answer 2

O IsIdenticalStreams A função postada por daemon_x é excelente - mas precisa de um ajuste para funcionar corretamente.(Uwe Raabe já percebeu o problema.) É crítico que você redefina as posições do fluxo antes de iniciar o loop - ou este procedimento provavelmente retornará um TRUE incorreto se os dois fluxos já tiverem sido acessados ​​fora desta função.

Esta é a solução final que funciona sempre.Acabei de renomear a função para se adequar às minhas convenções de nomenclatura.Obrigado daemon_x pela solução elegante.

function StreamsAreIdentical(Stream1, Stream2: TStream): boolean;
const
  Block_Size = 4096;

var
  Buffer_1: array[0..Block_Size-1] of byte;
  Buffer_2: array[0..Block_Size-1] of byte;
  Buffer_Length: integer;

begin

  Result := False;

  if Stream1.Size <> Stream2.Size then exit;

  // These two added lines are critical for proper operation 
  Stream1.Position := 0;
  Stream2.Position := 0;

  while Stream1.Position < Stream1.Size do
  begin

    Buffer_Length := Stream1.Read(Buffer_1, Block_Size);
    Stream2.Read(Buffer_2, Block_Size);
    if not CompareMem(@Buffer_1, @Buffer_2, Buffer_Length) then exit;

  end;

  Result := True;

end;

Answer 3

Não existe essa função interna. Apenas uma coisa que posso recomendar-não leia byte a byte, mas usando blocos de 16-64kbytes, isso seria muito mais rápido.

Answer 4

Respostas de User532231 e Mike estão trabalhando em 99% de casos, mas existem verificações adicionais a serem feitas!

Descendentes de TStream pode ser quase tudo, então Não é garantido que o stream.read retornará a mesma quantidade de dados, mesmo que os fluxos tenham o mesmo comprimento (o descendente do fluxo também pode baixar dados, portanto, pode retornar lido = 0 bytes, enquanto aguardam o próximo pedaço). Os fluxos também podem estar em diferentes mídias completas e o erro de leitura de fluxo pode ocorrer em apenas um.

Para um código de trabalho 100%, todas essas verificações devem ser feitas. Eu modifiquei a função de Mike.

Se essa função for usada, por exemplo, para reescrever o Stream 2 se não for idêntico ao Stream1, todos os erros devem ser verificados. Quando o resultado da função é verdadeiro, tudo é bom, mas se for falso, seria muito inteligente verificar se os fluxos são realmente diferentes ou apenas algum erro ocorreu.

Editado: Adicionado algumas verificações adicionais, a função FileSeDeDical com base no exemplo de streamSeDentical e de uso.

// Usage example

var lError: Integer;
...
 if FilesAreIdentical(lError, 'file1.ext', 'file2.ext')
    then Memo1.Lines.Append('Files are identical.')
    else case lError of
           0: Memo1.Lines.Append('Files are NOT identical!');
           1: Memo1.Lines.Append('Files opened, stream read exception raised!');
           2: Memo1.Lines.Append('File does not exist!');
           3: Memo1.Lines.Append('File open exception raised!');
         end; // case
...

// StreamAreIdentical

function StreamsAreIdentical(var aError: Integer;
                             const aStream1, aStream2: TStream;
                             const aBlockSize: Integer = 4096): Boolean;

var
  lBuffer1: array of byte;
  lBuffer2: array of byte;
  lBuffer1Readed,
  lBuffer2Readed,
  lBlockSize: integer;

begin
  Result:=False;
  aError:=0;
  try
    if aStream1.Size <> aStream2.Size
       then Exit;

    aStream1.Position:=0;
    aStream2.Position:=0;

    if aBlockSize>0
       then lBlockSize:=aBlockSize
       else lBlockSize:=4096;

    SetLength(lBuffer1, lBlockSize);
    SetLength(lBuffer2, lBlockSize);

    lBuffer1Readed:=1; // just for entering while

    while (lBuffer1Readed > 0) and (aStream1.Position < aStream1.Size) do
    begin
      lBuffer1Readed := aStream1.Read(lBuffer1[0], lBlockSize);
      lBuffer2Readed := aStream2.Read(lBuffer2[0], lBlockSize);

      if (lBuffer1Readed <> lBuffer2Readed) or ((lBuffer1Readed <> lBlockSize) and (aStream1.Position < aStream1.Size))
         then Exit;

      if not CompareMem(@lBuffer1[0], @lBuffer2[0], lBuffer1Readed)
         then Exit;
    end; // while

    Result:=True;
  except
    aError:=1; // stream read exception
  end;
end;


// FilesAreIdentical using function StreamsAreIdentical

function FilesAreIdentical(var aError: Integer;
                           const aFileName1, aFileName2: String;
                           const aBlockSize: Integer = 4096): Boolean;

var lFileStream1,
    lFilestream2: TFileStream;

begin
 Result:=False;
 try
   if not (FileExists(aFileName1) and FileExists(aFileName2))
      then begin
        aError:=2; // file not found
        Exit;
      end;

   lFileStream1:=nil;
   lFileStream2:=nil;
   try
     lFileStream1:=TfileStream.Create(aFileName1, fmOpenRead or fmShareDenyNone);
     lFileStream2:=TFileStream.Create(aFileName2, fmOpenRead or fmShareDenyNone);
     result:=StreamsAreIdentical(aError, lFileStream1, lFileStream2, aBlockSize);
   finally
     if lFileStream2<>nil
        then lFileStream2.Free;

     if lFileStream1<>nil
        then lFileStream1.Free;
   end; // finally
 except
   aError:=3; // file open exception
 end; // except
end;