تحديد ما إذا كان الكائن عضوًا في مجموعة في VBA
-
02-07-2019 - |
سؤال
كيف يمكنني تحديد ما إذا كان الكائن عضوًا في مجموعة في VBA؟
على وجه التحديد، أحتاج إلى معرفة ما إذا كان تعريف الجدول عضوًا في TableDefs
مجموعة.
المحلول
أفضل رهان لك هو التكرار على أعضاء المجموعة ومعرفة ما إذا كان أي منهم يطابق ما تبحث عنه.ثق بي لقد اضطررت إلى القيام بذلك عدة مرات.
الحل الثاني (وهو الأسوأ بكثير) هو اكتشاف الخطأ "العنصر ليس في المجموعة" ثم تعيين علامة للإشارة إلى أن العنصر غير موجود.
نصائح أخرى
أليست جيدة بما فيه الكفاية؟
Public Function Contains(col As Collection, key As Variant) As Boolean
Dim obj As Variant
On Error GoTo err
Contains = True
obj = col(key)
Exit Function
err:
Contains = False
End Function
لم يكن الحل أنيقًا تمامًا، ولكن الحل الأفضل (والأسرع) الذي تمكنت من العثور عليه هو استخدام OnError.سيكون هذا أسرع بكثير من التكرار لأي مجموعة متوسطة إلى كبيرة.
Public Function InCollection(col As Collection, key As String) As Boolean
Dim var As Variant
Dim errNumber As Long
InCollection = False
Set var = Nothing
Err.Clear
On Error Resume Next
var = col.Item(key)
errNumber = CLng(Err.Number)
On Error GoTo 0
'5 is not in, 0 and 438 represent incollection
If errNumber = 5 Then ' it is 5 if not in collection
InCollection = False
Else
InCollection = True
End If
End Function
هذا سؤال قديم.لقد قمت بمراجعة جميع الإجابات والتعليقات بعناية، واختبرت الحلول من حيث الأداء.
لقد توصلت إلى الخيار الأسرع لبيئتي والذي لا يفشل عندما تحتوي المجموعة على كائنات بالإضافة إلى العناصر الأولية.
Public Function ExistsInCollection(col As Collection, key As Variant) As Boolean
On Error GoTo err
ExistsInCollection = True
IsObject(col.item(key))
Exit Function
err:
ExistsInCollection = False
End Function
بالإضافة إلى ذلك، لا يعتمد هذا الحل على قيم الخطأ المرمزة.لذلك المعلمة col As Collection
يمكن استبداله بمتغير آخر من نوع المجموعة، ويجب أن تظل الوظيفة تعمل.على سبيل المثال، في مشروعي الحالي، سأحصل عليه كما هو col As ListColumns
.
لقد قمت بإنشاء هذا الحل من الاقتراحات المذكورة أعلاه الممزوجة بحل Microsoft للتكرار من خلال مجموعة.
Public Function InCollection(col As Collection, Optional vItem, Optional vKey) As Boolean
On Error Resume Next
Dim vColItem As Variant
InCollection = False
If Not IsMissing(vKey) Then
col.item vKey
'5 if not in collection, it is 91 if no collection exists
If Err.Number <> 5 And Err.Number <> 91 Then
InCollection = True
End If
ElseIf Not IsMissing(vItem) Then
For Each vColItem In col
If vColItem = vItem Then
InCollection = True
GoTo Exit_Proc
End If
Next vColItem
End If
Exit_Proc:
Exit Function
Err_Handle:
Resume Exit_Proc
End Function
يمكنك اختصار الكود المقترح لهذا بالإضافة إلى التعميم على الأخطاء غير المتوقعة.ها أنت ذا:
Public Function InCollection(col As Collection, key As String) As Boolean
On Error GoTo incol
col.Item key
incol:
InCollection = (Err.Number = 0)
End Function
في حالتك المحددة (TableDefs)، يعد التكرار على المجموعة والتحقق من الاسم أسلوبًا جيدًا.هذا أمر جيد لأن مفتاح المجموعة (الاسم) هو خاصية للفئة الموجودة في المجموعة.
ولكن في الحالة العامة لمجموعات VBA، لن يكون المفتاح بالضرورة جزءًا من الكائن الموجود في المجموعة (على سبيل المثال.من الممكن أن تستخدم مجموعة كقاموس، بمفتاح لا علاقة له بالكائن الموجود في المجموعة).في هذه الحالة، ليس لديك خيار سوى محاولة الوصول إلى العنصر ورصد الخطأ.
لدي بعض التعديلات، أفضل عمل للمجموعات:
Public Function Contains(col As collection, key As Variant) As Boolean
Dim obj As Object
On Error GoTo err
Contains = True
Set obj = col.Item(key)
Exit Function
err:
Contains = False
End Function
يعمل هذا الإصدار مع الأنواع البدائية والفئات (يتضمن طريقة اختبار قصيرة)
' TODO: change this to the name of your module
Private Const sMODULE As String = "MVbaUtils"
Public Function ExistsInCollection(oCollection As Collection, sKey As String) As Boolean
Const scSOURCE As String = "ExistsInCollection"
Dim lErrNumber As Long
Dim sErrDescription As String
lErrNumber = 0
sErrDescription = "unknown error occurred"
Err.Clear
On Error Resume Next
' note: just access the item - no need to assign it to a dummy value
' and this would not be so easy, because we would need different
' code depending on the type of object
' e.g.
' Dim vItem as Variant
' If VarType(oCollection.Item(sKey)) = vbObject Then
' Set vItem = oCollection.Item(sKey)
' Else
' vItem = oCollection.Item(sKey)
' End If
oCollection.Item sKey
lErrNumber = CLng(Err.Number)
sErrDescription = Err.Description
On Error GoTo 0
If lErrNumber = 5 Then ' 5 = not in collection
ExistsInCollection = False
ElseIf (lErrNumber = 0) Then
ExistsInCollection = True
Else
' Re-raise error
Err.Raise lErrNumber, mscMODULE & ":" & scSOURCE, sErrDescription
End If
End Function
Private Sub Test_ExistsInCollection()
Dim asTest As New Collection
Debug.Assert Not ExistsInCollection(asTest, "")
Debug.Assert Not ExistsInCollection(asTest, "xx")
asTest.Add "item1", "key1"
asTest.Add "item2", "key2"
asTest.Add New Collection, "key3"
asTest.Add Nothing, "key4"
Debug.Assert ExistsInCollection(asTest, "key1")
Debug.Assert ExistsInCollection(asTest, "key2")
Debug.Assert ExistsInCollection(asTest, "key3")
Debug.Assert ExistsInCollection(asTest, "key4")
Debug.Assert Not ExistsInCollection(asTest, "abcx")
Debug.Print "ExistsInCollection is okay"
End Sub
يتطلب الأمر بعض التعديلات الإضافية في حالة أن العناصر الموجودة في المجموعة ليست كائنات، بل مصفوفات.بخلاف ذلك كان يعمل بشكل جيد بالنسبة لي.
Public Function CheckExists(vntIndexKey As Variant) As Boolean
On Error Resume Next
Dim cObj As Object
' just get the object
Set cObj = mCol(vntIndexKey)
' here's the key! Trap the Error Code
' when the error code is 5 then the Object is Not Exists
CheckExists = (Err <> 5)
' just to clear the error
If Err <> 0 Then Call Err.Clear
Set cObj = Nothing
End Function
مصدر: http://coderstalk.blogspot.com/2007/09/visual-basic-programming-how-to-check.html
في حالة عدم استخدام المفتاح للتجميع:
Public Function Contains(col As Collection, thisItem As Variant) As Boolean
Dim item As Variant
Contains = False
For Each item In col
If item = thisItem Then
Contains = True
Exit Function
End If
Next
End Function
ليس الكود الخاص بي، ولكن أعتقد أنه مكتوب بشكل جيد جدًا.فهو يسمح بالتحقق من خلال المفتاح وكذلك من خلال عنصر الكائن نفسه ويتعامل مع كل من طريقة On Error والتكرار عبر جميع عناصر المجموعة.
https://danwagner.co/how-to-check-if-a-collection-contains-an-object/
لن أنسخ الشرح الكامل لأنه موجود على الصفحة المرتبطة.يتم نسخ الحل نفسه في حالة عدم توفر الصفحة في المستقبل في المستقبل.
الشك الذي لدي بشأن الكود هو الإفراط في استخدام GoTo في كتلة If الأولى ولكن من السهل إصلاح ذلك لأي شخص لذا سأترك الكود الأصلي كما هو.
'''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''
'INPUT : Kollection, the collection we would like to examine
' : (Optional) Key, the Key we want to find in the collection
' : (Optional) Item, the Item we want to find in the collection
'OUTPUT : True if Key or Item is found, False if not
'SPECIAL CASE: If both Key and Item are missing, return False
Option Explicit
Public Function CollectionContains(Kollection As Collection, Optional Key As Variant, Optional Item As Variant) As Boolean
Dim strKey As String
Dim var As Variant
'First, investigate assuming a Key was provided
If Not IsMissing(Key) Then
strKey = CStr(Key)
'Handling errors is the strategy here
On Error Resume Next
CollectionContains = True
var = Kollection(strKey) '<~ this is where our (potential) error will occur
If Err.Number = 91 Then GoTo CheckForObject
If Err.Number = 5 Then GoTo NotFound
On Error GoTo 0
Exit Function
CheckForObject:
If IsObject(Kollection(strKey)) Then
CollectionContains = True
On Error GoTo 0
Exit Function
End If
NotFound:
CollectionContains = False
On Error GoTo 0
Exit Function
'If the Item was provided but the Key was not, then...
ElseIf Not IsMissing(Item) Then
CollectionContains = False '<~ assume that we will not find the item
'We have to loop through the collection and check each item against the passed-in Item
For Each var In Kollection
If var = Item Then
CollectionContains = True
Exit Function
End If
Next var
'Otherwise, no Key OR Item was provided, so we default to False
Else
CollectionContains = False
End If
End Function
لقد فعلت ذلك على هذا النحو، وهو شكل مختلف من كود Vadims ولكن بالنسبة لي أكثر قابلية للقراءة:
' Returns TRUE if item is already contained in collection, otherwise FALSE
Public Function Contains(col As Collection, item As String) As Boolean
Dim i As Integer
For i = 1 To col.Count
If col.item(i) = item Then
Contains = True
Exit Function
End If
Next i
Contains = False
End Function
لقد كتبت هذا الرمز.أعتقد أنه يمكن أن يساعد شخص ما ...
Public Function VerifyCollection()
For i = 1 To 10 Step 1
MyKey = "A"
On Error GoTo KillError:
Dispersao.Add 1, MyKey
GoTo KeepInForLoop
KillError: 'If My collection already has the key A Then...
count = Dispersao(MyKey)
Dispersao.Remove (MyKey)
Dispersao.Add count + 1, MyKey 'Increase the amount in relationship with my Key
count = Dispersao(MyKey) 'count = new amount
On Error GoTo -1
KeepInForLoop:
Next
End Function