Können Sie eine sumifs-Formel abhängig von einer if-Anweisung erweitern?

Question

Ich frage mich, ob es möglich ist, eine SUMIFS-Formel abhängig von einer IF-Anweisung zu erweitern.

Im folgenden Beispiel möchte ich, wenn $ O $ 5 = 0 ist, die SUMMENWENN-Formel so erweitern, dass "> 0" zu Kriterien1 wird und dann ein neuer Kriterienbereich2 mit "<10" als Kriterium2.

Wenn ich mir 'Formel auswerten' anschaue, bin ich mir nicht sicher, ob das Problem darin besteht, dass das erweiterte Bit nicht gelesen wird, weil dies nicht möglich ist oder wenn das ZEICHEN (34) nicht angezeigt wird, wie ich gehofft habe.

=SUMIFS('Einnahmen'!$G$1:$G$100,'Einnahmen'!$ H $ 1: $ H $ 100, WENN ($ O $ 5 = 0, ZEICHEN (34)& "> 0"& ZEICHEN(34)&","&"' Einnahmen'!$H$1:$H$100"&","&ZEICHEN(34)&"<10 "& ZEICHEN (34), $ O$ 5))

Jede Hilfe wäre sehr dankbar!Danke!

Answer 1

Wenn Sie verwenden möchten SUMIFs, es sollte so etwas sein:

weg №1

=SUMIFS(Revenue!$G$1:$G$100,Revenue!$H$1:$H$100,IF($O$5=0,">0",$O$5),
                            Revenue!$H$1:$H$100,IF($O$5=0,"<10",$O$5)
 )

Wenn O5=0, formel wertet aus zu:

=SUMIFS(Revenue!$G$1:$G$100,Revenue!$H$1:$H$100,">0",
                            Revenue!$H$1:$H$100,"<10"
 )

Wenn O5<>0, formel wertet aus zu:

=SUMIFS(Revenue!$G$1:$G$100,Revenue!$H$1:$H$100,$O$5,
                            Revenue!$H$1:$H$100,$O$5
 )

was Ihnen tatsächlich das gleiche Ergebnis liefert wie

=SUMIFS(Revenue!$G$1:$G$100,Revenue!$H$1:$H$100,$O$5)

---

weg №2

=IF($O$5=0,
  SUMIFs(Revenue!$G$1:$G$100,Revenue!$H$1:$H$100,">0",
                             Revenue!$H$1:$H$100,"<10"),
  SUMIFs(Revenue!$G$1:$G$100,Revenue!$H$1:$H$100,$O$5)
 )

Wenn O5=0, formel wertet aus zu:

=SUMIFS(Revenue!$G$1:$G$100,Revenue!$H$1:$H$100,">0",
                            Revenue!$H$1:$H$100,"<10"
 )

Wenn O5<>0, formel wertet aus zu:

=SUMIFS(Revenue!$G$1:$G$100,Revenue!$H$1:$H$100,$O$5)

---

weg №3

Oder Sie können auch sumproduct verwenden:

=SUMPRODUCT((Revenue!$G$1:$G$100)*
            IF($O$5=0,(Revenue!$H$1:$H$100>0)*(Revenue!$H$1:$H$100<10),
                      (Revenue!$H$1:$H$100=$O$5)
            )
 )

Dies ist ein Matrixformel, geben Sie also die Formel ein und drücken Sie dann STRG+SHIFT+GEBEN.Geschweifte Klammern werden automatisch am Anfang und Ende der Formel angezeigt.

Wenn O5=0, formel wertet aus zu:

=SUMPRODUCT((Revenue!$G$1:$G$100)*(Revenue!$H$1:$H$100>0)*
                                  (Revenue!$H$1:$H$100<10)
 )

Wenn O5<>0, formel wertet aus zu:

=SUMPRODUCT((Revenue!$G$1:$G$100)*(Revenue!$H$1:$H$100=$O$5))