Pouvez-vous étendre un sumifs formule dépend d'une instruction if?

Question

Je me demandais si il est possible d'étendre une SUMIFS formule dépend de l'instruction if.

Dans l'exemple ci-dessous, ce que je veux, c'est si $O$5 = 0, d'étendre la SUMIFS formule de l' ">0" devient criteria1 et puis un nouveau criteria_range2 est créé, avec "<10" comme criteria2.

En regardant "évaluer la formule', je ne sais pas si le problème est qu'il ne sera pas lu l'étendue peu, parce qu'il n'est pas possible de le faire, ou si le CHAR(34) ne se montrent pas comme je l'espérais.

=SUMIFS('Revenue'!$G$1:$G$100,'Revenue'!$H$1:$H$100,IF($O$5=0,CHAR(34)&">0"&CHAR(34)&","&"'Revenue'!$H$1:$H$100"&","&CHAR(34)&"<10"&CHAR(34),$O$5))

Toute aide serait grandement appréciée!Merci!

Answer 1

Si vous souhaitez utiliser SUMIFs, il devrait être quelque chose comme ceci:

façon №1

=SUMIFS(Revenue!$G$1:$G$100,Revenue!$H$1:$H$100,IF($O$5=0,">0",$O$5),
                            Revenue!$H$1:$H$100,IF($O$5=0,"<10",$O$5)
 )

Si O5=0, la formule donne:

=SUMIFS(Revenue!$G$1:$G$100,Revenue!$H$1:$H$100,">0",
                            Revenue!$H$1:$H$100,"<10"
 )

Si O5<>0, la formule donne:

=SUMIFS(Revenue!$G$1:$G$100,Revenue!$H$1:$H$100,$O$5,
                            Revenue!$H$1:$H$100,$O$5
 )

ce qui est, de fait, donne le même résultat que

=SUMIFS(Revenue!$G$1:$G$100,Revenue!$H$1:$H$100,$O$5)

---

façon №2

=IF($O$5=0,
  SUMIFs(Revenue!$G$1:$G$100,Revenue!$H$1:$H$100,">0",
                             Revenue!$H$1:$H$100,"<10"),
  SUMIFs(Revenue!$G$1:$G$100,Revenue!$H$1:$H$100,$O$5)
 )

Si O5=0, la formule donne:

=SUMIFS(Revenue!$G$1:$G$100,Revenue!$H$1:$H$100,">0",
                            Revenue!$H$1:$H$100,"<10"
 )

Si O5<>0, la formule donne:

=SUMIFS(Revenue!$G$1:$G$100,Revenue!$H$1:$H$100,$O$5)

---

façon №3

Ou vous pouvez utiliser sumproduct ainsi:

=SUMPRODUCT((Revenue!$G$1:$G$100)*
            IF($O$5=0,(Revenue!$H$1:$H$100>0)*(Revenue!$H$1:$H$100<10),
                      (Revenue!$H$1:$H$100=$O$5)
            )
 )

C'est un la formule de tableau, saisissez la formule, puis appuyez sur CTRL+MAJ+ENTREZ.Les accolades apparaîtra automatiquement au début et à la fin de la formule.

Si O5=0, la formule donne:

=SUMPRODUCT((Revenue!$G$1:$G$100)*(Revenue!$H$1:$H$100>0)*
                                  (Revenue!$H$1:$H$100<10)
 )

Si O5<>0, la formule donne:

=SUMPRODUCT((Revenue!$G$1:$G$100)*(Revenue!$H$1:$H$100=$O$5))