Можете ли вы расширить формулу sumifs, зависящую от оператора if?
-
21-12-2019 - |
Вопрос
Мне интересно, возможно ли расширить формулу SUMIFS, зависящую от оператора IF.
В приведенном ниже примере я хочу, если $ O $ 5 = 0, расширить формулу SUMIFS так, чтобы "> 0" стало критерием1, а затем был создан новый criteria_range2 с "<10" в качестве критерия2.
Глядя на "формулу оценки", я не уверен, проблема в том, что она не будет считывать расширенный бит, потому что это невозможно сделать, или если CHAR (34) отображается не так, как я надеялся.
=SUMIFS('Revenue'!$G$1:$G$100,'Revenue'!$H$1:$H$100,IF($O$5=0,CHAR(34)&">0"&CHAR(34)&","&"'Revenue'!$H$1:$H$100"&","&CHAR(34)&"<10"&CHAR(34),$O$5))
Мы были бы очень признательны за любую помощь!Спасибо!
Решение
Если вы хотите использовать SUMIFs
, это должно быть что - то вроде этого:
способ №1
=SUMIFS(Revenue!$G$1:$G$100,Revenue!$H$1:$H$100,IF($O$5=0,">0",$O$5),
Revenue!$H$1:$H$100,IF($O$5=0,"<10",$O$5)
)
Если O5=0
, формула вычисляется как:
=SUMIFS(Revenue!$G$1:$G$100,Revenue!$H$1:$H$100,">0",
Revenue!$H$1:$H$100,"<10"
)
Если O5<>0
, формула вычисляется как:
=SUMIFS(Revenue!$G$1:$G$100,Revenue!$H$1:$H$100,$O$5,
Revenue!$H$1:$H$100,$O$5
)
что на самом деле дает вам тот же результат, что и
=SUMIFS(Revenue!$G$1:$G$100,Revenue!$H$1:$H$100,$O$5)
способ №2
=IF($O$5=0,
SUMIFs(Revenue!$G$1:$G$100,Revenue!$H$1:$H$100,">0",
Revenue!$H$1:$H$100,"<10"),
SUMIFs(Revenue!$G$1:$G$100,Revenue!$H$1:$H$100,$O$5)
)
Если O5=0
, формула вычисляется как:
=SUMIFS(Revenue!$G$1:$G$100,Revenue!$H$1:$H$100,">0",
Revenue!$H$1:$H$100,"<10"
)
Если O5<>0
, формула вычисляется как:
=SUMIFS(Revenue!$G$1:$G$100,Revenue!$H$1:$H$100,$O$5)
способ №3
Или вы также можете использовать sumproduct:
=SUMPRODUCT((Revenue!$G$1:$G$100)*
IF($O$5=0,(Revenue!$H$1:$H$100>0)*(Revenue!$H$1:$H$100<10),
(Revenue!$H$1:$H$100=$O$5)
)
)
Это важный момент формула массива, поэтому введите формулу и нажмите CTRL+СДВИГ+ВОЙТИ.Фигурные скобки автоматически появятся в начале и в конце формулы.
Если O5=0
, формула вычисляется как:
=SUMPRODUCT((Revenue!$G$1:$G$100)*(Revenue!$H$1:$H$100>0)*
(Revenue!$H$1:$H$100<10)
)
Если O5<>0
, формула вычисляется как:
=SUMPRODUCT((Revenue!$G$1:$G$100)*(Revenue!$H$1:$H$100=$O$5))