XSLT aplicado a XML doc con el atributo xmlns
-
05-07-2019 - |
Pregunta
Estoy aplicando una hoja de estilo XSLT al siguiente archivo XML:
<top xmlns="http://www.foo.com/bar">
<elementA />
<elementB />
<contents>
<contentitem>
<id>3</id>
<moretags1 />
<moretags2 />
</contentitem>
<contentitem>
<id>2</id>
<moretags1 />
<moretags2 />
</contentitem>
<contentitem>
<id>1</id>
<moretags1 />
<moretags2 />
</contentitem>
</contents>
</top>
Aquí está mi archivo XSLT actual (realiza una ordenación simple):
<xsl:stylesheet version="1.0"
xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
xmlns:doc="http://www.foo.com/bar">
<xsl:output omit-xml-declaration="yes" indent="yes"/>
<!-- -->
<xsl:strip-space elements="*"/>
<!-- -->
<xsl:template match="node()|@*">
<xsl:copy>
<xsl:apply-templates select="node()|@*"/>
</xsl:copy>
</xsl:template>
<!-- -->
<xsl:template match="contents">
<xsl:copy>
<xsl:apply-templates select="@*"/>
<xsl:apply-templates select="contentitem">
<xsl:sort select="id" data-type="number"/>
</xsl:apply-templates>
</xsl:copy>
</xsl:template>
</xsl:stylesheet>
El problema es que no sé exactamente cómo usar el prefijo de espacio de nombres 'doc:' con las etiquetas xsl: template y xsl: apply-templates.
En este momento, el documento XML se copia como está, por lo que creo que se está aplicando el primer bloque xsl: template. Sin embargo, los elementos no están clasificados, por lo que creo que el problema radica en la segunda xsl: template.
Debo tener en cuenta que si elimino los atributos xmlns de ambos archivos, la transformación funcionará correctamente.
¿Alguna sugerencia?
(la pregunta se basa en este ejemplo )
Solución
¿Ha intentado prefijar nombres de elementos con el prefijo de espacio de nombres doc:
en sus atributos seleccionados?
<xsl:template match="doc:contents">
<xsl:copy>
<xsl:apply-templates select="@*"/>
<xsl:apply-templates select="doc:contentitem">
<xsl:sort select="doc:id" data-type="number"/>
</xsl:apply-templates>
</xsl:copy>
</xsl:template>