Как обращаться с необработанными # 2044 ошибки от Flash TileList при изменении dataProvider?

Question

У меня есть компонент тильелита, используя пользовательский рендер на основе ImageCell. Я знаю, что иногда некоторые из изображений, которые он пытается получить, не будет найден, и я могу справиться с этим через слушатель IEORROR на пользовательском погрузчике ImageCell.

Однако, если я установлю поставщика данных, то он изменен, прежде чем все изображения выполнили их процесс загрузки или ошибки, проигрыватель Flash Debug выбрасывает необработанную ошибку # 2044 в Firefox, указав, что изображение не может быть найдено. В Opera с отладочной игрой он бросает # 2044, заявив, что нагрузка никогда не завершена.

Я не могу найти способ ловушки и игнорировать эти ошибки, чтобы они не бросали диалог отладчика. Кроме того, при использовании IDE Flash Builder IDE для отладки, отладчик не разбивается на этих ошибках вообще - только в игроке, пока я могу сломаться на других ошибках без проблем.

Как будто прослушиватель ошибок утилизируется при изменении DataProvider, но погрузчик продолжается и бросает необработанную # 2044.

Любые идеи о том, как обращаться с эффективелем? Заранее спасибо за ваше время и помощь -

b

Answer 1

В конструкторе вашего пользовательского визуализации элементов необходимо добавить слушатель событий в защищенный экземпляр LOUTED и обрабатывать ioError.

Вот пример:

package
{
    import fl.controls.listClasses.ICellRenderer;
    import fl.controls.listClasses.ImageCell;
    import fl.controls.TileList;
    import fl.data.DataProvider;
    import fl.managers.StyleManager;
    import flash.events.EventDispatcher;
    import flash.events.*;
    import fl.containers.UILoader;

    public class CustomImageCell extends ImageCell implements ICellRenderer
    {  

        public function CustomImageCell() 
        {
            super();

            //do other stuff here

            loader.scaleContent = false;
            loader.addEventListener(IOErrorEvent.IO_ERROR, handleErrorEvent, false, 0, true);

            useHandCursor = true;
        }

        override protected function drawLayout():void
        {
            var imagePadding:Number = getStyleValue("imagePadding") as Number;
            loader.move(11, 5);

            var w:Number = width-(imagePadding*2);
            var h:Number = height-imagePadding*2;
            if (loader.width != w && loader.height != h)
            {
                loader.setSize(w,h);
            }
            loader.drawNow(); // Force validation!

        }
        override protected function handleErrorEvent(event:IOErrorEvent):void {
            trace('ioError: ' + event);
            //dispatchEvent(event);
        }
    }
}

.

Вот простой тест, который я сделал, чтобы увидеть, что произойдет, когда поставщик данных обновляется:

import fl.controls.*;
import fl.data.DataProvider;
import fl.controls.listClasses.CellRenderer;

stage.scaleMode = StageScaleMode.NO_SCALE;
stage.align = StageAlign.TOP_LEFT;

var tileList:TileList = new TileList ();
tileList.move(220,40);
tileList.setSize(215, 400);
tileList.columnWidth = 215;
tileList.rowHeight = 86;
tileList.direction = ScrollBarDirection.VERTICAL;
tileList.setStyle("cellRenderer", CustomImageCell);
addChild(tileList);

tileList.dataProvider = getRandomDP(10);
setTimeout(resetDP,3000);

function resetDP():void {
    tileList.dataProvider = getRandomDP(10);
}
function getRandomDP(size:int):DataProvider {
    var result:DataProvider = new DataProvider();
    for(var i:int = 0; i < size; i++)   result.addItem({label:'item'+i,source:'wrong.url/'+Math.random()});
    return result;
}

.

HTH