das Startzeichen prüfen sollte ‚T‘ sein und die nächsten 3 Zeichen sollte Nummer in Xslt sein
Frage
Ich verwende XSLT1.0 für mein Transformieren von XML.
Ich habe unter tabs.xml
<?xml version="1.0"?>
<tcm:ListItems xmlns:tcm="http://www.tridion.com/ContentManager/5.0" ID="tcm:481-87289-4" Managed="68">
<tcm:Item ID="tcm:481-596728-64" Title="T000. Brisbane" pageURL="/australia/brisbane/index.aspx" componentTitle="Overview"/>
<tcm:Item ID="tcm:481-598671-64" Title="Tabs XML"/>
<tcm:Item ID="tcm:481-598672-64" Title="T030 Special Offers" pageURL="/australia/brisbane/specialoffers.aspx" componentTitle="Special Offers"/>
<tcm:Item ID="tcm:481-598673-64" Title="020 Flight Schedules" pageURL="/australia/brisbane/flightschedules.aspx" componentTitle="Flight Schedules"/>
<tcm:Item ID="tcm:481-598674-64" Title="T010 Guide" pageURL="/australia/brisbane/guide.aspx" componentTitle="Guide"/>
</tcm:ListItems>
Und ich bin unten Xslt Verwendung zu verwandeln!
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform" xmlns:tcm="http://www.tridion.com/ContentManager/5.0" xmlns:xlink="http://www.w3.org/1999/xlink" xmlns:em="http://www.emirates.com/tridion/schemas" xmlns:tcmse="http://www.tridion.com/ContentManager/5.1/TcmScriptAssistant" exclude-result-prefixes="em xlink tcmse tcm">
<xsl:output method="xml" version="1.0" encoding="UTF-16" indent="yes"/>
<xsl:template match="tcm:ListItems">
<list type="Tabs">
<xsl:apply-templates select="tcm:Item">
<xsl:sort select="@Title" order="ascending"/>
</xsl:apply-templates>
</list>
</xsl:template>
<!-- add field values for each item-->
<xsl:template match="tcm:Item">
<xsl:if test="@componentTitle != ''">
<xsl:element name="tab">
<xsl:attribute name="id">
<xsl:value-of select="substring-after(@ID, '-')"/>
</xsl:attribute>
<xsl:attribute name="title">
<xsl:value-of select="@componentTitle"/>
</xsl:attribute>
<xsl:attribute name="url">
<xsl:value-of select="@pageURL"/>
</xsl:attribute>
</xsl:element>
</xsl:if>
</xsl:template>
</xsl:stylesheet>
Bisher war es funktioniert gut, aber jetzt gibt es eine weitere Änderung erforderlich, jetzt brauche ich diese Knoten gemacht werden, deren @Title beginnt mit ‚T‘ oder ‚t‘ sowie nächsten 3 Zeichen sollte Zahl beispielsweise in über xml „Flugplan“ soll nicht kommen, gehe ich davon aus i in <xsl:if test="@componentTitle != ''">
nur schreiben muß eine mehr und Zustand,
Bitte machen! wie es gemacht werden kann!
Lösung 5
Ich kam mit unten Lösung auf, bitte vorschlagen, wenn es in Ordnung ist!
<xsl:template match="tcm:Item">
<xsl:if test="@componentTitle != '' and (starts-with(translate(@Title, 't', 'T'), 'T')and string(number(substring(@Title,2,3))) != 'NaN')">
<xsl:element name="tab">
<xsl:attribute name="id">
<xsl:value-of select="substring-after(@ID, '-')"/>
</xsl:attribute>
<xsl:attribute name="title">
<xsl:value-of select="@componentTitle"/>
</xsl:attribute>
<xsl:attribute name="url">
<xsl:value-of select="@pageURL"/>
</xsl:attribute>
</xsl:element>
</xsl:if>
</xsl:template>
Ihr alle Eingaben erforderlich!
Andere Tipps
Hier ist der einfachste Ausdruck, der die passenden tun:
translate(substring(@Title, 1, 4), 't12345679', 'T000000000') = 'T000'
Hier ist die Vorlage:
<xsl:template match="
tcm:Item[translate(substring(@Title, 1, 4), 't12345679', 'T000000000') = 'T000'
and @componentTitle != '' "/>
Die Auswahllogik ist am besten put in das Übereinstimmungsmuster der Vorlage -. Und es kann ein wenig vereinfacht, werden
<xsl:template match=
"tcm:Item[contains('tT', substring(@Title,1,1))
and
number(substring(@Title,2,3))
=
number(substring(@Title,2,3))
]
">
Eine Regel erinnern : Testen Sie immer, wenn einige String $s
eine Zahl - wie folgt aus:
number($s) = number($s)
Sie sollten wählen die Knoten, die Sie in Ihren Vorlagen im apply-templates
Element operieren wollen:
<xsl:apply-templates select="tcm:Item[@componentTitle != ''
and (starts-with(translate(@Title, 't', 'T'), 'T')
and string(number(substring(@Title,2,3))) != 'NaN')]">
Ich habe den Test verwendet, dass @solution für diese produziert - es funktioniert gut für die Anforderung (getestet hier ).
Das ist besser als alle tcm:Item
Knoten auswählen und ihnen einen nach dem anderen in der Vorlage zu testen.
Arbeiten mit XSLT nur sehr selten, kam ich auf die folgende Lösung:
<xsl:if test="@componentTitle != ''">
<xsl:if test="starts-with(@Title,'T') or starts-with(@Title,'t')">
<xsl:if test="string-length(@Title) > 3">
<xsl:if test="string(number(substring(@Title,2,3))) != 'NaN'">
...
</xsl:if>
</xsl:if>
</xsl:if>
</xsl:if>
Ich habe bemerkt, dass es auch Funktionen sind lower-case
/ upper-case
, die für die Prüfung für das erste Zeichen verwendet werden könnte, ein t
oder T
zu sein, aber sie scheinen nur in XSLT2.0 zur Verfügung zu stehen.