Clojure：从序列中查找顺序项目

Question

在一个Clojure程序中，我有一系列数字：

(2 3 4 6 8 1)

我想找到最长的子序列，其中这些项目是顺序的：

(2 3 4)

我假设它将涉及 (take-while ...) 或者 (reduce ...).

有任何想法吗？

澄清: ：我需要最长的顺序项目列表。我敢肯定。感谢您最初提出的更困难的问题的解决方案。

Answer 1

如果您只对最长的初始序列感兴趣，那是一个1栏：

(defn longest-initial-sequence [[x :as s]]
  (take-while identity (map #(#{%1} %2) s (iterate inc x))))

Answer 2

考虑到OP对问题的评论 - 这完全改变了游戏！ - 这可以写得很简单：

(let [doubletons (partition 2 1 [1 2 3 5 6])
      increment? (fn increment? [[x y]]
                   (== (inc x) y))]
  (cons (ffirst doubletons)
        (map second (take-while increment? doubletons))))

;; returns (1 2 3)

请注意，这实际上是懒惰的。我希望它不抓住 doubletons 感谢当地人清算。另一个版本：

(cons (first [1 2 3 5 6])
      (map second (take-while increment? (partition 2 1 [1 2 3 5 6]))))

不过，这个问题的原始版本更有趣！ :-)可以使用上述构建的超简单解决方案，但是当然，这比使用的性能要少得多 reduce. 。我将看看我是否有与Zmila和Dnolen的解决方案有根本不同的东西（但仍然合理的表现），以添加到以后的该线程的那一部分中。 （我想不太可能。）

Answer 3

原始答案：

(defn conj-if-sequential
  ([] [])
  ([a] a)
  ([a b] (let [a (if (vector? a) a [a])]
           (if (= (inc (last a)) b)
             (conj a b)
             a))))

(reduce conj-if-sequential [2 3 4 6 8 1])

对感兴趣的人来说是一个更通用的解决方案：

(defn sequential-seqs
  ([] [])
  ([a] a)
  ([a b] (let [n (last (last a))]
           (if (and n (= (inc n) b))
             (update-in a [(dec (count a))] conj b)
             (conj a [b])))))

(defn largest
  ([] nil)
  ([a] a)
  ([a b] (if (> (count b) (count a)) b a)))

(reduce largest (reduce sequential-seqs [] [2 3 4 6 8 1 4 5 6 7 8 9 13]))

我认为这要好得多。

Answer 4

(defn find-max-seq [lst]
  (let [[f & r] lst, 
        longest-seq (fn [a b] (if (> (count a) (count b)) a b)),
        [last-seq max-seq] (reduce 
                             (fn [ [[prev-num & _ :as cur-seq] max-seq] cur-num ]
                               (if (== (inc prev-num) cur-num) 
                                 [(conj cur-seq cur-num) max-seq]
                                 [(list cur-num) (longest-seq cur-seq max-seq)]
                                 ))
                             [(list f) ()]
                             r)]
    (reverse (longest-seq last-seq max-seq))))

(find-max-seq '(2 3 4 6 8 1))  ; ==> (2 3 4) 
(find-max-seq '(3 2 3 4 6 8 9 10 11)) ; ==> (8 9 10 11)