Обращаться к диску или выбирать его только по его метке?(т. е. не буква диска)
-
09-06-2019 - |
Вопрос
Я пытаюсь обратиться к диску, буква которого может измениться.Я хотел бы ссылаться на него по его метке (например, MyLabel (v:) в пакетном файле.На него можно ссылаться по V:\ .Я хотел бы сослаться на него через MyLabel.
(Это сообщение было размещено на Experts Echange в течение месяца без ответа.Посмотрим, как быстро SO ответит на него)
Решение
Этот bat-файл даст вам букву диска из метки диска:
Option Explicit
Dim num, args, objWMIService, objItem, colItems
set args = WScript.Arguments
num = args.Count
if num <> 1 then
WScript.Echo "Usage: CScript DriveFromLabel.vbs <label>"
WScript.Quit 1
end if
Set objWMIService = GetObject("winmgmts:\\.\root\cimv2")
Set colItems = objWMIService.ExecQuery("Select * from Win32_LogicalDisk")
For Each objItem in colItems
If strcomp(objItem.VolumeName, args.Item(0), 1) = 0 Then
Wscript.Echo objItem.Name
End If
Next
WScript.Quit 0
Запустите его как:
cscript /nologo DriveFromLabel.vbs label
Другие советы
Предыдущие ответы кажутся либо слишком сложными, либо не особенно подходящими для пакетного файла.
Эта простая строка должна поместить нужную букву диска в переменную myDrive.Очевидно, измените «Мой ярлык» на свой настоящий ярлык.
for /f %%D in ('wmic volume get DriveLetter^, Label ^| find "My Label"') do set myDrive=%%D
При запуске из командной строки (не в пакетном файле) %%D необходимо изменить на %D в обоих местах.
После того, как переменная установлена, вы можете обратиться к диску, используя %myDrive%
.Например
dir %myDrive%\someFolder
Для этого вы можете использовать язык запросов WMI.Взгляни на http://msdn.microsoft.com/en-us/library/aa394592(VS.85).aspx Например.Информация, которую вы ищете, доступна, например.через свойство VolumeName класса Win32_LogicalDisk, http://msdn.microsoft.com/en-us/library/aa394173(VS.85).aspx
SELECT * FROM Win32_LogicalDisk WHERE VolumeName="MyLabel"
Вот простой пакетный скрипт getdrive.cmd для поиска буквы диска по метке тома.Просто вызовите «getdrive MyLabel» или getdrive «My Label».
@echo off
setlocal
:: Initial variables
set TMPFILE=%~dp0getdrive.tmp
set driveletters=abcdefghijklmnopqrstuvwxyz
set MatchLabel_res=
for /L %%g in (2,1,25) do call :MatchLabel %%g %*
if not "%MatchLabel_res%"=="" echo %MatchLabel_res%
goto :END
:: Function to match a label with a drive letter.
::
:: The first parameter is an integer from 1..26 that needs to be
:: converted in a letter. It is easier looping on a number
:: than looping on letters.
::
:: The second parameter is the volume name passed-on to the script
:MatchLabel
:: result already found, just do nothing
:: (necessary because there is no break for for loops)
if not "%MatchLabel_res%"=="" goto :eof
:: get the proper drive letter
call set dl=%%driveletters:~%1,1%%
:: strip-off the " in the volume name to be able to add them again further
set volname=%2
set volname=%volname:"=%
:: get the volume information on that disk
vol %dl%: > "%TMPFILE%" 2>&1
:: Drive/Volume does not exist, just quit
if not "%ERRORLEVEL%"=="0" goto :eof
set found=0
for /F "usebackq tokens=3 delims=:" %%g in (`find /C /I "%volname%" "%TMPFILE%"`) do set found=%%g
:: trick to stip any whitespaces
set /A found=%found% + 0
if not "%found%"=="0" set MatchLabel_res=%dl%:
goto :eof
:END
if exist "%TMPFILE%" del "%TMPFILE%"
endlocal