Verifica del carattere di partenza dovrebbe essere 'T' e successivo 3 personaggio dovrebbe essere il numero in XSLT

Question

Sto usando XSLT1.0 per trasformare il mio XML.

Sto avendo seguito Tabs.xml

<?xml version="1.0"?>
<tcm:ListItems xmlns:tcm="http://www.tridion.com/ContentManager/5.0" ID="tcm:481-87289-4" Managed="68">
  <tcm:Item ID="tcm:481-596728-64" Title="T000. Brisbane" pageURL="/australia/brisbane/index.aspx" componentTitle="Overview"/>
  <tcm:Item ID="tcm:481-598671-64" Title="Tabs XML"/>
  <tcm:Item ID="tcm:481-598672-64" Title="T030 Special Offers" pageURL="/australia/brisbane/specialoffers.aspx" componentTitle="Special Offers"/>
  <tcm:Item ID="tcm:481-598673-64" Title="020 Flight Schedules" pageURL="/australia/brisbane/flightschedules.aspx" componentTitle="Flight Schedules"/>
  <tcm:Item ID="tcm:481-598674-64" Title="T010 Guide" pageURL="/australia/brisbane/guide.aspx" componentTitle="Guide"/>
</tcm:ListItems>

E sto usando qui sotto XSLT per trasformarla!

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform" xmlns:tcm="http://www.tridion.com/ContentManager/5.0" xmlns:xlink="http://www.w3.org/1999/xlink" xmlns:em="http://www.emirates.com/tridion/schemas" xmlns:tcmse="http://www.tridion.com/ContentManager/5.1/TcmScriptAssistant" exclude-result-prefixes="em xlink tcmse tcm">
  <xsl:output method="xml" version="1.0" encoding="UTF-16" indent="yes"/>
  <xsl:template match="tcm:ListItems">
    <list type="Tabs">
      <xsl:apply-templates select="tcm:Item">
        <xsl:sort select="@Title" order="ascending"/>
      </xsl:apply-templates>
    </list>
  </xsl:template>
  <!-- add field values for each item-->
  <xsl:template match="tcm:Item">
    <xsl:if test="@componentTitle != ''">
      <xsl:element name="tab">
        <xsl:attribute name="id">
          <xsl:value-of select="substring-after(@ID, '-')"/>
        </xsl:attribute>
        <xsl:attribute name="title">
          <xsl:value-of select="@componentTitle"/>
        </xsl:attribute>
        <xsl:attribute name="url">
          <xsl:value-of select="@pageURL"/>
        </xsl:attribute>
      </xsl:element>
    </xsl:if>
  </xsl:template>
</xsl:stylesheet>

In precedenza, è stato lavorando bene, ma ora c'è un altro cambiamento richiesto, ora devo quelle nodo da cui inizia resi @Title con 'T' o 't' così come accanto 3 carattere deve essere il numero, ad esempio in sopra xml "Flight Schedule" non dovrebbe venire, suppongo che ho solo bisogno di scrivere più uno e condizione in <xsl:if test="@componentTitle != ''">,

Si prega di suggerire! come si può fare!

Answer 1

Sono venuto con sottostante soluzione, si prega di suggerire se è OK!

<xsl:template match="tcm:Item">
    <xsl:if test="@componentTitle != '' and (starts-with(translate(@Title, 't', 'T'), 'T')and string(number(substring(@Title,2,3))) != 'NaN')">
      <xsl:element name="tab">
        <xsl:attribute name="id">
          <xsl:value-of select="substring-after(@ID, '-')"/>
        </xsl:attribute>
        <xsl:attribute name="title">
          <xsl:value-of select="@componentTitle"/>
        </xsl:attribute>
        <xsl:attribute name="url">
          <xsl:value-of select="@pageURL"/>
        </xsl:attribute>
      </xsl:element>
    </xsl:if>
  </xsl:template>

È necessario fornire i tutti gli input!

Answer 2

Ecco l'espressione più semplice che farà l'abbinamento:

translate(substring(@Title, 1, 4), 't12345679', 'T000000000') = 'T000'

Ecco il template:

<xsl:template match="
 tcm:Item[translate(substring(@Title, 1, 4), 't12345679', 'T000000000') = 'T000'
 and @componentTitle != '' "/>

Answer 3

La logica di selezione è meglio mettere nel pattern match del modello -. E può essere un po 'semplificata, troppo

<xsl:template match=
 "tcm:Item[contains('tT', substring(@Title,1,1))
         and
           number(substring(@Title,2,3)) 
          =    
           number(substring(@Title,2,3)) 
          ]
 ">

Una regola da ricordare : sempre prova se alcuni $s stringa rappresenta un numero - in questo modo:

number($s) = number($s)

Answer 4

Si dovrebbe selezionare i nodi che si desidera operare su nei modelli nell'elemento apply-templates:

<xsl:apply-templates select="tcm:Item[@componentTitle != '' 
                           and (starts-with(translate(@Title, 't', 'T'), 'T') 
                           and string(number(substring(@Title,2,3))) != 'NaN')]">

ho usato il test che @solution prodotto per questo - funziona bene per il requisito (testato qui ).

Questo è meglio di selezionare tutti i nodi tcm:Item e testare uno alla volta nel modello.

Answer 5

Lavorare con XSLT solo occasionalmente, mi si avvicinò con la seguente soluzione:

<xsl:if test="@componentTitle != ''">
  <xsl:if test="starts-with(@Title,'T') or starts-with(@Title,'t')"> 
    <xsl:if test="string-length(@Title) &gt; 3">
      <xsl:if test="string(number(substring(@Title,2,3))) != 'NaN'"> 
...
      </xsl:if>
    </xsl:if>
  </xsl:if>
</xsl:if>

ho notato che ci sono anche funzioni lower-case / upper-case che potrebbero essere utilizzati per la verifica per il primo carattere di essere un t o T ma sembrano essere disponibili solo in XSLT2.0.