题
我试图引用一个字母可能会改变的驱动器。我想通过其标签来引用它(例如,批处理文件中的 MyLabel (v:))。可以通过 V:\ 来引用。我想通过 MyLabel 引用它。
(此问题在 Experts Echange 上发布了一个月,但没有得到答复。让我们看看 SO 回答得有多快)
解决方案
此 bat 文件将为您提供驱动器标签中的驱动器号:
Option Explicit
Dim num, args, objWMIService, objItem, colItems
set args = WScript.Arguments
num = args.Count
if num <> 1 then
WScript.Echo "Usage: CScript DriveFromLabel.vbs <label>"
WScript.Quit 1
end if
Set objWMIService = GetObject("winmgmts:\\.\root\cimv2")
Set colItems = objWMIService.ExecQuery("Select * from Win32_LogicalDisk")
For Each objItem in colItems
If strcomp(objItem.VolumeName, args.Item(0), 1) = 0 Then
Wscript.Echo objItem.Name
End If
Next
WScript.Quit 0
运行它作为:
cscript /nologo DriveFromLabel.vbs label
其他提示
前面的答案似乎过于复杂,和/或不太适合批处理文件。
这个简单的一行应该将所需的驱动器号放置在变量 myDrive 中。显然将“我的标签”更改为您的实际标签。
for /f %%D in ('wmic volume get DriveLetter^, Label ^| find "My Label"') do set myDrive=%%D
如果从命令行(不在批处理文件中)运行,则必须将两个位置的 %%D 更改为 %D。
设置变量后,您可以使用以下命令引用驱动器 %myDrive%
. 。例如
dir %myDrive%\someFolder
您可以使用 WMI 查询语言来实现此目的。看一眼 http://msdn.microsoft.com/en-us/library/aa394592(VS.85).aspx 举些例子。您正在寻找的信息是可用的,例如通过Win32_LogicalDisk类的属性VolumeName, http://msdn.microsoft.com/en-us/library/aa394173(VS.85).aspx
SELECT * FROM Win32_LogicalDisk WHERE VolumeName="MyLabel"
下面是一个简单的批处理脚本 getdrive.cmd,用于从卷标中查找驱动器号。只需调用“getdrive MyLabel”或 getdrive“My Label”即可。
@echo off
setlocal
:: Initial variables
set TMPFILE=%~dp0getdrive.tmp
set driveletters=abcdefghijklmnopqrstuvwxyz
set MatchLabel_res=
for /L %%g in (2,1,25) do call :MatchLabel %%g %*
if not "%MatchLabel_res%"=="" echo %MatchLabel_res%
goto :END
:: Function to match a label with a drive letter.
::
:: The first parameter is an integer from 1..26 that needs to be
:: converted in a letter. It is easier looping on a number
:: than looping on letters.
::
:: The second parameter is the volume name passed-on to the script
:MatchLabel
:: result already found, just do nothing
:: (necessary because there is no break for for loops)
if not "%MatchLabel_res%"=="" goto :eof
:: get the proper drive letter
call set dl=%%driveletters:~%1,1%%
:: strip-off the " in the volume name to be able to add them again further
set volname=%2
set volname=%volname:"=%
:: get the volume information on that disk
vol %dl%: > "%TMPFILE%" 2>&1
:: Drive/Volume does not exist, just quit
if not "%ERRORLEVEL%"=="0" goto :eof
set found=0
for /F "usebackq tokens=3 delims=:" %%g in (`find /C /I "%volname%" "%TMPFILE%"`) do set found=%%g
:: trick to stip any whitespaces
set /A found=%found% + 0
if not "%found%"=="0" set MatchLabel_res=%dl%:
goto :eof
:END
if exist "%TMPFILE%" del "%TMPFILE%"
endlocal
不隶属于 StackOverflow