使用批处理文件打开一系列文件之一
-
09-06-2019 - |
题
我最多有 4 个基于此结构的文件(注意前缀是日期)
- 0830文件名.txt
- 0907文件名.txt
- 0914文件名.txt
- 0921文件名.txt
我想打开最新的一个(0921filename.txt)。我如何在批处理文件中执行此操作?
谢谢。
解决方案
此方法使用实际的文件修改日期来确定哪个是最新的文件:
@echo off
for /F %%i in ('dir /B /O:-D *.txt') do (
call :open "%%i"
exit /B 0
)
:open
start "dummy" "%~1"
exit /B 0
但是,此方法按字母顺序选择最后一个文件(或按逆字母顺序选择第一个文件),因此如果文件名一致 - 它将起作用:
@echo off
for /F %%i in ('dir /B *.txt^|sort /R') do (
call :open "%%i"
exit /B 0
)
:open
start "dummy" "%~1"
exit /B 0
您实际上必须选择哪种方法更适合您。
其他提示
抱歉,我乱发了这个问题,但我真的很想发帖 真正的答案。如果您希望 BATCH 脚本 解析 和 比较 文件名中的日期,那么您可以使用如下内容:
@echo off
rem Enter the ending of the filenames.
rem Basically, you must specify everything that comes after the date.
set fn_end=filename.txt
rem Do not touch anything bellow this line.
set max_month=00
set max_day=00
for /F %%i in ('dir /B *%fn_end%') do call :check "%%i"
call :open %max_month% %max_day%
exit /B 0
:check
set name=%~1
set date=%name:~0,4%
set month=%date:~0,2%
set day=%date:~2,2%
if /I %month% GTR %max_month% (
set max_month=%month%
set max_day=%day%
) else if /I %month% EQU %max_month% (
set max_month=%month%
if /I %day% GTR %max_day% (
set max_day=%day%
)
)
exit /B 0
:open
set date=%~1
set month=%~2
set name=%date%%month%%fn_end%
start "dummy" "%name%"
exit /B 0
一行,使用 EXIT 技巧:
FOR /F %%I IN ('DIR *.TXT /B /O:-D') DO NOTEPAD %%I & EXIT
编辑:
@帕姆:你是对的,我假设文件按日期顺序排列,但你可以将命令更改为:
FOR /F %%I IN ('DIR *.TXT /B /O:-N') DO NOTEPAD %%I & EXIT
然后文件列表按名称按相反顺序排序。
干得好...(希望没有人击败我...)(您需要将文件保存为lastText.bat之类的东西)这将打开 /运行最古老的.txt文件
dir *.txt /b /od > systext.bak
FOR /F %%i in (systext.bak) do set sysRunCommand=%%i
call %sysRunCommand%
del systext.bak /Y
可能仅限XP。可见 DOS 的强大威力。
虽然这会按日期获取最新的文件名 - 而不是按文件名..
如果您想获取最新的文件名,请将 /od 更改为 /on 。
如果您想对其他内容进行排序,请在第二行添加“排序”命令。
使用正则表达式解析出相关整数并进行比较。
不隶属于 StackOverflow