Qual é a forma canônica para fazer autoconf ligação em bibliotecas de rede do Solaris?
Pergunta
No Solaris, quando compilar um programa que usa soquetes, você precisa vinculá-lo com -lnsl -lsocket
. Muitos desses programas foram originalmente escritos para Linux (onde não são necessários bibliotecas extras), e, portanto, não verificar para essas bibliotecas em seus scripts de configuração, apesar de que é uma adição bastante simples. Algo parecido com isto (não testado):
AC_SEARCH_LIBS(gethostbyname, nsl, , AC_MSG_ERROR([gethostbyname not found]))
AC_SEARCH_LIBS(connect, socket, , AC_MSG_ERROR([connect not found]))
Existe uma maneira canônica de fazer essa verificação? Talvez até mesmo incluído na distribuição autoconf? Você poderia imaginar que há uma necessidade bastante difundida para isso, mas o Google não quis me dizer.
Solução
eu acho que o mais próximo de uma forma canônica para verificar isso é o AX_LIB_SOCKET_NSL
macro do Autoconf Arquivo :
# ===========================================================================
# http://www.nongnu.org/autoconf-archive/ax_lib_socket_nsl.html
# ===========================================================================
#
# SYNOPSIS
#
# AX_LIB_SOCKET_NSL
#
# DESCRIPTION
#
# This macro figures out what libraries are required on this platform to
# link sockets programs.
#
# The common cases are not to need any extra libraries, or to need
# -lsocket and -lnsl. We need to avoid linking with libnsl unless we need
# it, though, since on some OSes where it isn't necessary it will totally
# break networking. Unisys also includes gethostbyname() in libsocket but
# needs libnsl for socket().
#
# LICENSE
#
# Copyright (c) 2008 Russ Allbery <rra@stanford.edu>
# Copyright (c) 2008 Stepan Kasal <kasal@ucw.cz>
# Copyright (c) 2008 Warren Young <warren@etr-usa.com>
#
# Copying and distribution of this file, with or without modification, are
# permitted in any medium without royalty provided the copyright notice
# and this notice are preserved.
AU_ALIAS([LIB_SOCKET_NSL], [AX_LIB_SOCKET_NSL])
AC_DEFUN([AX_LIB_SOCKET_NSL],
[
AC_SEARCH_LIBS([gethostbyname], [nsl])
AC_SEARCH_LIBS([socket], [socket], [], [
AC_CHECK_LIB([socket], [socket], [LIBS="-lsocket -lnsl $LIBS"],
[], [-lnsl])])
])
Outras dicas
Não me lembro de qualquer código acabado fora do topo da minha cabeça, mas você geralmente deseja verificar se você pode vincular um programa de chamar a função gethostbyname()
sem libs extras em primeiro lugar. Só se isso falhar, você quiser tentar a biblioteca nsl
.
coisas semelhantes se aplicam, por exemplo, para a biblioteca m
.