バッチ ファイルを使用して一連のファイルの 1 つを開く
-
09-06-2019 - |
質問
この構造に基づくファイルは最大 4 つあります (プレフィックスは日付であることに注意してください)
- 0830ファイル名.txt
- 0907ファイル名.txt
- 0914ファイル名.txt
- 0921ファイル名.txt
最新のもの(0921ファイル名.txt)を開きたいと思っています。バッチファイルでこれを行うにはどうすればよいですか?
ありがとう。
解決
このメソッドは、実際のファイル変更日を使用して、どのファイルが最新のものであるかを判断します。
@echo off
for /F %%i in ('dir /B /O:-D *.txt') do (
call :open "%%i"
exit /B 0
)
:open
start "dummy" "%~1"
exit /B 0
ただし、この方法はアルファベット順の最後のファイル (またはアルファベットの逆順の最初のファイル) を選択するため、ファイル名が一貫していれば機能します。
@echo off
for /F %%i in ('dir /B *.txt^|sort /R') do (
call :open "%%i"
exit /B 0
)
:open
start "dummy" "%~1"
exit /B 0
実際には、どちらの方法が自分にとって良いかを選択する必要があります。
他のヒント
申し訳ありませんが、この質問にスパムを送ってしまいましたが、本当に投稿したい気分です 本当の答え。BATCH スクリプトを次のようにしたい場合は、 解析する そして 比較する ファイル名に日付を含める場合は、次のようなものを使用できます。
@echo off
rem Enter the ending of the filenames.
rem Basically, you must specify everything that comes after the date.
set fn_end=filename.txt
rem Do not touch anything bellow this line.
set max_month=00
set max_day=00
for /F %%i in ('dir /B *%fn_end%') do call :check "%%i"
call :open %max_month% %max_day%
exit /B 0
:check
set name=%~1
set date=%name:~0,4%
set month=%date:~0,2%
set day=%date:~2,2%
if /I %month% GTR %max_month% (
set max_month=%month%
set max_day=%day%
) else if /I %month% EQU %max_month% (
set max_month=%month%
if /I %day% GTR %max_day% (
set max_day=%day%
)
)
exit /B 0
:open
set date=%~1
set month=%~2
set name=%date%%month%%fn_end%
start "dummy" "%name%"
exit /B 0
EXIT トリックを使用したワンライナー:
FOR /F %%I IN ('DIR *.TXT /B /O:-D') DO NOTEPAD %%I & EXIT
編集:
@パム:おっしゃるとおり、ファイルは日付順であると想定していましたが、コマンドを次のように変更できます。
FOR /F %%I IN ('DIR *.TXT /B /O:-N') DO NOTEPAD %%I & EXIT
これで、ファイルリストが名前順に逆順にソートされます。
どうぞ...(誰も私を打ち負かしないことを願っています...)(ファイルをlastText.batなどとして保存する必要があります)
dir *.txt /b /od > systext.bak
FOR /F %%i in (systext.bak) do set sysRunCommand=%%i
call %sysRunCommand%
del systext.bak /Y
おそらくXPのみだと思います。見よ、DOS の強力なパワー。
ただし、これはファイル名ではなく日付に基づいて最新のファイル名を取得します。
最新のファイル名を取得したい場合は、 /od を /on に変更します。
他の項目で並べ替えたい場合は、2 行目に「sort」コマンドを追加します。
正規表現を使用して関連する整数を解析し、それらを比較します。