Каков канонический способ сделать автоконфигурацию в сетевых библиотеках Solaris?

Question

В Solaris, когда вы компилируете программу, которая использует сокеты, вам нужно связать ее с -lnsl -lsocket . Многие такие программы изначально были написаны для Linux (где не нужны дополнительные библиотеки), и поэтому не проверяют эти библиотеки в своих скриптах configure, хотя это довольно простое дополнение. Примерно так (не проверено):

AC_SEARCH_LIBS(gethostbyname, nsl, , AC_MSG_ERROR([gethostbyname not found]))
AC_SEARCH_LIBS(connect, socket, , AC_MSG_ERROR([connect not found]))

Есть ли канонический способ сделать эту проверку? Может быть, даже включены в дистрибутив autoconf? Вы можете себе представить, что в этом есть достаточно распространенная потребность, но Google не сказал бы мне.

Answer 1

Я думаю, что наиболее близким к каноническим способом проверки этого является AX_LIB_SOCKET_NSL макрос из архива автоконфигурации :

# ===========================================================================
#        http://www.nongnu.org/autoconf-archive/ax_lib_socket_nsl.html
# ===========================================================================
#
# SYNOPSIS
#
#   AX_LIB_SOCKET_NSL
#
# DESCRIPTION
#
#   This macro figures out what libraries are required on this platform to
#   link sockets programs.
#
#   The common cases are not to need any extra libraries, or to need
#   -lsocket and -lnsl. We need to avoid linking with libnsl unless we need
#   it, though, since on some OSes where it isn't necessary it will totally
#   break networking. Unisys also includes gethostbyname() in libsocket but
#   needs libnsl for socket().
#
# LICENSE
#
#   Copyright (c) 2008 Russ Allbery <rra@stanford.edu>
#   Copyright (c) 2008 Stepan Kasal <kasal@ucw.cz>
#   Copyright (c) 2008 Warren Young <warren@etr-usa.com>
#
#   Copying and distribution of this file, with or without modification, are
#   permitted in any medium without royalty provided the copyright notice
#   and this notice are preserved.

AU_ALIAS([LIB_SOCKET_NSL], [AX_LIB_SOCKET_NSL])
AC_DEFUN([AX_LIB_SOCKET_NSL],
[
        AC_SEARCH_LIBS([gethostbyname], [nsl])
        AC_SEARCH_LIBS([socket], [socket], [], [
                AC_CHECK_LIB([socket], [socket], [LIBS="-lsocket -lnsl $LIBS"],
                [], [-lnsl])])
])

Answer 2

Я не могу вспомнить какой-либо готовый код на моей голове, но вы обычно хотите проверить, можете ли вы сначала связать программу, вызывающую функцию gethostbyname () , без каких-либо дополнительных библиотек. Только в случае сбоя вы можете попробовать библиотеку nsl .

Аналогичные вещи применимы, например, для библиотеки m .