開始文字をチェックすることは「t」でなければならず、次の3文字はXSLTの番号である必要があります

StackOverflow https://stackoverflow.com/questions/3645234

  •  01-10-2019
  •  | 
  •  

質問

XSLT1.0を使用してXMLを変換しています。

Tabs.xmlの下にあります 

<?xml version="1.0"?>
<tcm:ListItems xmlns:tcm="http://www.tridion.com/ContentManager/5.0" ID="tcm:481-87289-4" Managed="68">
  <tcm:Item ID="tcm:481-596728-64" Title="T000. Brisbane" pageURL="/australia/brisbane/index.aspx" componentTitle="Overview"/>
  <tcm:Item ID="tcm:481-598671-64" Title="Tabs XML"/>
  <tcm:Item ID="tcm:481-598672-64" Title="T030 Special Offers" pageURL="/australia/brisbane/specialoffers.aspx" componentTitle="Special Offers"/>
  <tcm:Item ID="tcm:481-598673-64" Title="020 Flight Schedules" pageURL="/australia/brisbane/flightschedules.aspx" componentTitle="Flight Schedules"/>
  <tcm:Item ID="tcm:481-598674-64" Title="T010 Guide" pageURL="/australia/brisbane/guide.aspx" componentTitle="Guide"/>
</tcm:ListItems>

そして、私はそれを変換するためにXSLT以下を使用しています！

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform" xmlns:tcm="http://www.tridion.com/ContentManager/5.0" xmlns:xlink="http://www.w3.org/1999/xlink" xmlns:em="http://www.emirates.com/tridion/schemas" xmlns:tcmse="http://www.tridion.com/ContentManager/5.1/TcmScriptAssistant" exclude-result-prefixes="em xlink tcmse tcm">
  <xsl:output method="xml" version="1.0" encoding="UTF-16" indent="yes"/>
  <xsl:template match="tcm:ListItems">
    <list type="Tabs">
      <xsl:apply-templates select="tcm:Item">
        <xsl:sort select="@Title" order="ascending"/>
      </xsl:apply-templates>
    </list>
  </xsl:template>
  <!-- add field values for each item-->
  <xsl:template match="tcm:Item">
    <xsl:if test="@componentTitle != ''">
      <xsl:element name="tab">
        <xsl:attribute name="id">
          <xsl:value-of select="substring-after(@ID, '-')"/>
        </xsl:attribute>
        <xsl:attribute name="title">
          <xsl:value-of select="@componentTitle"/>
        </xsl:attribute>
        <xsl:attribute name="url">
          <xsl:value-of select="@pageURL"/>
        </xsl:attribute>
      </xsl:element>
    </xsl:if>
  </xsl:template>
</xsl:stylesheet>

以前は正常に動作していましたが、今では別の変更が必要でしたが、@Titleが「T」または「T」から始まるノードをレンダリングする必要があります。フライトスケジュール」は来るべきではありません、私はちょうどもう1つを書いて条件を書く必要があると思います <xsl:if test="@componentTitle != ''">,

提案してください！それがどのようにできるか！

役に立ちましたか？

解決 5

以下のソリューションを思いついたので、大丈夫かどうかを提案してください！

<xsl:template match="tcm:Item">
    <xsl:if test="@componentTitle != '' and (starts-with(translate(@Title, 't', 'T'), 'T')and string(number(substring(@Title,2,3))) != 'NaN')">
      <xsl:element name="tab">
        <xsl:attribute name="id">
          <xsl:value-of select="substring-after(@ID, '-')"/>
        </xsl:attribute>
        <xsl:attribute name="title">
          <xsl:value-of select="@componentTitle"/>
        </xsl:attribute>
        <xsl:attribute name="url">
          <xsl:value-of select="@pageURL"/>
        </xsl:attribute>
      </xsl:element>
    </xsl:if>
  </xsl:template>

あなたのすべての入力が必要です！

他のヒント

これは、マッチングを行う最も単純な表現です。

translate(substring(@Title, 1, 4), 't12345679', 'T000000000') = 'T000'

これがテンプレートです：

<xsl:template match="
 tcm:Item[translate(substring(@Title, 1, 4), 't12345679', 'T000000000') = 'T000'
 and @componentTitle != '' "/>

選択ロジックはマッチパターンに最適です テンプレートの - そして、それも少し単純化することができます。

<xsl:template match=
 "tcm:Item[contains('tT', substring(@Title,1,1))
         and
           number(substring(@Title,2,3)) 
          =    
           number(substring(@Title,2,3)) 
          ]
 ">

覚えておくべき1つのルール: ：文字列の場合は常にテストしてください $s このような数字を表します：

number($s) = number($s)

あなたがすべき 選択する テンプレートで動作するノード apply-templates エレメント：

<xsl:apply-templates select="tcm:Item[@componentTitle != '' 
                           and (starts-with(translate(@Title, 't', 'T'), 'T') 
                           and string(number(substring(@Title,2,3))) != 'NaN')]">

私は@Solutionがこれのために生成したテストを使用しました - それは要件に適しています（テスト済み ここ).

これはすべてを選択するよりも優れています tcm:Item ノードとテストをテンプレートで1つずつテストします。

XSLTを非常にたまにしか作業していないので、次のソリューションを思いつきました。

<xsl:if test="@componentTitle != ''">
  <xsl:if test="starts-with(@Title,'T') or starts-with(@Title,'t')"> 
    <xsl:if test="string-length(@Title) &gt; 3">
      <xsl:if test="string(number(substring(@Title,2,3))) != 'NaN'"> 
...
      </xsl:if>
    </xsl:if>
  </xsl:if>
</xsl:if>

機能もあることに気付きました lower-case/upper-case これは、最初のキャラクターが t また T しかし、それらはXSLT2.0でのみ利用可能であるようです。

ライセンス： CC-BY-SA と 帰属
所属していません StackOverflow
scroll top