Faire référence à/sélectionner un lecteur en fonction uniquement de son étiquette ?(c'est-à-dire pas la lettre du lecteur)

Question

J'essaie de faire référence à un lecteur dont la lettre peut changer.J'aimerais y faire référence par son étiquette (par exemple, MyLabel (v:) dans un fichier batch.Il peut être référencé par V:\ .J'aimerais y faire référence par MyLabel.

(Ceci a été publié sur Experts Echange pendant un mois sans réponse.Voyons à quelle vitesse SO y répond)

Answer 1

Ce fichier bat vous donnera la lettre de lecteur à partir d'une étiquette de lecteur :

Option Explicit
Dim num, args, objWMIService, objItem, colItems

set args = WScript.Arguments
num = args.Count

if num <> 1 then
   WScript.Echo "Usage: CScript DriveFromLabel.vbs <label>"
   WScript.Quit 1
end if

Set objWMIService = GetObject("winmgmts:\\.\root\cimv2")
Set colItems = objWMIService.ExecQuery("Select * from Win32_LogicalDisk")

For Each objItem in colItems
  If strcomp(objItem.VolumeName, args.Item(0), 1) = 0 Then
    Wscript.Echo objItem.Name
  End If
Next

WScript.Quit 0

Exécutez-le comme :

 cscript /nologo DriveFromLabel.vbs label

Answer 2

Les réponses précédentes semblent soit trop compliquées, et/ou pas particulièrement adaptées à un fichier batch.

Cette simple doublure doit placer la lettre de lecteur souhaitée dans la variable myDrive.Remplacez évidemment « Mon étiquette » par votre étiquette actuelle.

for /f %%D in ('wmic volume get DriveLetter^, Label ^| find "My Label"') do set myDrive=%%D

S'il est exécuté à partir de la ligne de commande (pas dans un fichier batch), alors %%D doit être remplacé par %D aux deux endroits.

Une fois la variable définie, vous pouvez vous référer au variateur en utilisant %myDrive%.Par exemple

dir %myDrive%\someFolder

Answer 3

Vous pouvez utiliser le langage de requête WMI pour cela.Jeter un coup d'œil à http://msdn.microsoft.com/en-us/library/aa394592(VS.85).aspx pour des exemples.Les informations que vous recherchez sont disponibles, par ex.via la propriété VolumeName de la classe Win32_LogicalDisk, http://msdn.microsoft.com/en-us/library/aa394173(VS.85).aspx

SELECT * FROM Win32_LogicalDisk WHERE VolumeName="MyLabel"

Answer 4

Voici un simple script batch getdrive.cmd pour trouver une lettre de lecteur à partir d'une étiquette de volume.Appelez simplement « getdrive MyLabel » ou getdrive « My Label ».

@echo off
setlocal

:: Initial variables
set TMPFILE=%~dp0getdrive.tmp
set driveletters=abcdefghijklmnopqrstuvwxyz
set MatchLabel_res=

for /L %%g in (2,1,25) do call :MatchLabel %%g %*

if not "%MatchLabel_res%"=="" echo %MatchLabel_res%

goto :END


:: Function to match a label with a drive letter. 
::
:: The first parameter is an integer from 1..26 that needs to be 
:: converted in a letter. It is easier looping on a number
:: than looping on letters.
::
:: The second parameter is the volume name passed-on to the script
:MatchLabel

:: result already found, just do nothing 
:: (necessary because there is no break for for loops)
if not "%MatchLabel_res%"=="" goto :eof

:: get the proper drive letter
call set dl=%%driveletters:~%1,1%%

:: strip-off the " in the volume name to be able to add them again further
set volname=%2
set volname=%volname:"=%

:: get the volume information on that disk
vol %dl%: > "%TMPFILE%" 2>&1

:: Drive/Volume does not exist, just quit
if not "%ERRORLEVEL%"=="0" goto :eof

set found=0
for /F "usebackq tokens=3 delims=:" %%g in (`find /C /I "%volname%" "%TMPFILE%"`) do set found=%%g

:: trick to stip any whitespaces
set /A found=%found% + 0


if not "%found%"=="0" set MatchLabel_res=%dl%:
goto :eof








:END

if exist "%TMPFILE%" del "%TMPFILE%"
endlocal