Puoi estendere una formula Sumifs dipendente da una dichiarazione se?

Question

Mi chiedo se è possibile estendere una formula di Sumifs dipendente da un'istruzione IF.

Nell'esempio seguente, quello che voglio è se $ o $ 5= 0, per estendere la formula di Sumifs in modo che il "> 0" diventa criterio1 e quindi un nuovo criterio_range2 viene creato, con "<10" come criterio2. .

Guardando a "Valutare la formula", non sono sicuro se il problema è che non leggerà il bit esteso perché non è possibile farlo, o se il Char (34) non si presentanoCome speravo.

.

= Sumifs ('Entrate'! $ G $ 1: $ G $ 100, 'Entrate'! $ H $ 1: $ H $ 100, se ($ o $ 5= 0, CHAR (34) & "> 0" & Char (34)) & "," & "'Ricavi'! $ H $ 1: $ H $ 100" & "," & char (34) & "<10" & char (34), $ o $ 5))

Qualsiasi aiuto sarebbe molto apprezzato!Grazie!

Answer 1

Se desideri utilizzare SUMIFs, dovrebbe essere qualcosa del genere:

way №1

=SUMIFS(Revenue!$G$1:$G$100,Revenue!$H$1:$H$100,IF($O$5=0,">0",$O$5),
                            Revenue!$H$1:$H$100,IF($O$5=0,"<10",$O$5)
 )

.

Se O5=0, Formula valuta:

=SUMIFS(Revenue!$G$1:$G$100,Revenue!$H$1:$H$100,">0",
                            Revenue!$H$1:$H$100,"<10"
 )

.

Se O5<>0, Formula valuta:

=SUMIFS(Revenue!$G$1:$G$100,Revenue!$H$1:$H$100,$O$5,
                            Revenue!$H$1:$H$100,$O$5
 )

.

che è in realtà ti dà lo stesso risultato di

=SUMIFS(Revenue!$G$1:$G$100,Revenue!$H$1:$H$100,$O$5)

.

---

.

way №2

=IF($O$5=0,
  SUMIFs(Revenue!$G$1:$G$100,Revenue!$H$1:$H$100,">0",
                             Revenue!$H$1:$H$100,"<10"),
  SUMIFs(Revenue!$G$1:$G$100,Revenue!$H$1:$H$100,$O$5)
 )

.

Se O5=0, Formula valuta:

=SUMIFS(Revenue!$G$1:$G$100,Revenue!$H$1:$H$100,">0",
                            Revenue!$H$1:$H$100,"<10"
 )

.

Se O5<>0, Formula valuta:

=SUMIFS(Revenue!$G$1:$G$100,Revenue!$H$1:$H$100,$O$5)

.

---

.

way №3

o puoi usare anche SumProduct:

=SUMPRODUCT((Revenue!$G$1:$G$100)*
            IF($O$5=0,(Revenue!$H$1:$H$100>0)*(Revenue!$H$1:$H$100<10),
                      (Revenue!$H$1:$H$100=$O$5)
            )
 )

.

Questa è una formula di array , quindi digita la formula quindi premere ctrl + shift + immettere . Le staffe ricci appariranno automaticamente all'inizio e alla fine della formula.

Se O5=0, Formula valuta:

=SUMPRODUCT((Revenue!$G$1:$G$100)*(Revenue!$H$1:$H$100>0)*
                                  (Revenue!$H$1:$H$100<10)
 )

.

Se O5<>0, Formula valuta:

=SUMPRODUCT((Revenue!$G$1:$G$100)*(Revenue!$H$1:$H$100=$O$5))

.