Wie kann ich den Text in der mui_welcome_page ändern, wenn ich MUI2 für NSIS verwende?

Question

Ich möchte ein Etikett hinzufügen, das die Vollversionsstring im Begrüßungsbildschirm im Installationsprogramm zeigt, das ich mit NSIS mit MUI2 erstelle.

Ich habe nach Informationen dazu gesucht, wie dies zu tun ist, aber nur Referenzen zur Verwendung von mui_installoptions* gefunden, die ich für MUI2 veraltet fand. Ein anderer bezog sich auf die neueren Versionen, die Installoptionen* mit denselben Optionen verwenden, aber ich konnte es nicht zum Laufen bringen. Ich habe schließlich auch einen Verweis auf die Verwendung von NSDIALOGS dafür gefunden - was ich für meine benutzerdefinierten Seiten verwende. Ich habe jedoch keine Referenz oder Stichproben gefunden, wie man die vorhandenen Seiten, die mit MUI2.NSH geliefert werden, geändert werden.

Ich habe einen Weg gefunden, den MUI_HeaderText zu ändern, aber das hat keinen Einfluss auf den Begrüßungsbildschirm. Ich wünschte, es gäbe eine Möglichkeit, auch den Welcometext zu ändern. Vielleicht verwenden Sie mui_welcometitle und mui_welcomeBody oder ähnliches.

Answer 1

Es gibt mui_welcomePage_text, aber es ist nur nützlich, wenn Sie den gesamten Text ändern und nicht nur etwas anhängen möchten.

Während der Show -Funktion für die Seite können Sie den Text einer beliebigen Steuerung ändern:

outfile test.exe
requestexecutionlevel user

!include MUI2.nsh

#!define MUI_WELCOMEPAGE_TEXT "New text goes here"
!define MUI_PAGE_CUSTOMFUNCTION_SHOW MyWelcomeShowCallback
!insertmacro MUI_PAGE_WELCOME
!insertmacro MUI_PAGE_INSTFILES
!insertmacro MUI_LANGUAGE "English"


Function MyWelcomeShowCallback
SendMessage $mui.WelcomePage.Text ${WM_SETTEXT} 0 "STR:$(MUI_TEXT_WELCOME_INFO_TEXT)$\n$\nVersion: foo.bar"
FunctionEnd

Section
SectionEnd

..or eine neue Kontrolle hinzufügen:

outfile test.exe
requestexecutionlevel user

!include MUI2.nsh

!define MUI_PAGE_CUSTOMFUNCTION_SHOW MyWelcomeShowCallback
!insertmacro MUI_PAGE_WELCOME
!insertmacro MUI_PAGE_INSTFILES
!insertmacro MUI_LANGUAGE "English"


Function MyWelcomeShowCallback
${NSD_CreateLabel} 120u 150u 50% 12u "Version: foo.bar"
Pop $0
SetCtlColors $0 "" "${MUI_BGCOLOR}"
FunctionEnd

Section
SectionEnd