Инфиксный формат для макроса Nemerle

Question

Скажем, мне нужен очень специальный оператор умножения. Это может быть реализовано в следующем макросе:

macro @<<!(op1, op2)
{
    <[ ( $op1 * $op2 ) ]>
}

И я могу использовать это как

def val = 2 <<! 3

И его работа.

Но что мне действительно нужно, так это некоторый «английский» оператор для DSL, который я сейчас разрабатываю:

macro @multiply(op1, op2)
{
    <[ ( $op1 * $op2 ) ]>
}

и если я попытаюсь использовать его как

def val = 2 multiply 3

компилятор завершается неудачно с ожидаемым; ошибка

В чем проблема? Как я могу реализовать этот макрос в формате infix?

Answer 1

Прямо из исходного кода компилятора:

namespace Nemerle.English
{
  [assembly: Nemerle.Internal.OperatorAttribute ("Nemerle.English", "and", false, 160, 161)]
  [assembly: Nemerle.Internal.OperatorAttribute ("Nemerle.English", "or", false, 150, 151)]
  [assembly: Nemerle.Internal.OperatorAttribute ("Nemerle.English", "not", true, 181, 180)]  

  macro @and (e1, e2) {
    <[ $e1 && $e2 ]>
  }

  macro @or (e1, e2) {
    <[ $e1 || $e2 ]>
  }

  macro @not (e) {
    <[ ! $e ]>
  }

Вам нужно разбросать атрибуты OperatorAttributes, и это будет работать. Кстати, OperatorAttribute определяется следующим образом:

public class OperatorAttribute : NemerleAttribute
{
  public mutable env : string;
  public mutable name : string;
  public mutable IsUnary : bool;
  public mutable left : int;
  public mutable right : int;
}

Answer 2

Как обычно, я нашел ответ раньше, чем сообщество ответило :) Таким образом, решение состоит в том, чтобы просто использовать специальный атрибут уровня сборки, который определяет макрос как бинарный оператор:

namespace TestMacroLib
{
  [assembly: Nemerle.Internal.OperatorAttribute ("TestMacroLib", "multiply", false, 160, 161)]
  public macro multiply(op1, op2)
  {
    <[ ( $op1 * $op2 ) ]>
  }
}