Откройте один из серии файлов с помощью пакетного файла.

Question

У меня есть до 4 файлов на основе этой структуры (обратите внимание, что префиксы — это даты)

• 0830имяфайла.txt
• 0907имяфайла.txt
• 0914имяфайла.txt
• 0921имяфайла.txt

Я хочу открыть самый последний файл (0921filename.txt).как я могу сделать это в пакетном файле?

Спасибо.

Answer 1

Этот метод использует фактическую дату изменения файла, чтобы определить, какой из файлов является последним:

@echo off
for /F %%i in ('dir /B /O:-D *.txt') do (
    call :open "%%i"
    exit /B 0
)
:open
    start "dummy" "%~1"
exit /B 0

Однако этот метод выбирает последний файл в алфавитном порядке (или первый в обратном алфавитном порядке), поэтому, если имена файлов совпадают, он будет работать:

@echo off
for /F %%i in ('dir /B *.txt^|sort /R') do (
    call :open "%%i"
    exit /B 0
)
:open
    start "dummy" "%~1"
exit /B 0

На самом деле вам придется выбрать, какой метод лучше для вас.

Answer 2

Извините за спам с этим вопросом, но мне просто очень хочется написать Настоящий ответ.Если вы хотите, чтобы ваш BATCH-скрипт анализировать и сравнивать даты в именах файлов, то вы можете использовать что-то вроде этого:

@echo off

rem Enter the ending of the filenames.
rem Basically, you must specify everything that comes after the date.
set fn_end=filename.txt

rem Do not touch anything bellow this line.
set max_month=00
set max_day=00

for /F %%i in ('dir /B *%fn_end%') do call :check "%%i"
call :open %max_month% %max_day%
exit /B 0

:check
    set name=%~1
    set date=%name:~0,4%
    set month=%date:~0,2%
    set day=%date:~2,2%
    if /I %month% GTR %max_month% (
        set max_month=%month%
        set max_day=%day%
    ) else if /I %month% EQU %max_month% (
        set max_month=%month%
        if /I %day% GTR %max_day% (
            set max_day=%day%
        )
    )
exit /B 0

:open
    set date=%~1
    set month=%~2
    set name=%date%%month%%fn_end%
    start "dummy" "%name%"
exit /B 0

Answer 3

Один лайнер с использованием трюка EXIT:

FOR /F %%I IN ('DIR *.TXT /B /O:-D') DO NOTEPAD %%I & EXIT

РЕДАКТИРОВАТЬ:

@пэм:вы правы, я предполагал, что файлы расположены в порядке дат, но вы можете изменить команду на:

FOR /F %%I IN ('DIR *.TXT /B /O:-N') DO NOTEPAD %%I & EXIT

тогда у вас есть список файлов, отсортированный по имени в обратном порядке.

Answer 4

Ну вот...(Надеюсь, никто никто не победил меня ...) (Вам нужно сохранить файл как Lastext.Bat или что-то в этом роде) Это откроет / запустит самый старый файл .txt

dir *.txt /b /od > systext.bak 
FOR /F %%i in (systext.bak) do set sysRunCommand=%%i 
call %sysRunCommand%
del systext.bak /Y

Наверное только XP.УЗНАЙТЕ могучую силу DOS.
Хотя для этого требуется последнее имя файла по дате, а НЕ по имени файла.

Если вы хотите получить последнее имя файла, измените /od на /on .
Если вы хотите отсортировать что-то еще, добавьте команду «сортировка» во вторую строку.

Answer 5

Используйте регулярное выражение, чтобы проанализировать соответствующее целое число и сравнить его.