您可以根据 if 语句扩展 sumifs 公式吗?
-
21-12-2019 - |
题
我想知道是否可以根据 IF 语句扩展 SUMIFS 公式。
在下面的示例中,我想要的是如果 $O$5 = 0,则扩展 SUMIFS 公式,使“>0”成为 criteria1,然后创建一个新的 criteria_range2,其中“<10”作为 criteria2。
看看“评估公式”,我不确定问题是否在于它不会读取扩展位,因为不可能这样做,或者 CHAR(34) 是否没有按我希望的那样显示。
=SUMIFS('收入'!$G$1:$G$100,'收入'!$H$1:$H$100,IF($O$5=0,CHAR(34)&">0"&CHAR(34)&" ,"&"'收入'!$H$1:$H$100"&","&CHAR(34)&"<10"&CHAR(34),$O$5))
任何帮助将非常感激!谢谢!
解决方案
如果您想使用 SUMIFs
, ,它应该是这样的:
方式1
=SUMIFS(Revenue!$G$1:$G$100,Revenue!$H$1:$H$100,IF($O$5=0,">0",$O$5),
Revenue!$H$1:$H$100,IF($O$5=0,"<10",$O$5)
)
如果 O5=0
, ,公式计算结果为:
=SUMIFS(Revenue!$G$1:$G$100,Revenue!$H$1:$H$100,">0",
Revenue!$H$1:$H$100,"<10"
)
如果 O5<>0
, ,公式计算结果为:
=SUMIFS(Revenue!$G$1:$G$100,Revenue!$H$1:$H$100,$O$5,
Revenue!$H$1:$H$100,$O$5
)
这实际上给你相同的结果
=SUMIFS(Revenue!$G$1:$G$100,Revenue!$H$1:$H$100,$O$5)
方式2
=IF($O$5=0,
SUMIFs(Revenue!$G$1:$G$100,Revenue!$H$1:$H$100,">0",
Revenue!$H$1:$H$100,"<10"),
SUMIFs(Revenue!$G$1:$G$100,Revenue!$H$1:$H$100,$O$5)
)
如果 O5=0
, ,公式计算结果为:
=SUMIFS(Revenue!$G$1:$G$100,Revenue!$H$1:$H$100,">0",
Revenue!$H$1:$H$100,"<10"
)
如果 O5<>0
, ,公式计算结果为:
=SUMIFS(Revenue!$G$1:$G$100,Revenue!$H$1:$H$100,$O$5)
方式 3
或者您也可以使用 sumproduct:
=SUMPRODUCT((Revenue!$G$1:$G$100)*
IF($O$5=0,(Revenue!$H$1:$H$100>0)*(Revenue!$H$1:$H$100<10),
(Revenue!$H$1:$H$100=$O$5)
)
)
这是一 数组公式, ,因此输入公式然后按 控制键+转移+进入. 。大括号将自动出现在公式的开头和结尾处。
如果 O5=0
, ,公式计算结果为:
=SUMPRODUCT((Revenue!$G$1:$G$100)*(Revenue!$H$1:$H$100>0)*
(Revenue!$H$1:$H$100<10)
)
如果 O5<>0
, ,公式计算结果为:
=SUMPRODUCT((Revenue!$G$1:$G$100)*(Revenue!$H$1:$H$100=$O$5))
不隶属于 StackOverflow