T-SQL: ¿Cómo usar parámetros en SQL dinámico?

Question

Tengo la siguiente consulta dinámica que funciona bien sin la cláusula WHERE , que espera UNIQUEIDENTIFIER .

Cuando lo paso, no obtengo un resultado. Intenté CAST y CONVERT , pero no obtuve ningún resultado. Podría estar haciéndolo mal, ¿alguien puede ayudarme?

CREATE PROCEDURE [dbo].[sp_Test1] /* 'b0da56dc-fc73-4c0e-85f7-541e3e8f249d' */
(
@p_CreatedBy UNIQUEIDENTIFIER
)
AS
DECLARE @sql NVARCHAR(4000)
SET @sql ='

DECLARE @p_CreatedBY UNIQUEIDENTIFIER

SELECT 
  DateTime,
  Subject,
  CreatedBy
FROM
(
  SELECT 
    DateTime, Subject, CreatedBy, 
    ROW_NUMBER() OVER(ORDER BY DateTime ) AS Indexing
  FROM
    ComposeMail
  WHERE 
    CreatedBy = @p_CreatedBy /* <--- the problem is in this condition */
) AS NewDataTable
'

EXEC sp_executesql @sql

Answer 1

Debe pasar los parámetros a sp_executesql. Consulte MSDN para obtener más información. .

...
 WHERE 
    CreatedBy = @p
...

EXECUTE sp_executesql @sql, N'@p UNIQUEIDENTIFIER', @p = @p_CreatedBY

Answer 2

DECLARE @ParmDefinition NVARCHAR(500)
SET @ParmDefinition = '@p_CreatedBy UNIQUEIDENTIFIER'

EXEC sp_executesql @sql, @ParmDefinition, @p_CreatedBy = @p_CreatedBy

Answer 3

Sintaxis de múltiples parámetros. Tal vez esto le ahorrará a alguien una Búsqueda de Google adicional:

exec sp_executesql 
    @qry, 
    N'@value1 int, @value2 int, @currentValue int', 
    @value1 = @value1, @value2 = @value2, @currentValue = @currentValue

Answer 4

No estoy seguro de si su variable se está rellenando en formato de cadena o binario, pero es posible que necesite citar el identificador único en su cláusula where. Si solo selecciona el campo identificador único, ¿vuelve como cadena o binario?