Déterminer si un objet est membre d'une collection dans VBA

StackOverflow https://stackoverflow.com/questions/137845

Question

Comment déterminer si un objet est membre d'une collection dans VBA?

Plus précisément, je dois savoir si une définition de table est membre de la collection TableDefs .

Était-ce utile?

La solution

Votre meilleur choix est de parcourir les membres de la collection et de voir s’ils correspondent à ce que vous recherchez. Croyez-moi, j'ai dû le faire plusieurs fois.

La deuxième solution (qui est bien pire) consiste à attraper le "Article non en collection". erreur et ensuite définir un drapeau pour dire que l'élément n'existe pas.

Autres conseils

N'est-ce pas assez bon? 

Public Function Contains(col As Collection, key As Variant) As Boolean
Dim obj As Variant
On Error GoTo err
    Contains = True
    obj = col(key)
    Exit Function
err:

    Contains = False
End Function

Pas tout à fait élégant, mais la meilleure solution (et la plus rapide) que j’ai pu trouver consistait à utiliser OnError. Ce sera beaucoup plus rapide que l'itération pour toute collection de taille moyenne à grande. 

Public Function InCollection(col As Collection, key As String) As Boolean
  Dim var As Variant
  Dim errNumber As Long

  InCollection = False
  Set var = Nothing

  Err.Clear
  On Error Resume Next
    var = col.Item(key)
    errNumber = CLng(Err.Number)
  On Error GoTo 0

  '5 is not in, 0 and 438 represent incollection
  If errNumber = 5 Then ' it is 5 if not in collection
    InCollection = False
  Else
    InCollection = True
  End If

End Function

C'est une vieille question. J'ai soigneusement examiné toutes les réponses et tous les commentaires, et testé les performances des solutions.

J'ai proposé l'option la plus rapide pour mon environnement, qui n'échoue pas lorsqu'une collection contient des objets ainsi que des primitives. 

Public Function ExistsInCollection(col As Collection, key As Variant) As Boolean
    On Error GoTo err
    ExistsInCollection = True
    IsObject(col.item(key))
    Exit Function
err:
    ExistsInCollection = False
End Function

De plus, cette solution ne dépend pas des valeurs d'erreur codées en dur. Ainsi, le paramètre col As Collection peut être remplacé par une autre variable de type collection, et la fonction doit toujours fonctionner. Par exemple, sur mon projet actuel, je l'aurai sous la forme col En tant que ListColumns .

J'ai créé cette solution à partir des suggestions ci-dessus mélangées à une solution microsofts ou pour une itération dans une collection. 

Public Function InCollection(col As Collection, Optional vItem, Optional vKey) As Boolean
On Error Resume Next

Dim vColItem As Variant

InCollection = False

If Not IsMissing(vKey) Then
    col.item vKey

    '5 if not in collection, it is 91 if no collection exists
    If Err.Number <> 5 And Err.Number <> 91 Then
        InCollection = True
    End If
ElseIf Not IsMissing(vItem) Then
    For Each vColItem In col
        If vColItem = vItem Then
            InCollection = True
            GoTo Exit_Proc
        End If
    Next vColItem
End If

Exit_Proc:
Exit Function
Err_Handle:
Resume Exit_Proc
End Function

Vous pouvez raccourcir le code suggéré et généraliser les erreurs inattendues. Ici vous allez: 

Public Function InCollection(col As Collection, key As String) As Boolean

  On Error GoTo incol
  col.Item key

incol:
  InCollection = (Err.Number = 0)

End Function

Dans votre cas spécifique (TableDefs), itérer sur la collection et vérifier le nom est une bonne approche. Ceci est correct car la clé de la collection (Nom) est une propriété de la classe de la collection.

Mais dans le cas général des collections VBA, la clé ne fera pas nécessairement partie de l'objet de la collection (vous pouvez par exemple utiliser une collection comme dictionnaire, avec une clé qui n'a rien à voir avec l'objet de la collection. collection). Dans ce cas, vous n'avez pas d'autre choix que d'essayer d'accéder à l'élément et de détecter l'erreur.

J'ai des modifications, fonctionnant mieux pour les collections: 

Public Function Contains(col As collection, key As Variant) As Boolean
    Dim obj As Object
    On Error GoTo err
    Contains = True
    Set obj = col.Item(key)
    Exit Function
    
err:
    Contains = False
End Function

cette version fonctionne pour les types primitifs et pour les classes (méthode de test courte incluse) 

' TODO: change this to the name of your module
Private Const sMODULE As String = "MVbaUtils"

Public Function ExistsInCollection(oCollection As Collection, sKey As String) As Boolean
    Const scSOURCE As String = "ExistsInCollection"

    Dim lErrNumber As Long
    Dim sErrDescription As String

    lErrNumber = 0
    sErrDescription = "unknown error occurred"
    Err.Clear
    On Error Resume Next
        ' note: just access the item - no need to assign it to a dummy value
        ' and this would not be so easy, because we would need different
        ' code depending on the type of object
        ' e.g.
        '   Dim vItem as Variant
        '   If VarType(oCollection.Item(sKey)) = vbObject Then
        '       Set vItem = oCollection.Item(sKey)
        '   Else
        '       vItem = oCollection.Item(sKey)
        '   End If
        oCollection.Item sKey
        lErrNumber = CLng(Err.Number)
        sErrDescription = Err.Description
    On Error GoTo 0

    If lErrNumber = 5 Then ' 5 = not in collection
        ExistsInCollection = False
    ElseIf (lErrNumber = 0) Then
        ExistsInCollection = True
    Else
        ' Re-raise error
        Err.Raise lErrNumber, mscMODULE & ":" & scSOURCE, sErrDescription
    End If
End Function

Private Sub Test_ExistsInCollection()
    Dim asTest As New Collection

    Debug.Assert Not ExistsInCollection(asTest, "")
    Debug.Assert Not ExistsInCollection(asTest, "xx")

    asTest.Add "item1", "key1"
    asTest.Add "item2", "key2"
    asTest.Add New Collection, "key3"
    asTest.Add Nothing, "key4"
    Debug.Assert ExistsInCollection(asTest, "key1")
    Debug.Assert ExistsInCollection(asTest, "key2")
    Debug.Assert ExistsInCollection(asTest, "key3")
    Debug.Assert ExistsInCollection(asTest, "key4")
    Debug.Assert Not ExistsInCollection(asTest, "abcx")

    Debug.Print "ExistsInCollection is okay"
End Sub

Des ajustements supplémentaires sont nécessaires si les éléments de la collection ne sont pas des objets, mais des tableaux. Autre que cela a bien fonctionné pour moi. 

Public Function CheckExists(vntIndexKey As Variant) As Boolean
    On Error Resume Next
    Dim cObj As Object

    ' just get the object
    Set cObj = mCol(vntIndexKey)

    ' here's the key! Trap the Error Code
    ' when the error code is 5 then the Object is Not Exists
    CheckExists = (Err <> 5)

    ' just to clear the error
    If Err <> 0 Then Call Err.Clear
    Set cObj = Nothing
End Function

Source: http: //coderstalk.blogspot.com/2007/09/visual-basic-programming-how-to-check.html

Pour le cas où la clé n'est pas utilisée pour la collecte: 

Public Function Contains(col As Collection, thisItem As Variant) As   Boolean

  Dim item As Variant

  Contains = False
  For Each item In col
    If item = thisItem Then
      Contains = True
      Exit Function
    End If
  Next
End Function

Ce n'est pas mon code, mais je pense que c'est assez bien écrit. Il permet de vérifier par la clé ainsi que par l'élément Object lui-même et gère à la fois la méthode On Error et l'itération de tous les éléments Collection.

https://danwagner.co/ comment-vérifier-si-une-collection-contient-un-objet /

Je ne copierai pas l'intégralité de l'explication car elle est disponible sur la page liée. Solution elle-même copiée au cas où la page ne serait plus disponible ultérieurement.

Le doute que j’ai sur le code est la surutilisation de GoTo dans le premier bloc If, mais c’est facile à corriger pour quiconque, je laisse donc le code original tel quel. 

'''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''
'INPUT       : Kollection, the collection we would like to examine
'            : (Optional) Key, the Key we want to find in the collection
'            : (Optional) Item, the Item we want to find in the collection
'OUTPUT      : True if Key or Item is found, False if not
'SPECIAL CASE: If both Key and Item are missing, return False
Option Explicit
Public Function CollectionContains(Kollection As Collection, Optional Key As Variant, Optional Item As Variant) As Boolean
    Dim strKey As String
    Dim var As Variant

    'First, investigate assuming a Key was provided
    If Not IsMissing(Key) Then

        strKey = CStr(Key)

        'Handling errors is the strategy here
        On Error Resume Next
            CollectionContains = True
            var = Kollection(strKey) '<~ this is where our (potential) error will occur
            If Err.Number = 91 Then GoTo CheckForObject
            If Err.Number = 5 Then GoTo NotFound
        On Error GoTo 0
        Exit Function

CheckForObject:
        If IsObject(Kollection(strKey)) Then
            CollectionContains = True
            On Error GoTo 0
            Exit Function
        End If

NotFound:
        CollectionContains = False
        On Error GoTo 0
        Exit Function

    'If the Item was provided but the Key was not, then...
    ElseIf Not IsMissing(Item) Then

        CollectionContains = False '<~ assume that we will not find the item

        'We have to loop through the collection and check each item against the passed-in Item
        For Each var In Kollection
            If var = Item Then
                CollectionContains = True
                Exit Function
            End If
        Next var

    'Otherwise, no Key OR Item was provided, so we default to False
    Else
        CollectionContains = False
    End If

End Function

Je l'ai fait comme ceci, une variation du code Vadims mais pour moi un peu plus lisible: 

' Returns TRUE if item is already contained in collection, otherwise FALSE

Public Function Contains(col As Collection, item As String) As Boolean

    Dim i As Integer

    For i = 1 To col.Count

    If col.item(i) = item Then
        Contains = True
        Exit Function
    End If

    Next i

    Contains = False

End Function

J'ai écrit ce code. Je suppose que cela peut aider quelqu'un ... 

Public Function VerifyCollection()
    For i = 1 To 10 Step 1
       MyKey = "A"
       On Error GoTo KillError:
       Dispersao.Add 1, MyKey
       GoTo KeepInForLoop
KillError: 'If My collection already has the key A Then...
        count = Dispersao(MyKey)
        Dispersao.Remove (MyKey)
        Dispersao.Add count + 1, MyKey 'Increase the amount in relationship with my Key
        count = Dispersao(MyKey) 'count = new amount
        On Error GoTo -1
KeepInForLoop:
    Next
End Function
Licencié sous: CC-BY-SA avec attribution
Non affilié à StackOverflow
scroll top