XSLT применяется к XML документу с атрибутом xmlns

Question

Я применяю таблицу стилей XSLT к следующему XML-файлу:

<top xmlns="http://www.foo.com/bar">
    <elementA />
    <elementB />
    <contents>
        <contentitem>
                <id>3</id>
                <moretags1 />
                <moretags2 />
        </contentitem>
        <contentitem>
                <id>2</id>
                <moretags1 />
                <moretags2 />
        </contentitem>
        <contentitem>
                <id>1</id>
                <moretags1 />
                <moretags2 />
        </contentitem>
    </contents>
</top>

Вот мой текущий XSLT-файл (выполняет простую сортировку):

<xsl:stylesheet version="1.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
 xmlns:doc="http://www.foo.com/bar">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>
<!--                                                -->
 <xsl:strip-space elements="*"/>
<!--                                                -->
  <xsl:template match="node()|@*">
    <xsl:copy>
      <xsl:apply-templates select="node()|@*"/>
    </xsl:copy>
  </xsl:template>
<!--                                                -->
  <xsl:template match="contents">
    <xsl:copy>
      <xsl:apply-templates select="@*"/>
      <xsl:apply-templates select="contentitem">
        <xsl:sort select="id" data-type="number"/>
      </xsl:apply-templates>
    </xsl:copy>
  </xsl:template>
</xsl:stylesheet>

Проблема в том, что я не знаю точно, как использовать префикс пространства имен 'doc:' с тегами xsl: template и xsl: apply-templates.

В данный момент документ XML копируется как есть, поэтому я считаю, что применяется первый блок xsl: template. Тем не менее, элементы не отсортированы, поэтому я думаю, что проблема заключается во втором xsl: template.

Следует отметить, что если я удалю атрибуты xmlns из обоих файлов, преобразование будет работать правильно.

Есть предложения?

(вопрос основан на этом примере )

Answer 1

Пробовали ли вы использовать префикс имен элементов с префиксом пространства имен doc: в ваших атрибутах select?

<xsl:template match="doc:contents">
  <xsl:copy>
    <xsl:apply-templates select="@*"/>
    <xsl:apply-templates select="doc:contentitem">
      <xsl:sort select="doc:id" data-type="number"/>
    </xsl:apply-templates>
  </xsl:copy>
</xsl:template>