xmlns属性を持つXMLドキュメントに適用されるXSLT

Question

XSLTスタイルシートを次のXMLファイルに適用しています：

<top xmlns="http://www.foo.com/bar">
    <elementA />
    <elementB />
    <contents>
        <contentitem>
                <id>3</id>
                <moretags1 />
                <moretags2 />
        </contentitem>
        <contentitem>
                <id>2</id>
                <moretags1 />
                <moretags2 />
        </contentitem>
        <contentitem>
                <id>1</id>
                <moretags1 />
                <moretags2 />
        </contentitem>
    </contents>
</top>

現在のXSLTファイルは次のとおりです（簡単な並べ替えを実行します）：

<xsl:stylesheet version="1.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
 xmlns:doc="http://www.foo.com/bar">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>
<!--                                                -->
 <xsl:strip-space elements="*"/>
<!--                                                -->
  <xsl:template match="node()|@*">
    <xsl:copy>
      <xsl:apply-templates select="node()|@*"/>
    </xsl:copy>
  </xsl:template>
<!--                                                -->
  <xsl:template match="contents">
    <xsl:copy>
      <xsl:apply-templates select="@*"/>
      <xsl:apply-templates select="contentitem">
        <xsl:sort select="id" data-type="number"/>
      </xsl:apply-templates>
    </xsl:copy>
  </xsl:template>
</xsl:stylesheet>

問題は、xsl：templateおよびxsl：apply-templatesタグで 'doc：'名前空間プレフィックスを使用する方法が正確にはわからないことです。

現在、XMLドキュメントはそのままコピーされているため、最初のxsl：templateブロックが適用されていると思います。ただし、アイテムはソートされていないため、問題は2番目のxsl：templateにあると思います。

両方のファイルからxmlns属性を削除すると、変換が適切に機能することに注意してください。

提案はありますか

（質問はこの例に基づいています）

Answer 1

選択属性で要素名の前に doc：名前空間プレフィックスを付けましたか？

<xsl:template match="doc:contents">
  <xsl:copy>
    <xsl:apply-templates select="@*"/>
    <xsl:apply-templates select="doc:contentitem">
      <xsl:sort select="doc:id" data-type="number"/>
    </xsl:apply-templates>
  </xsl:copy>
</xsl:template>