XSLT aplicado ao documento XML com o atributo xmlns
-
05-07-2019 - |
Pergunta
Estou aplicando uma folha de estilo XSLT para o seguinte arquivo XML:
<top xmlns="http://www.foo.com/bar">
<elementA />
<elementB />
<contents>
<contentitem>
<id>3</id>
<moretags1 />
<moretags2 />
</contentitem>
<contentitem>
<id>2</id>
<moretags1 />
<moretags2 />
</contentitem>
<contentitem>
<id>1</id>
<moretags1 />
<moretags2 />
</contentitem>
</contents>
</top>
Aqui está o meu arquivo XSLT atual (executa uma espécie simples):
<xsl:stylesheet version="1.0"
xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
xmlns:doc="http://www.foo.com/bar">
<xsl:output omit-xml-declaration="yes" indent="yes"/>
<!-- -->
<xsl:strip-space elements="*"/>
<!-- -->
<xsl:template match="node()|@*">
<xsl:copy>
<xsl:apply-templates select="node()|@*"/>
</xsl:copy>
</xsl:template>
<!-- -->
<xsl:template match="contents">
<xsl:copy>
<xsl:apply-templates select="@*"/>
<xsl:apply-templates select="contentitem">
<xsl:sort select="id" data-type="number"/>
</xsl:apply-templates>
</xsl:copy>
</xsl:template>
</xsl:stylesheet>
O problema é que eu não sei exatamente como usar o 'doc:' namespace prefix com o xsl: template e xsl:. Apply-modelos Tags
Agora, o documento XML é copiado como está, então eu acredito que o primeiro xsl: bloco do modelo está sendo aplicado. No entanto, os itens são indiferenciados, então eu acho que as mentiras problema na segunda xsl:. Template
Gostaria de salientar que se eu remover os atributos xmlns de ambos os arquivos, a transformação funciona corretamente.
Todas as sugestões?
(pergunta é baseada em este exemplo )
Solução
Você já tentou prefixar nomes de elementos com o prefixo namespace doc:
em seus atributos selecionados?
<xsl:template match="doc:contents">
<xsl:copy>
<xsl:apply-templates select="@*"/>
<xsl:apply-templates select="doc:contentitem">
<xsl:sort select="doc:id" data-type="number"/>
</xsl:apply-templates>
</xsl:copy>
</xsl:template>