T-SQL：動的SQLでパラメーターを使用する方法

StackOverflow https://stackoverflow.com/questions/1036745

質問

UNIQUEIDENTIFIER を想定している WHERE 句なしで正常に動作する次の動的クエリがあります。

渡すと、結果が得られません。 CAST と CONVERT を試しましたが、結果はありませんでした。私は間違っているかもしれません、誰か助けてもらえますか？

CREATE PROCEDURE [dbo].[sp_Test1] /* 'b0da56dc-fc73-4c0e-85f7-541e3e8f249d' */
(
@p_CreatedBy UNIQUEIDENTIFIER
)
AS
DECLARE @sql NVARCHAR(4000)
SET @sql ='

DECLARE @p_CreatedBY UNIQUEIDENTIFIER

SELECT 
  DateTime,
  Subject,
  CreatedBy
FROM
(
  SELECT 
    DateTime, Subject, CreatedBy, 
    ROW_NUMBER() OVER(ORDER BY DateTime ) AS Indexing
  FROM
    ComposeMail
  WHERE 
    CreatedBy = @p_CreatedBy /* <--- the problem is in this condition */
) AS NewDataTable
'

EXEC sp_executesql @sql
役に立ちましたか？

解決

パラメータをsp_executesqlに渡す必要があります。 詳細については、MSDNを参照。

...
 WHERE 
    CreatedBy = @p
...

EXECUTE sp_executesql @sql, N'@p UNIQUEIDENTIFIER', @p = @p_CreatedBY

他のヒント

DECLARE @ParmDefinition NVARCHAR(500)
SET @ParmDefinition = '@p_CreatedBy UNIQUEIDENTIFIER'

EXEC sp_executesql @sql, @ParmDefinition, @p_CreatedBy = @p_CreatedBy

複数のパラメーター構文。たぶんこれは誰かに余分なGoogle検索を保存するでしょう：

exec sp_executesql 
    @qry, 
    N'@value1 int, @value2 int, @currentValue int', 
    @value1 = @value1, @value2 = @value2, @currentValue = @currentValue

変数が文字列形式またはバイナリ形式で入力されているかどうかはわかりませんが、where句でuniqueidentifierを引用する必要がある場合があります。 uniqueidentifierフィールドを選択した場合、文字列またはバイナリとして返されますか？

ライセンス： CC-BY-SA と 帰属
所属していません StackOverflow
scroll top