Comprobación del carácter de arranque debe ser 'T' y el próximo 3 personaje debe ser el número de XSLT

Question

Estoy utilizando XSLT1.0 para transformar mi XML.

Estoy teniendo a continuación Tabs.xml

<?xml version="1.0"?>
<tcm:ListItems xmlns:tcm="http://www.tridion.com/ContentManager/5.0" ID="tcm:481-87289-4" Managed="68">
  <tcm:Item ID="tcm:481-596728-64" Title="T000. Brisbane" pageURL="/australia/brisbane/index.aspx" componentTitle="Overview"/>
  <tcm:Item ID="tcm:481-598671-64" Title="Tabs XML"/>
  <tcm:Item ID="tcm:481-598672-64" Title="T030 Special Offers" pageURL="/australia/brisbane/specialoffers.aspx" componentTitle="Special Offers"/>
  <tcm:Item ID="tcm:481-598673-64" Title="020 Flight Schedules" pageURL="/australia/brisbane/flightschedules.aspx" componentTitle="Flight Schedules"/>
  <tcm:Item ID="tcm:481-598674-64" Title="T010 Guide" pageURL="/australia/brisbane/guide.aspx" componentTitle="Guide"/>
</tcm:ListItems>

Y estoy usando a continuación XSLT para transformarlo!

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform" xmlns:tcm="http://www.tridion.com/ContentManager/5.0" xmlns:xlink="http://www.w3.org/1999/xlink" xmlns:em="http://www.emirates.com/tridion/schemas" xmlns:tcmse="http://www.tridion.com/ContentManager/5.1/TcmScriptAssistant" exclude-result-prefixes="em xlink tcmse tcm">
  <xsl:output method="xml" version="1.0" encoding="UTF-16" indent="yes"/>
  <xsl:template match="tcm:ListItems">
    <list type="Tabs">
      <xsl:apply-templates select="tcm:Item">
        <xsl:sort select="@Title" order="ascending"/>
      </xsl:apply-templates>
    </list>
  </xsl:template>
  <!-- add field values for each item-->
  <xsl:template match="tcm:Item">
    <xsl:if test="@componentTitle != ''">
      <xsl:element name="tab">
        <xsl:attribute name="id">
          <xsl:value-of select="substring-after(@ID, '-')"/>
        </xsl:attribute>
        <xsl:attribute name="title">
          <xsl:value-of select="@componentTitle"/>
        </xsl:attribute>
        <xsl:attribute name="url">
          <xsl:value-of select="@pageURL"/>
        </xsl:attribute>
      </xsl:element>
    </xsl:if>
  </xsl:template>
</xsl:stylesheet>

Anteriormente, se trabaja muy bien, pero ahora hay otro cambio que se requiere, ahora necesito los nodos a ser prestados cuyos arranques @title por 'T' o 't', así como el próximo 3 de caracteres debe ser el número, por ejemplo, en por encima de xml "Programa de vuelo" no debe entrar, supongo que sólo hay que escribir uno más y condición en <xsl:if test="@componentTitle != ''">,

Para sugerir! ¿Cómo se puede hacer!

Answer 1

Se me ocurrió a continuación solución, por favor sugerir si está bien!

<xsl:template match="tcm:Item">
    <xsl:if test="@componentTitle != '' and (starts-with(translate(@Title, 't', 'T'), 'T')and string(number(substring(@Title,2,3))) != 'NaN')">
      <xsl:element name="tab">
        <xsl:attribute name="id">
          <xsl:value-of select="substring-after(@ID, '-')"/>
        </xsl:attribute>
        <xsl:attribute name="title">
          <xsl:value-of select="@componentTitle"/>
        </xsl:attribute>
        <xsl:attribute name="url">
          <xsl:value-of select="@pageURL"/>
        </xsl:attribute>
      </xsl:element>
    </xsl:if>
  </xsl:template>

Se requiere su entrada de todos!

Answer 2

Esta es la expresión más simple que hará el juego:

translate(substring(@Title, 1, 4), 't12345679', 'T000000000') = 'T000'

Esta es la plantilla:

<xsl:template match="
 tcm:Item[translate(substring(@Title, 1, 4), 't12345679', 'T000000000') = 'T000'
 and @componentTitle != '' "/>

Answer 3

La lógica de selección es mejor poner en el perfil de compatibilidad de la plantilla -. Y puede ser un poco simplificada, también

<xsl:template match=
 "tcm:Item[contains('tT', substring(@Title,1,1))
         and
           number(substring(@Title,2,3)) 
          =    
           number(substring(@Title,2,3)) 
          ]
 ">

Una regla para recordar : Siempre prueba si alguna $s cadena representa un número - de esta manera:

number($s) = number($s)

Answer 4

debe seleccione los nodos que desea operar sobre en sus plantillas en el elemento apply-templates:

<xsl:apply-templates select="tcm:Item[@componentTitle != '' 
                           and (starts-with(translate(@Title, 't', 'T'), 'T') 
                           and string(number(substring(@Title,2,3))) != 'NaN')]">

he utilizado la prueba que @solution producido para este - que funciona bien para el requisito (probado aquí ).

Esto es mejor que la selección de todos los nodos tcm:Item y las pruebas de uno a la vez en la plantilla.

Answer 5

Trabajo con XSLT sólo es muy de vez en cuando, me encontré con la siguiente solución:

<xsl:if test="@componentTitle != ''">
  <xsl:if test="starts-with(@Title,'T') or starts-with(@Title,'t')"> 
    <xsl:if test="string-length(@Title) &gt; 3">
      <xsl:if test="string(number(substring(@Title,2,3))) != 'NaN'"> 
...
      </xsl:if>
    </xsl:if>
  </xsl:if>
</xsl:if>

Me di cuenta de que también hay funciones lower-case / upper-case que podrían utilizarse para probar para el primer carácter de ser un t o T pero parecen ser sólo está disponible en XSLT2.0.