¿Se puede extender una fórmula sumifs dependiente de una declaración if?

Question

Me pregunto si es posible ampliar una fórmula SUMIFS que depende de una declaración IF.

En el siguiente ejemplo, lo que quiero es si $O$5 = 0, extender la fórmula SUMIFS para que ">0" se convierta en criterio1 y luego se cree un nuevo rango_criterio2, con "<10" como criterio2.

Al mirar 'evaluar fórmula', no estoy seguro de si el problema es que no lee el bit extendido porque no es posible hacer esto, o si CHAR(34) no aparece como esperaba. .

=SUMIFS('Ingresos'!$G$1:$G$100,'Ingresos'!$H$1:$H$100,IF($O$5=0,CHAR(34)&">0"&CHAR(34)&" ,"&"'Ingresos'!$H$1:$H$100"&","&CHAR(34)&"<10"&CHAR(34),$O$5))

¡Cualquier ayuda sería muy apreciada!¡Gracias!

Answer 1

Si desea utilizar SUMIFs, debería ser algo como esto:

camino №1

=SUMIFS(Revenue!$G$1:$G$100,Revenue!$H$1:$H$100,IF($O$5=0,">0",$O$5),
                            Revenue!$H$1:$H$100,IF($O$5=0,"<10",$O$5)
 )

Si O5=0, la fórmula se evalúa como:

=SUMIFS(Revenue!$G$1:$G$100,Revenue!$H$1:$H$100,">0",
                            Revenue!$H$1:$H$100,"<10"
 )

Si O5<>0, la fórmula se evalúa como:

=SUMIFS(Revenue!$G$1:$G$100,Revenue!$H$1:$H$100,$O$5,
                            Revenue!$H$1:$H$100,$O$5
 )

que en realidad te da el mismo resultado que

=SUMIFS(Revenue!$G$1:$G$100,Revenue!$H$1:$H$100,$O$5)

---

camino №2

=IF($O$5=0,
  SUMIFs(Revenue!$G$1:$G$100,Revenue!$H$1:$H$100,">0",
                             Revenue!$H$1:$H$100,"<10"),
  SUMIFs(Revenue!$G$1:$G$100,Revenue!$H$1:$H$100,$O$5)
 )

Si O5=0, la fórmula se evalúa como:

=SUMIFS(Revenue!$G$1:$G$100,Revenue!$H$1:$H$100,">0",
                            Revenue!$H$1:$H$100,"<10"
 )

Si O5<>0, la fórmula se evalúa como:

=SUMIFS(Revenue!$G$1:$G$100,Revenue!$H$1:$H$100,$O$5)

---

camino №3

O también puedes usar sumproduct:

=SUMPRODUCT((Revenue!$G$1:$G$100)*
            IF($O$5=0,(Revenue!$H$1:$H$100>0)*(Revenue!$H$1:$H$100<10),
                      (Revenue!$H$1:$H$100=$O$5)
            )
 )

Esto es un fórmula matricial, entonces escriba la fórmula y luego presione CONTROL+CAMBIO+INGRESAR.Las llaves aparecerán automáticamente al principio y al final de la fórmula.

Si O5=0, la fórmula se evalúa como:

=SUMPRODUCT((Revenue!$G$1:$G$100)*(Revenue!$H$1:$H$100>0)*
                                  (Revenue!$H$1:$H$100<10)
 )

Si O5<>0, la fórmula se evalúa como:

=SUMPRODUCT((Revenue!$G$1:$G$100)*(Revenue!$H$1:$H$100=$O$5))