gtkD:Минимальный пример рисунка?

Question

Я довольно опытный программист, но новичок в программировании графического интерфейса.Я пытаюсь перенести библиотеку построения графиков, которую я написал для DFL, в gtkD, но не могу отобразить рисунки.Следующий код создает для меня пустое окно.Может кто-нибудь сказать мне, что с ним не так, и/или опубликовать минимальный пример кода для ввода нескольких строк в файл? DrawingArea и отображение результатов в MainWindow?

import gtk.DrawingArea, gtk.Main, gtk.MainWindow, gdk.GC, gdk.Drawable,
    gdk.Color;

void main(string[] args) {
    Main.init(args);

    auto win = new MainWindow("Hello, world");
    win.setDefaultSize(800, 600);
    auto drawingArea = new DrawingArea(800, 600);
    win.add(drawingArea);
    drawingArea.realize();

    auto drawable = drawingArea.getWindow();
    auto gc = new GC(drawable);
    gc.setForeground(new Color(255, 0, 0));
    gc.setBackground(new Color(255, 255, 255));
    drawable.drawLine(gc, 0, 0, 100, 100);

    drawingArea.showAll();
    drawingArea.queueDraw();
    win.showAll();

    Main.run();
}

Answer 1

У меня нет никакого опыта работы с D, но много опыта в GTK, поэтому с помощью руководства по gtkD мне удалось взломать минимальный пример:

import gtk.DrawingArea, gtk.Main, gtk.MainWindow, gdk.GC, gdk.Drawable,
    gdk.Color, gtk.Widget;

class DrawingTest : MainWindow
{
    this()
    {
        super("Hello, world");
        setDefaultSize(800, 600);
        auto drawingArea = new DrawingArea(800, 600);
        add(drawingArea);
        drawingArea.addOnExpose(&drawStuff);
        showAll();
    }

    bool drawStuff(GdkEventExpose *event, Widget self) 
    {
        auto drawable = self.getWindow();
        auto gc = new GC(drawable);
        gc.setForeground(new Color(cast(ubyte)255, cast(ubyte)0, cast(ubyte)0));
        gc.setBackground(new Color(cast(ubyte)255, cast(ubyte)255, cast(ubyte)255));
        drawable.drawLine(gc, 0, 0, 100, 100);
        return true;
    }
}

void main(string[] args) {
    Main.init(args);
    new DrawingTest();
    Main.run();
}

В ГТК DrawingArea на самом деле это просто пустой виджет, на котором вы можете рисовать, а рисование на виджетах всегда должно выполняться в expose-event обработчик.(Хотя я понимаю, что это изменится в GTK 3!)

Я понимаю, что вы не можете подключать функции как обратные вызовы сигналов, а только делегаты, поэтому в этом причина DrawingTest сорт.