Функция Delphi сравнивая содержимое двух Tstream?
Вопрос
Мне нужно сравнить, если два TSTREAM потомство иметь тот же контентОтказ Единственный интересный результат для меня - логическая да / нет
Я собираюсь в код простая петля Проверка байта после байта потоковых контента.
Но я любопытный знать, есть ли уже существующая функция. Я не нашел внутри Delphixe или JCL / JVCL Libs.
Конечно, два потока имеют одинаковый размер!
Решение
Точно, как никелай О. сказал, что вы должны прочитать ваш поток в блоках и использовать сравнительную информацию. Вот пример (включая размер теста) ...
function IsIdenticalStreams(Source, Destination: TStream): boolean;
const Block_Size = 4096;
var Buffer_1: array[0..Block_Size-1] of byte;
Buffer_2: array[0..Block_Size-1] of byte;
Buffer_Length: integer;
begin
Result := False;
if Source.Size <> Destination.Size then
Exit;
while Source.Position < Source.Size do
begin
Buffer_Length := Source.Read(Buffer_1, Block_Size);
Destination.Read(Buffer_2, Block_Size);
if not CompareMem(@Buffer_1, @Buffer_2, Buffer_Length) then
Exit;
end;
Result := True;
end;
Другие советы
То IsidenticalStreams. Функция, размещенная daemon_x, отличная - но нужна одна корректировка правильной работы. (Уве Раабе уже поймал проблему.) Это критический, который вы сбросите положения потока перед запуском цикла - или эта процедура, вероятно, вернет неверную верную версию, если два потока уже доступны вне этой функции.
Это окончательное решение, которое работает каждый раз. Я просто переименован в функцию, чтобы удовлетворить моих соглашений о именах. Спасибо Daemon_x для элегантного решения.
function StreamsAreIdentical(Stream1, Stream2: TStream): boolean;
const
Block_Size = 4096;
var
Buffer_1: array[0..Block_Size-1] of byte;
Buffer_2: array[0..Block_Size-1] of byte;
Buffer_Length: integer;
begin
Result := False;
if Stream1.Size <> Stream2.Size then exit;
// These two added lines are critical for proper operation
Stream1.Position := 0;
Stream2.Position := 0;
while Stream1.Position < Stream1.Size do
begin
Buffer_Length := Stream1.Read(Buffer_1, Block_Size);
Stream2.Read(Buffer_2, Block_Size);
if not CompareMem(@Buffer_1, @Buffer_2, Buffer_Length) then exit;
end;
Result := True;
end;
Такого встроенного функции нет. Только одно я могу рекомендовать - прочитать не байт-байт, но используя блоки 16-64кбайт, что было бы намного быстрее.
Ответы от user532231. а также Майк работают в 99% случаев, но есть Дополнительные проверки должны быть сделаны!
Потомки Tstream могут быть почти все, поэтому Это не гарантируется, что stream.read вернется в ту же сумму данных, Даже если потоки имеют одинаковую длину (поток потока также может загружать данные, поэтому может возвращать читаемые = 0 байтов во время ожидания следующего чанка). Потоки могут также быть заполненными разными мультимедиа и повторной ошибки чтения потока могут возникнуть только на одном.
Для 100% рабочего кода все эти проверки должны быть сделаны. Я изменил функцию из Майка.
Если эта функция используется, например, для перезаписи потока 2, если не идентично Stream1, все ошибки должны быть проверены. Когда результат функции верно, вечно все в порядке, но если оно ложно, было бы очень умным проверить, будут ли фактически разные потоки или просто некоторые ошибки.
Отредактировано: Добавлены некоторые дополнительные проверки, файловая функция на основе примера StreamsAReidentical и использование.
// Usage example
var lError: Integer;
...
if FilesAreIdentical(lError, 'file1.ext', 'file2.ext')
then Memo1.Lines.Append('Files are identical.')
else case lError of
0: Memo1.Lines.Append('Files are NOT identical!');
1: Memo1.Lines.Append('Files opened, stream read exception raised!');
2: Memo1.Lines.Append('File does not exist!');
3: Memo1.Lines.Append('File open exception raised!');
end; // case
...
// StreamAreIdentical
function StreamsAreIdentical(var aError: Integer;
const aStream1, aStream2: TStream;
const aBlockSize: Integer = 4096): Boolean;
var
lBuffer1: array of byte;
lBuffer2: array of byte;
lBuffer1Readed,
lBuffer2Readed,
lBlockSize: integer;
begin
Result:=False;
aError:=0;
try
if aStream1.Size <> aStream2.Size
then Exit;
aStream1.Position:=0;
aStream2.Position:=0;
if aBlockSize>0
then lBlockSize:=aBlockSize
else lBlockSize:=4096;
SetLength(lBuffer1, lBlockSize);
SetLength(lBuffer2, lBlockSize);
lBuffer1Readed:=1; // just for entering while
while (lBuffer1Readed > 0) and (aStream1.Position < aStream1.Size) do
begin
lBuffer1Readed := aStream1.Read(lBuffer1[0], lBlockSize);
lBuffer2Readed := aStream2.Read(lBuffer2[0], lBlockSize);
if (lBuffer1Readed <> lBuffer2Readed) or ((lBuffer1Readed <> lBlockSize) and (aStream1.Position < aStream1.Size))
then Exit;
if not CompareMem(@lBuffer1[0], @lBuffer2[0], lBuffer1Readed)
then Exit;
end; // while
Result:=True;
except
aError:=1; // stream read exception
end;
end;
// FilesAreIdentical using function StreamsAreIdentical
function FilesAreIdentical(var aError: Integer;
const aFileName1, aFileName2: String;
const aBlockSize: Integer = 4096): Boolean;
var lFileStream1,
lFilestream2: TFileStream;
begin
Result:=False;
try
if not (FileExists(aFileName1) and FileExists(aFileName2))
then begin
aError:=2; // file not found
Exit;
end;
lFileStream1:=nil;
lFileStream2:=nil;
try
lFileStream1:=TfileStream.Create(aFileName1, fmOpenRead or fmShareDenyNone);
lFileStream2:=TFileStream.Create(aFileName2, fmOpenRead or fmShareDenyNone);
result:=StreamsAreIdentical(aError, lFileStream1, lFileStream2, aBlockSize);
finally
if lFileStream2<>nil
then lFileStream2.Free;
if lFileStream1<>nil
then lFileStream1.Free;
end; // finally
except
aError:=3; // file open exception
end; // except
end;