Come posso modificare il testo nella MUI_WELCOME_PAGE quando si utilizza MUI2 per NSIS?

Question

Voglio aggiungere un'etichetta che visualizza la versione completa-stringa nella schermata di benvenuto nel programma di installazione che sto creando con NSIS con MUI2.

Ho cercato informazioni su come fare questo, ma trova solo i riferimenti ad usare MUI_INSTALLOPTIONS * che ho trovato ws deprecati per MUI2. Un altro di cui le versioni più recenti che utilizzano InstallOptions * con le stesse opzioni, ma non ho potuto farlo funzionare. Alla fine ho trovato anche un riferimento a utilizzare nsDialogs per questo - che è quello che sto usando per le mie pagine personalizzate. Tuttavia -. Ho trovato alcun riferimento oi campioni su come modificare le pagine esistenti che viene fornito con MUI2.nsh

Ho trovato un modo per cambiare il MUI_HEADERTEXT, ma che non pregiudica l'accoglienza a schermo. Vorrei che ci fosse un modo per cambiare anche l'welcometext. Forse usando MUI_WELCOMETITLE e MUI_WELCOMEBODY o simili.

Answer 1

C'è MUI_WELCOMEPAGE_TEXT ma è utile solo se si desidera modificare tutto il testo e non basta aggiungere qualcosa.

Durante la funzione spettacolo per la pagina, è possibile modificare il testo di qualsiasi controllo:

outfile test.exe
requestexecutionlevel user

!include MUI2.nsh

#!define MUI_WELCOMEPAGE_TEXT "New text goes here"
!define MUI_PAGE_CUSTOMFUNCTION_SHOW MyWelcomeShowCallback
!insertmacro MUI_PAGE_WELCOME
!insertmacro MUI_PAGE_INSTFILES
!insertmacro MUI_LANGUAGE "English"


Function MyWelcomeShowCallback
SendMessage $mui.WelcomePage.Text ${WM_SETTEXT} 0 "STR:$(MUI_TEXT_WELCOME_INFO_TEXT)$\n$\nVersion: foo.bar"
FunctionEnd

Section
SectionEnd

.. o aggiungere un nuovo controllo:

outfile test.exe
requestexecutionlevel user

!include MUI2.nsh

!define MUI_PAGE_CUSTOMFUNCTION_SHOW MyWelcomeShowCallback
!insertmacro MUI_PAGE_WELCOME
!insertmacro MUI_PAGE_INSTFILES
!insertmacro MUI_LANGUAGE "English"


Function MyWelcomeShowCallback
${NSD_CreateLabel} 120u 150u 50% 12u "Version: foo.bar"
Pop $0
SetCtlColors $0 "" "${MUI_BGCOLOR}"
FunctionEnd

Section
SectionEnd