Abra um de uma série de arquivos usando um arquivo em lote

Question

Tenho até 4 arquivos baseados nesta estrutura (observe que os prefixos são datas)

• 0830nomedoarquivo.txt
• 0907nomedoarquivo.txt
• 0914nome do arquivo.txt
• 0921nomedoarquivo.txt

Quero abrir o mais recente (0921filename.txt).como posso fazer isso em um arquivo em lote?

Obrigado.

Answer 1

Este método usa a data real de modificação do arquivo para descobrir qual é o arquivo mais recente:

@echo off
for /F %%i in ('dir /B /O:-D *.txt') do (
    call :open "%%i"
    exit /B 0
)
:open
    start "dummy" "%~1"
exit /B 0

Este método, entretanto, escolhe o último arquivo em ordem alfabética (ou o primeiro, em ordem alfabética inversa), portanto, se os nomes dos arquivos forem consistentes - funcionará:

@echo off
for /F %%i in ('dir /B *.txt^|sort /R') do (
    call :open "%%i"
    exit /B 0
)
:open
    start "dummy" "%~1"
exit /B 0

Na verdade, você precisa escolher qual método é melhor para você.

Answer 2

Desculpe, por enviar spam para esta pergunta, mas realmente estou com vontade de postar A verdadeira resposta.Se você quiser que seu script BATCH seja analisar e comparar as datas nos nomes dos arquivos, então você pode usar algo assim:

@echo off

rem Enter the ending of the filenames.
rem Basically, you must specify everything that comes after the date.
set fn_end=filename.txt

rem Do not touch anything bellow this line.
set max_month=00
set max_day=00

for /F %%i in ('dir /B *%fn_end%') do call :check "%%i"
call :open %max_month% %max_day%
exit /B 0

:check
    set name=%~1
    set date=%name:~0,4%
    set month=%date:~0,2%
    set day=%date:~2,2%
    if /I %month% GTR %max_month% (
        set max_month=%month%
        set max_day=%day%
    ) else if /I %month% EQU %max_month% (
        set max_month=%month%
        if /I %day% GTR %max_day% (
            set max_day=%day%
        )
    )
exit /B 0

:open
    set date=%~1
    set month=%~2
    set name=%date%%month%%fn_end%
    start "dummy" "%name%"
exit /B 0

Answer 3

Uma linha, usando o truque EXIT:

FOR /F %%I IN ('DIR *.TXT /B /O:-D') DO NOTEPAD %%I & EXIT

EDITAR:

@pam:você está certo, eu estava assumindo que os arquivos estavam em ordem de data, mas você pode alterar o comando para:

FOR /F %%I IN ('DIR *.TXT /B /O:-N') DO NOTEPAD %%I & EXIT

então você tem a lista de arquivos classificada por nome na ordem inversa.

Answer 4

Aqui você vai...(Espero que ninguém tenha me vencido ...) (Você precisará salvar o arquivo como lastText.bat ou algo assim) Isso abrirá / executará o arquivo .txt mais antigo

dir *.txt /b /od > systext.bak 
FOR /F %%i in (systext.bak) do set sysRunCommand=%%i 
call %sysRunCommand%
del systext.bak /Y

Provavelmente apenas XP.VEJA O grande poder do DOS.
Embora isso leve o nome do arquivo mais recente por data - NÃO por nome de arquivo.

Se você deseja obter o nome de arquivo mais recente, altere /od para /on .
Se você quiser classificar outra coisa, adicione um comando "classificar" à segunda linha.

Answer 5

Use expressão regular para analisar o número inteiro relevante e compará-los.