在将MUI2用于NSIS时，如何在MUI_WELCOME_PAGE中修改文本？

Question

我想在我正在使用MUI2的NSIS创建的安装程序中的欢迎屏幕中添加一个标签，该标签显示完整版本的弦乐。

我已经搜索了有关如何执行此操作的信息，但仅发现了使用MUI_INSTALLOPTIONS*的引用，我发现MUI2弃用了WS。另一个使用installoptions*带有相同选项的较新版本，但我无法正常工作。最终，我还发现了对此使用NSDialogs的引用 - 这是我在自定义页面上使用的内容。但是 - 我没有发现有关如何更改mui2.nsh随附的任何现有页面的参考或示例。

我找到了一种更改MUI_Headertext的方法，但这不会影响欢迎屏幕。我希望有一种方法也可以改变welcometext。也许使用MUI_WELCOMETITLE和MUI_WELCOMEBOBOD或类似。

Answer 1

有mui_welcomepage_text，但只有在要更改所有文本而不仅仅是附加内容时才有用。

在页面的显示功能期间，您可以更改任何控件的文本：

outfile test.exe
requestexecutionlevel user

!include MUI2.nsh

#!define MUI_WELCOMEPAGE_TEXT "New text goes here"
!define MUI_PAGE_CUSTOMFUNCTION_SHOW MyWelcomeShowCallback
!insertmacro MUI_PAGE_WELCOME
!insertmacro MUI_PAGE_INSTFILES
!insertmacro MUI_LANGUAGE "English"


Function MyWelcomeShowCallback
SendMessage $mui.WelcomePage.Text ${WM_SETTEXT} 0 "STR:$(MUI_TEXT_WELCOME_INFO_TEXT)$\n$\nVersion: foo.bar"
FunctionEnd

Section
SectionEnd

..或添加新控件：

outfile test.exe
requestexecutionlevel user

!include MUI2.nsh

!define MUI_PAGE_CUSTOMFUNCTION_SHOW MyWelcomeShowCallback
!insertmacro MUI_PAGE_WELCOME
!insertmacro MUI_PAGE_INSTFILES
!insertmacro MUI_LANGUAGE "English"


Function MyWelcomeShowCallback
${NSD_CreateLabel} 120u 150u 50% 12u "Version: foo.bar"
Pop $0
SetCtlColors $0 "" "${MUI_BGCOLOR}"
FunctionEnd

Section
SectionEnd