Determinare se un oggetto è un membro di una raccolta in VBA
-
02-07-2019 - |
Domanda
Come posso determinare se un oggetto è un membro di una raccolta in VBA?
In particolare, devo scoprire se una definizione di tabella è un membro della raccolta TableDefs
.
Soluzione
La tua scommessa migliore è quella di scorrere i membri della collezione e vedere se c'è qualcosa che cerchi. Fidati di me, ho dovuto farlo molte volte.
La seconda soluzione (che è molto peggio) è quella di catturare l'articolo non in collezione " errore e quindi impostare un flag per dire che l'elemento non esiste.
Altri suggerimenti
Non è abbastanza buono?
Public Function Contains(col As Collection, key As Variant) As Boolean
Dim obj As Variant
On Error GoTo err
Contains = True
obj = col(key)
Exit Function
err:
Contains = False
End Function
Non esattamente elegante, ma la soluzione migliore (e più veloce) che ho trovato è stata usare OnError. Questo sarà significativamente più veloce dell'iterazione per qualsiasi raccolta di dimensioni medio-grandi.
Public Function InCollection(col As Collection, key As String) As Boolean
Dim var As Variant
Dim errNumber As Long
InCollection = False
Set var = Nothing
Err.Clear
On Error Resume Next
var = col.Item(key)
errNumber = CLng(Err.Number)
On Error GoTo 0
'5 is not in, 0 and 438 represent incollection
If errNumber = 5 Then ' it is 5 if not in collection
InCollection = False
Else
InCollection = True
End If
End Function
Questa è una vecchia domanda. Ho esaminato attentamente tutte le risposte e i commenti, testato le soluzioni per le prestazioni.
Mi è venuta in mente l'opzione più veloce per il mio ambiente, che non fallisce quando una collezione ha oggetti e primitive.
Public Function ExistsInCollection(col As Collection, key As Variant) As Boolean
On Error GoTo err
ExistsInCollection = True
IsObject(col.item(key))
Exit Function
err:
ExistsInCollection = False
End Function
Inoltre, questa soluzione non dipende da valori di errore codificati. Quindi il parametro col As Collection
può essere sostituito da qualche altra variabile del tipo di raccolta e la funzione deve ancora funzionare. Ad esempio, sul mio progetto attuale, lo avrò come col As ListColumns
.
Ho creato questa soluzione dai suggerimenti di cui sopra mescolati con la soluzione di microsoft per iterare attraverso una raccolta.
Public Function InCollection(col As Collection, Optional vItem, Optional vKey) As Boolean
On Error Resume Next
Dim vColItem As Variant
InCollection = False
If Not IsMissing(vKey) Then
col.item vKey
'5 if not in collection, it is 91 if no collection exists
If Err.Number <> 5 And Err.Number <> 91 Then
InCollection = True
End If
ElseIf Not IsMissing(vItem) Then
For Each vColItem In col
If vColItem = vItem Then
InCollection = True
GoTo Exit_Proc
End If
Next vColItem
End If
Exit_Proc:
Exit Function
Err_Handle:
Resume Exit_Proc
End Function
Puoi abbreviare il codice suggerito per questo e generalizzare per errori imprevisti. Ecco qua:
Public Function InCollection(col As Collection, key As String) As Boolean
On Error GoTo incol
col.Item key
incol:
InCollection = (Err.Number = 0)
End Function
Nel tuo caso specifico (TableDefs) l'iterazione sulla raccolta e la verifica del nome è un buon approccio. Questo è OK perché la chiave per la raccolta (Nome) è una proprietà della classe nella raccolta.
Ma nel caso generale delle raccolte VBA, la chiave non farà necessariamente parte dell'oggetto nella raccolta (ad es. potresti usare una raccolta come dizionario, con una chiave che non ha nulla a che fare con l'oggetto nella collezione). In questo caso, non hai altra scelta che provare ad accedere all'elemento e rilevare l'errore.
Ho alcune modifiche, il migliore per le raccolte:
Public Function Contains(col As collection, key As Variant) As Boolean
Dim obj As Object
On Error GoTo err
Contains = True
Set obj = col.Item(key)
Exit Function
err:
Contains = False
End Function
questa versione funziona per tipi primitivi e per classi (metodo di prova breve incluso)
' TODO: change this to the name of your module
Private Const sMODULE As String = "MVbaUtils"
Public Function ExistsInCollection(oCollection As Collection, sKey As String) As Boolean
Const scSOURCE As String = "ExistsInCollection"
Dim lErrNumber As Long
Dim sErrDescription As String
lErrNumber = 0
sErrDescription = "unknown error occurred"
Err.Clear
On Error Resume Next
' note: just access the item - no need to assign it to a dummy value
' and this would not be so easy, because we would need different
' code depending on the type of object
' e.g.
' Dim vItem as Variant
' If VarType(oCollection.Item(sKey)) = vbObject Then
' Set vItem = oCollection.Item(sKey)
' Else
' vItem = oCollection.Item(sKey)
' End If
oCollection.Item sKey
lErrNumber = CLng(Err.Number)
sErrDescription = Err.Description
On Error GoTo 0
If lErrNumber = 5 Then ' 5 = not in collection
ExistsInCollection = False
ElseIf (lErrNumber = 0) Then
ExistsInCollection = True
Else
' Re-raise error
Err.Raise lErrNumber, mscMODULE & ":" & scSOURCE, sErrDescription
End If
End Function
Private Sub Test_ExistsInCollection()
Dim asTest As New Collection
Debug.Assert Not ExistsInCollection(asTest, "")
Debug.Assert Not ExistsInCollection(asTest, "xx")
asTest.Add "item1", "key1"
asTest.Add "item2", "key2"
asTest.Add New Collection, "key3"
asTest.Add Nothing, "key4"
Debug.Assert ExistsInCollection(asTest, "key1")
Debug.Assert ExistsInCollection(asTest, "key2")
Debug.Assert ExistsInCollection(asTest, "key3")
Debug.Assert ExistsInCollection(asTest, "key4")
Debug.Assert Not ExistsInCollection(asTest, "abcx")
Debug.Print "ExistsInCollection is okay"
End Sub
Richiede alcune regolazioni aggiuntive nel caso in cui gli elementi nella raccolta non siano Oggetti, ma Matrici. A parte questo, ha funzionato bene per me.
Public Function CheckExists(vntIndexKey As Variant) As Boolean
On Error Resume Next
Dim cObj As Object
' just get the object
Set cObj = mCol(vntIndexKey)
' here's the key! Trap the Error Code
' when the error code is 5 then the Object is Not Exists
CheckExists = (Err <> 5)
' just to clear the error
If Err <> 0 Then Call Err.Clear
Set cObj = Nothing
End Function
Fonte: http: //coderstalk.blogspot.com/2007/09/visual-basic-programming-how-to-check.html
Nel caso in cui la chiave non sia utilizzata per la raccolta:
Public Function Contains(col As Collection, thisItem As Variant) As Boolean
Dim item As Variant
Contains = False
For Each item In col
If item = thisItem Then
Contains = True
Exit Function
End If
Next
End Function
Non è il mio codice, ma penso che sia abbastanza ben scritto. Permette di controllare sia dalla chiave che dall'elemento Oggetto stesso e gestisce sia il metodo On Error che iterando tutti gli elementi Collection.
https://danwagner.co/ how-to-check-se-a-raccolta-contiene-un-oggetto /
Non copierò la spiegazione completa poiché è disponibile nella pagina collegata. La soluzione stessa viene copiata nel caso in cui la pagina alla fine non sarà disponibile in futuro.
Il dubbio che ho sul codice è l'overusage di GoTo nel primo blocco If, ma è facile da risolvere per chiunque, quindi lascio il codice originale così com'è.
'''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''
'INPUT : Kollection, the collection we would like to examine
' : (Optional) Key, the Key we want to find in the collection
' : (Optional) Item, the Item we want to find in the collection
'OUTPUT : True if Key or Item is found, False if not
'SPECIAL CASE: If both Key and Item are missing, return False
Option Explicit
Public Function CollectionContains(Kollection As Collection, Optional Key As Variant, Optional Item As Variant) As Boolean
Dim strKey As String
Dim var As Variant
'First, investigate assuming a Key was provided
If Not IsMissing(Key) Then
strKey = CStr(Key)
'Handling errors is the strategy here
On Error Resume Next
CollectionContains = True
var = Kollection(strKey) '<~ this is where our (potential) error will occur
If Err.Number = 91 Then GoTo CheckForObject
If Err.Number = 5 Then GoTo NotFound
On Error GoTo 0
Exit Function
CheckForObject:
If IsObject(Kollection(strKey)) Then
CollectionContains = True
On Error GoTo 0
Exit Function
End If
NotFound:
CollectionContains = False
On Error GoTo 0
Exit Function
'If the Item was provided but the Key was not, then...
ElseIf Not IsMissing(Item) Then
CollectionContains = False '<~ assume that we will not find the item
'We have to loop through the collection and check each item against the passed-in Item
For Each var In Kollection
If var = Item Then
CollectionContains = True
Exit Function
End If
Next var
'Otherwise, no Key OR Item was provided, so we default to False
Else
CollectionContains = False
End If
End Function
L'ho fatto in questo modo, una variazione del codice di Vadims ma per me un po 'più leggibile:
' Returns TRUE if item is already contained in collection, otherwise FALSE
Public Function Contains(col As Collection, item As String) As Boolean
Dim i As Integer
For i = 1 To col.Count
If col.item(i) = item Then
Contains = True
Exit Function
End If
Next i
Contains = False
End Function
Ho scritto questo codice. Immagino che possa aiutare qualcuno ...
Public Function VerifyCollection()
For i = 1 To 10 Step 1
MyKey = "A"
On Error GoTo KillError:
Dispersao.Add 1, MyKey
GoTo KeepInForLoop
KillError: 'If My collection already has the key A Then...
count = Dispersao(MyKey)
Dispersao.Remove (MyKey)
Dispersao.Add count + 1, MyKey 'Increase the amount in relationship with my Key
count = Dispersao(MyKey) 'count = new amount
On Error GoTo -1
KeepInForLoop:
Next
End Function