SQL Server: imposta tutti i casi UPPER su Case / Title Case appropriati
-
04-07-2019 - |
Domanda
Ho una tabella che è stata importata come tutto il MAIUSCOLO e vorrei trasformarla in caso corretto. Quale script hai usato qualcuno di voi per completare questo?
Soluzione
Ecco un UDF che farà il trucco ...
create function ProperCase(@Text as varchar(8000))
returns varchar(8000)
as
begin
declare @Reset bit;
declare @Ret varchar(8000);
declare @i int;
declare @c char(1);
if @Text is null
return null;
select @Reset = 1, @i = 1, @Ret = '';
while (@i <= len(@Text))
select @c = substring(@Text, @i, 1),
@Ret = @Ret + case when @Reset = 1 then UPPER(@c) else LOWER(@c) end,
@Reset = case when @c like '[a-zA-Z]' then 0 else 1 end,
@i = @i + 1
return @Ret
end
Dovrai comunque usarlo per aggiornare i tuoi dati.
Altri suggerimenti
Questa funzione:
- "Casi appropriati" tutto il "MAIUSCOLO" " parole delimitate da spazi bianchi
- lascia " parole minuscole " solo
- funziona correttamente anche per alfabeti non inglesi
- è portatile in quanto non utilizza le fantasiose funzionalità delle recenti versioni del server SQL
- può essere facilmente modificato per utilizzare NCHAR e NVARCHAR per il supporto Unicode, nonché qualsiasi lunghezza di parametro ritenuta adatta
- la definizione dello spazio bianco può essere configurata
CREATE FUNCTION ToProperCase(@string VARCHAR(255)) RETURNS VARCHAR(255)
AS
BEGIN
DECLARE @i INT -- index
DECLARE @l INT -- input length
DECLARE @c NCHAR(1) -- current char
DECLARE @f INT -- first letter flag (1/0)
DECLARE @o VARCHAR(255) -- output string
DECLARE @w VARCHAR(10) -- characters considered as white space
SET @w = '[' + CHAR(13) + CHAR(10) + CHAR(9) + CHAR(160) + ' ' + ']'
SET @i = 1
SET @l = LEN(@string)
SET @f = 1
SET @o = ''
WHILE @i <= @l
BEGIN
SET @c = SUBSTRING(@string, @i, 1)
IF @f = 1
BEGIN
SET @o = @o + @c
SET @f = 0
END
ELSE
BEGIN
SET @o = @o + LOWER(@c)
END
IF @c LIKE @w SET @f = 1
SET @i = @i + 1
END
RETURN @o
END
Risultato:
dbo.ToProperCase('ALL UPPER CASE and SOME lower ÄÄ ÖÖ ÜÜ ÉÉ ØØ ĈĈ ÆÆ')
-----------------------------------------------------------------
All Upper Case and Some lower Ää Öö Üü Éé Øø Cc Ææ
UPDATE titles
SET title =
UPPER(LEFT(title, 1)) +
LOWER(RIGHT(title, LEN(title) - 1))
Se è possibile abilitare il CLR in SQL Server (richiede 2005 o versione successiva), è possibile crea una funzione CLR che utilizza la TextInfo.ToTitleCase funzione integrata che ti consentirebbe di creare un modo consapevole della cultura di farlo in poche righe di codice.
Sono un po 'in ritardo nel gioco, ma credo che sia più funzionale e funzioni con qualsiasi lingua, inclusi russo, tedesco, tailandese, vietnamita ecc. Farà maiuscole qualsiasi cosa dopo 'o - o. o (o) o spazio (ovviamente :).
CREATE FUNCTION [dbo].[fnToProperCase]( @name nvarchar(500) )
RETURNS nvarchar(500)
AS
BEGIN
declare @pos int = 1
, @pos2 int
if (@name <> '')--or @name = lower(@name) collate SQL_Latin1_General_CP1_CS_AS or @name = upper(@name) collate SQL_Latin1_General_CP1_CS_AS)
begin
set @name = lower(rtrim(@name))
while (1 = 1)
begin
set @name = stuff(@name, @pos, 1, upper(substring(@name, @pos, 1)))
set @pos2 = patindex('%[- ''.)(]%', substring(@name, @pos, 500))
set @pos += @pos2
if (isnull(@pos2, 0) = 0 or @pos > len(@name))
break
end
end
return @name
END
GO
So che questo post è in ritardo in questa discussione ma, vale la pena cercare. Questa funzione è sempre attiva per me. Quindi ho pensato di condividerlo.
CREATE FUNCTION [dbo].[fnConvert_TitleCase] (@InputString VARCHAR(4000) )
RETURNS VARCHAR(4000)
AS
BEGIN
DECLARE @Index INT
DECLARE @Char CHAR(1)
DECLARE @OutputString VARCHAR(255)
SET @OutputString = LOWER(@InputString)
SET @Index = 2
SET @OutputString = STUFF(@OutputString, 1, 1,UPPER(SUBSTRING(@InputString,1,1)))
WHILE @Index <= LEN(@InputString)
BEGIN
SET @Char = SUBSTRING(@InputString, @Index, 1)
IF @Char IN (' ', ';', ':', '!', '?', ',', '.', '_', '-', '/', '&','''','(')
IF @Index + 1 <= LEN(@InputString)
BEGIN
IF @Char != ''''
OR
UPPER(SUBSTRING(@InputString, @Index + 1, 1)) != 'S'
SET @OutputString =
STUFF(@OutputString, @Index + 1, 1,UPPER(SUBSTRING(@InputString, @Index + 1, 1)))
END
SET @Index = @Index + 1
END
RETURN ISNULL(@OutputString,'')
END
Test chiamate:
select dbo.fnConvert_TitleCase(Upper('ÄÄ ÖÖ ÜÜ ÉÉ ØØ ĈĈ ÆÆ')) as test
select dbo.fnConvert_TitleCase(upper('Whatever the mind of man can conceive and believe, it can achieve. – Napoleon hill')) as test
Risultati:
Se ti trovi in ??SSIS per l'importazione di dati con casing misto e devi eseguire una ricerca su una colonna con il caso corretto, noterai che la ricerca non riesce nel punto in cui la sorgente è mista e la fonte di ricerca è corretta. Noterai anche che non puoi usare le funzioni destra e sinistra è SSIS per SQL Server 2008r2 per le colonne derivate. Ecco una soluzione che funziona per me:
UPPER(substring(input_column_name,1,1)) + LOWER(substring(input_column_name, 2, len(input_column_name)-1))
Il link che ho pubblicato sopra è un'ottima opzione che affronta il problema principale: che non possiamo mai rendere conto programmaticamente di tutti i casi (Smith-Jones, von Haussen, John Smith M.D.), almeno non in modo elegante. Tony introduce il concetto di carattere di eccezione / pausa per gestire questi casi. Ad ogni modo, basandosi sull'idea di Cervo (in alto tutti i caratteri inferiori preceduti dallo spazio), le istruzioni di sostituzione potrebbero invece essere racchiuse in una singola tabella basata su sostituto. In realtà, qualsiasi combinazione di caratteri low / up potrebbe essere inserita in @alpha e la dichiarazione non cambierebbe:
declare @str nvarchar(8000)
declare @alpha table (low nchar(1), up nchar(1))
set @str = 'ALL UPPER CASE and SOME lower ÄÄ ÖÖ ÜÜ ÉÉ ØØ ĈĈ ÆÆ'
-- stage the alpha (needs number table)
insert into @alpha
-- A-Z / a-z
select nchar(n+32),
nchar(n)
from dbo.Number
where n between 65 and 90 or
n between 192 and 223
-- append space at start of str
set @str = lower(' ' + @str)
-- upper all lower case chars preceded by space
select @str = replace(@str, ' ' + low, ' ' + up)
from @Alpha
select @str
Ecco una versione che utilizza una sequenza o una tabella numerica anziché un ciclo. Puoi modificare la clausola WHERE per modificare le tue regole personali per quando convertire un personaggio in maiuscolo. Ho appena incluso un set semplice che renderà maiuscole tutte le lettere che sono precedute da una non lettera ad eccezione degli apostrofi. Questo significa comunque che 123apple avrebbe una corrispondenza su " a " perché " 3 " non è una lettera. Se vuoi solo spazi bianchi (spazio, tabulazione, ritorno a capo, avanzamento riga), puoi sostituire il modello '[^ az]'
con '[' + Char (32 ) + Char (9) + Char (13) + Char (10) + ']'
.
CREATE FUNCTION String.InitCap( @string nvarchar(4000) ) RETURNS nvarchar(4000) AS
BEGIN
-- 1. Convert all letters to lower case
DECLARE @InitCap nvarchar(4000); SET @InitCap = Lower(@string);
-- 2. Using a Sequence, replace the letters that should be upper case with their upper case version
SELECT @InitCap = Stuff( @InitCap, n, 1, Upper( SubString( @InitCap, n, 1 ) ) )
FROM (
SELECT (1 + n1.n + n10.n + n100.n + n1000.n) AS n
FROM (SELECT 0 AS n UNION SELECT 1 UNION SELECT 2 UNION SELECT 3 UNION SELECT 4 UNION SELECT 5 UNION SELECT 6 UNION SELECT 7 UNION SELECT 8 UNION SELECT 9) AS n1
CROSS JOIN (SELECT 0 AS n UNION SELECT 10 UNION SELECT 20 UNION SELECT 30 UNION SELECT 40 UNION SELECT 50 UNION SELECT 60 UNION SELECT 70 UNION SELECT 80 UNION SELECT 90) AS n10
CROSS JOIN (SELECT 0 AS n UNION SELECT 100 UNION SELECT 200 UNION SELECT 300 UNION SELECT 400 UNION SELECT 500 UNION SELECT 600 UNION SELECT 700 UNION SELECT 800 UNION SELECT 900) AS n100
CROSS JOIN (SELECT 0 AS n UNION SELECT 1000 UNION SELECT 2000 UNION SELECT 3000) AS n1000
) AS Sequence
WHERE
n BETWEEN 1 AND Len( @InitCap )
AND SubString( @InitCap, n, 1 ) LIKE '[a-z]' /* this character is a letter */
AND (
n = 1 /* this character is the first `character` */
OR SubString( @InitCap, n-1, 1 ) LIKE '[^a-z]' /* the previous character is NOT a letter */
)
AND (
n < 3 /* only test the 3rd or greater characters for this exception */
OR SubString( @InitCap, n-2, 3 ) NOT LIKE '[a-z]''[a-z]' /* exception: The pattern <letter>'<letter> should not capatolize the letter following the apostrophy */
)
-- 3. Return the modified version of the input
RETURN @InitCap
END
Avrebbe senso mantenere una ricerca di eccezioni per occuparsi di The von Neumann, di McCain, di DeGuzman e di Johnson-Smith.
Penso che scoprirai che quanto segue è più efficiente:
IF OBJECT_ID('dbo.ProperCase') IS NOT NULL
DROP FUNCTION dbo.ProperCase
GO
CREATE FUNCTION dbo.PROPERCASE (
@str VARCHAR(8000))
RETURNS VARCHAR(8000)
AS
BEGIN
SET @str = ' ' + @str
SET @str = REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE( @str, ' a', ' A'), ' b', ' B'), ' c', ' C'), ' d', ' D'), ' e', ' E'), ' f', ' F'), ' g', ' G'), ' h', ' H'), ' i', ' I'), ' j', ' J'), ' k', ' K'), ' l', ' L'), ' m', ' M'), ' n', ' N'), ' o', ' O'), ' p', ' P'), ' q', ' Q'), ' r', ' R'), ' s', ' S'), ' t', ' T'), ' u', ' U'), ' v', ' V'), ' w', ' W'), ' x', ' X'), ' y', ' Y'), ' z', ' Z')
RETURN RIGHT(@str, LEN(@str) - 1)
END
GO
L'istruzione di sostituzione potrebbe essere tagliata e incollata direttamente in una query SQL. È ultra brutto, tuttavia sostituendo @str con la colonna che ti interessa, non pagherai un prezzo per un cursore implicito come faresti con gli udfs così pubblicati. Trovo che anche usando il mio UDF sia molto più efficiente.
Oh e invece di generare manualmente la dichiarazione di sostituzione usa questo:
-- Code Generator for expression
DECLARE @x INT,
@c CHAR(1),
@sql VARCHAR(8000)
SET @x = 0
SET @sql = '@str' -- actual variable/column you want to replace
WHILE @x < 26
BEGIN
SET @c = CHAR(ASCII('a') + @x)
SET @sql = 'REPLACE(' + @sql + ', '' ' + @c+ ''', '' ' + UPPER(@c) + ''')'
SET @x = @x + 1
END
PRINT @sql
Comunque dipende dal numero di righe. Vorrei che tu potessi semplicemente fare s / \ b ([a-z]) / uc $ 1 /, ma vabbè lavoriamo con gli strumenti che abbiamo.
NOTA dovresti usarlo come dovresti usarlo come .... SELEZIONA dbo.ProperCase (LOWER (colonna)) poiché la colonna è in maiuscolo. In realtà funziona abbastanza velocemente sulla mia tabella di 5.000 voci (nemmeno un secondo) anche con il valore più basso.
In risposta alla raffica di commenti sull'internazionalizzazione, presento la seguente implementazione che gestisce tutti i caratteri ASCII facendo affidamento solo sull'implementazione di SQL Server di upper e lower. Ricorda, le variabili che stiamo usando qui sono VARCHAR, il che significa che possono contenere solo valori ASCII. Per utilizzare ulteriori alfabeti internazionali, è necessario utilizzare NVARCHAR. La logica sarebbe simile ma dovresti usare UNICODE e NCHAR al posto di ASCII E CHAR e la dichiarazione di sostituzione sarebbe molto più grande ....
-- Code Generator for expression
DECLARE @x INT,
@c CHAR(1),
@sql VARCHAR(8000),
@count INT
SEt @x = 0
SET @count = 0
SET @sql = '@str' -- actual variable you want to replace
WHILE @x < 256
BEGIN
SET @c = CHAR(@x)
-- Only generate replacement expression for characters where upper and lowercase differ
IF @x = ASCII(LOWER(@c)) AND @x != ASCII(UPPER(@c))
BEGIN
SET @sql = 'REPLACE(' + @sql + ', '' ' + @c+ ''', '' ' + UPPER(@c) + ''')'
SET @count = @count + 1
END
SET @x = @x + 1
END
PRINT @sql
PRINT 'Total characters substituted: ' + CONVERT(VARCHAR(255), @count)
Fondamentalmente la premessa del mio metodo è il trading pre-computing per l'efficienza. L'implementazione ASCII completa è la seguente:
IF OBJECT_ID('dbo.ProperCase') IS NOT NULL
DROP FUNCTION dbo.ProperCase
GO
CREATE FUNCTION dbo.PROPERCASE (
@str VARCHAR(8000))
RETURNS VARCHAR(8000)
AS
BEGIN
SET @str = ' ' + @str
SET @str = REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(@str, ' a', ' A'), ' b', ' B'), ' c', ' C'), ' d', ' D'), ' e', ' E'), ' f', ' F'), ' g', ' G'), ' h', ' H'), ' i', ' I'), ' j', ' J'), ' k', ' K'), ' l', ' L'), ' m', ' M'), ' n', ' N'), ' o', ' O'), ' p', ' P'), ' q', ' Q'), ' r', ' R'), ' s', ' S'), ' t', ' T'), ' u', ' U'), ' v', ' V'), ' w', ' W'), ' x', ' X'), ' y', ' Y'), ' z', ' Z'), ' š', ' Š'), ' œ', ' Œ'), ' ž', ' Ž'), ' à', ' À'), ' á', ' Á'), ' â', ' Â'), ' ã', ' Ã'), ' ä', ' Ä'), ' å', ' Å'), ' æ', ' Æ'), ' ç', ' Ç'), ' è', ' È'), ' é', ' É'), ' ê', ' Ê'), ' ë', ' Ë'), ' ì', ' Ì'), ' í', ' Í'), ' î', ' Î'), ' ï', ' Ï'), ' ð', ' Ð'), ' ñ', ' Ñ'), ' ò', ' Ò'), ' ó', ' Ó'), ' ô', ' Ô'), ' õ', ' Õ'), ' ö', ' Ö'), ' ø', ' Ø'), ' ù', ' Ù'), ' ú', ' Ú'), ' û', ' Û'), ' ü', ' Ü'), ' ý', ' Ý'), ' þ', ' Þ'), ' ÿ', ' Ÿ')
RETURN RIGHT(@str, LEN(@str) - 1)
END
GO
È troppo tardi per tornare indietro e ottenere i dati non maiuscoli?
A von Neumann, McCain, DeGuzman e Johnson-Smith della tua base di clienti potrebbe non piacere il risultato della tua elaborazione ...
Inoltre, immagino che questo debba essere un aggiornamento una tantum dei dati? Potrebbe essere più semplice esportare, filtrare / modificare e reimportare i nomi corretti nel db, quindi è possibile utilizzare approcci non SQL per la correzione dei nomi ...
Ecco un'altra variante che ho trovato nei forum SQLTeam.com @ http://www.sqlteam.com/forums/topic.asp?TOPIC_ID= 47718
create FUNCTION PROPERCASE
(
--The string to be converted to proper case
@input varchar(8000)
)
--This function returns the proper case string of varchar type
RETURNS varchar(8000)
AS
BEGIN
IF @input IS NULL
BEGIN
--Just return NULL if input string is NULL
RETURN NULL
END
--Character variable declarations
DECLARE @output varchar(8000)
--Integer variable declarations
DECLARE @ctr int, @len int, @found_at int
--Constant declarations
DECLARE @LOWER_CASE_a int, @LOWER_CASE_z int, @Delimiter char(3), @UPPER_CASE_A int, @UPPER_CASE_Z int
--Variable/Constant initializations
SET @ctr = 1
SET @len = LEN(@input)
SET @output = ''
SET @LOWER_CASE_a = 97
SET @LOWER_CASE_z = 122
SET @Delimiter = ' ,-'
SET @UPPER_CASE_A = 65
SET @UPPER_CASE_Z = 90
WHILE @ctr <= @len
BEGIN
--This loop will take care of reccuring white spaces
WHILE CHARINDEX(SUBSTRING(@input,@ctr,1), @Delimiter) > 0
BEGIN
SET @output = @output + SUBSTRING(@input,@ctr,1)
SET @ctr = @ctr + 1
END
IF ASCII(SUBSTRING(@input,@ctr,1)) BETWEEN @LOWER_CASE_a AND @LOWER_CASE_z
BEGIN
--Converting the first character to upper case
SET @output = @output + UPPER(SUBSTRING(@input,@ctr,1))
END
ELSE
BEGIN
SET @output = @output + SUBSTRING(@input,@ctr,1)
END
SET @ctr = @ctr + 1
WHILE CHARINDEX(SUBSTRING(@input,@ctr,1), @Delimiter) = 0 AND (@ctr <= @len)
BEGIN
IF ASCII(SUBSTRING(@input,@ctr,1)) BETWEEN @UPPER_CASE_A AND @UPPER_CASE_Z
BEGIN
SET @output = @output + LOWER(SUBSTRING(@input,@ctr,1))
END
ELSE
BEGIN
SET @output = @output + SUBSTRING(@input,@ctr,1)
END
SET @ctr = @ctr + 1
END
END
RETURN @output
END
GO
SET QUOTED_IDENTIFIER OFF
GO
SET ANSI_NULLS ON
GO
So che il diavolo è nei dettagli (specialmente per quanto riguarda i dati personali delle persone), e che sarebbe molto bello avere nomi correttamente in maiuscolo, ma il tipo di seccatura di cui sopra è il motivo per cui il pragmatico, attento al tempo tra noi utilizzare quanto segue:
SELEZIONA UPPER ('Metti YoUR O'So stranamente incatenato McWeird-nAme von right QUI qui')
Nella mia esperienza, le persone stanno bene vedendo IL LORO NOME ... anche quando è a metà di una frase.
Fare riferimento a: i russi hanno usato una matita!
Ho appena saputo di InitCap ()
.
Ecco un codice di esempio:
SELECT ID
,InitCap(LastName ||', '|| FirstName ||' '|| Nvl(MiddleName,'')) AS RecipientName
FROM SomeTable
Funzionava in SSMS:
Select Jobtitle,
concat(Upper(LEFT(jobtitle,1)), SUBSTRING(jobtitle,2,LEN(jobtitle))) as Propercase
From [HumanResources].[Employee]
Preso in prestito e migliorato sulla risposta di @Richard Sayakanit. Questo gestisce più parole. Come la sua risposta, questo non utilizza alcun UDF, ma solo funzioni integrate ( STRING_SPLIT
e STRING_AGG
) ed è piuttosto veloce. STRING_AGG
richiede SQL Server 2017 ma puoi sempre utilizzare il trucco STUFF / XML
. Non gestirà ogni eccezione, ma può funzionare alla grande per molti requisiti.
SELECT StateName = 'North Carolina'
INTO #States
UNION ALL
SELECT 'Texas'
;WITH cteData AS
(
SELECT
UPPER(LEFT(value, 1)) +
LOWER(RIGHT(value, LEN(value) - 1)) value, op.StateName
FROM #States op
CROSS APPLY STRING_SPLIT(op.StateName, ' ') AS ss
)
SELECT
STRING_AGG(value, ' ')
FROM cteData c
GROUP BY StateName
Se sai che tutti i dati sono solo una parola, ecco una soluzione. Per prima cosa aggiorna la colonna in basso e quindi esegui quanto segue
update tableName set columnName =
upper(SUBSTRING(columnName, 1, 1)) + substring(columnName, 2, len(columnName)) from tableName
Una leggera modifica alla risposta di @ Galwegian - che si trasforma ad es. St Elizabeth's
in St Elizabeth'S
.
Questa modifica mantiene gli apostrofi come lettere minuscole dove la s arriva alla fine della stringa fornita o la s è seguita da uno spazio (e solo in quelle circostanze).
create function properCase(@text as varchar(8000))
returns varchar(8000)
as
begin
declare @reset int;
declare @ret varchar(8000);
declare @i int;
declare @c char(1);
declare @d char(1);
if @text is null
return null;
select @reset = 1, @i = 1, @ret = '';
while (@i <= len(@text))
select
@c = substring(@text, @i, 1),
@d = substring(@text, @i+1, 1),
@ret = @ret + case when @reset = 1 or (@reset=-1 and @c!='s') or (@reset=-1 and @c='s' and @d!=' ') then upper(@c) else lower(@c) end,
@reset = case when @c like '[a-za-z]' then 0 when @c='''' then -1 else 1 end,
@i = @i + 1
return @ret
end
Si trasforma:
-
st elizabeth's
inSt Elizabeth's
-
o'keefe
inO'Keefe
-
o'sullivan
inO'Sullivan
I commenti di altri che sono preferibili soluzioni diverse per input non inglesi