T-SQL: как использовать параметры в динамическом SQL?

Question

У меня есть следующий динамический запрос, который работает нормально без предложения WHERE , ожидающего UNIQUEIDENTIFIER .

Когда я передаю его, я не получаю результат. Я пробовал CAST и CONVERT , но безрезультатно. Я могу делать это неправильно, кто-нибудь может помочь?

CREATE PROCEDURE [dbo].[sp_Test1] /* 'b0da56dc-fc73-4c0e-85f7-541e3e8f249d' */
(
@p_CreatedBy UNIQUEIDENTIFIER
)
AS
DECLARE @sql NVARCHAR(4000)
SET @sql ='

DECLARE @p_CreatedBY UNIQUEIDENTIFIER

SELECT 
  DateTime,
  Subject,
  CreatedBy
FROM
(
  SELECT 
    DateTime, Subject, CreatedBy, 
    ROW_NUMBER() OVER(ORDER BY DateTime ) AS Indexing
  FROM
    ComposeMail
  WHERE 
    CreatedBy = @p_CreatedBy /* <--- the problem is in this condition */
) AS NewDataTable
'

EXEC sp_executesql @sql

Answer 1

Вы должны передать параметры sp_executesql. Подробнее см. в MSDN. .

...
 WHERE 
    CreatedBy = @p
...

EXECUTE sp_executesql @sql, N'@p UNIQUEIDENTIFIER', @p = @p_CreatedBY

Answer 2

DECLARE @ParmDefinition NVARCHAR(500)
SET @ParmDefinition = '@p_CreatedBy UNIQUEIDENTIFIER'

EXEC sp_executesql @sql, @ParmDefinition, @p_CreatedBy = @p_CreatedBy

Answer 3

Многопараметрический синтаксис. Может быть, это сэкономит кому-то дополнительный поиск Google:

exec sp_executesql 
    @qry, 
    N'@value1 int, @value2 int, @currentValue int', 
    @value1 = @value1, @value2 = @value2, @currentValue = @currentValue

Answer 4

Я не уверен, что ваша переменная заполняется в строковом или двоичном формате, но вам может потребоваться заключить в кавычки уникальный идентификатор в предложении where. Если вы просто выберете поле uniqueidentifier, оно вернется как строковое или двоичное?