Clojure: нахождение последовательных предметов из последовательности

Question

В программе Clojure у меня есть последовательность чисел:

(2 3 4 6 8 1)

Я хочу найти самую длинную подсигенцию, где элементы являются последовательными:

(2 3 4)

Я предполагаю, что это будет включать (take-while ...) или (reduce ...).

Есть идеи?

Разъяснение: Мне нужен самый длинный начальный список последовательных предметов. Я уверен, что я уверен. Спасибо за решения более сложной проблемы, я изначально поставил.

Answer 1

Если вы заинтересованы только в самой длинной первоначальной последовательности, это 1-лайнер:

(defn longest-initial-sequence [[x :as s]]
  (take-while identity (map #(#{%1} %2) s (iterate inc x))))

Answer 2

Учитывая комментарий OP на вопрос - который полностью меняет игру! - Это может быть написано очень просто:

(let [doubletons (partition 2 1 [1 2 3 5 6])
      increment? (fn increment? [[x y]]
                   (== (inc x) y))]
  (cons (ffirst doubletons)
        (map second (take-while increment? doubletons))))

;; returns (1 2 3)

Обратите внимание, что это на самом деле ленивый. Я ожидаю, что это не держаться за голову doubletons благодаря очистке местных жителей. Еще одна версия:

(cons (first [1 2 3 5 6])
      (map second (take-while increment? (partition 2 1 [1 2 3 5 6]))))

Оригинальная версия вопроса больше веселья, хотя! :-) суперпространное решение для того, чтобы можно было бы построить с помощью вышеперечисленного, но, конечно, это было бы значительно меньшее исполнение, чем использование reduce. Отказ Я посмотрю, что у меня есть что-то существенно отличное от решений Zmila и Dnolen - и все же еще разумно исполнительно - добавить к этой части этой темы позже. (Не очень скорее всего, я думаю.)

Answer 3

Ответ на оригинал:

(defn conj-if-sequential
  ([] [])
  ([a] a)
  ([a b] (let [a (if (vector? a) a [a])]
           (if (= (inc (last a)) b)
             (conj a b)
             a))))

(reduce conj-if-sequential [2 3 4 6 8 1])

Более общее решение для тех, кто заинтересован:

(defn sequential-seqs
  ([] [])
  ([a] a)
  ([a b] (let [n (last (last a))]
           (if (and n (= (inc n) b))
             (update-in a [(dec (count a))] conj b)
             (conj a [b])))))

(defn largest
  ([] nil)
  ([a] a)
  ([a b] (if (> (count b) (count a)) b a)))

(reduce largest (reduce sequential-seqs [] [2 3 4 6 8 1 4 5 6 7 8 9 13]))

Я думаю, что это намного лучше.

Answer 4

(defn find-max-seq [lst]
  (let [[f & r] lst, 
        longest-seq (fn [a b] (if (> (count a) (count b)) a b)),
        [last-seq max-seq] (reduce 
                             (fn [ [[prev-num & _ :as cur-seq] max-seq] cur-num ]
                               (if (== (inc prev-num) cur-num) 
                                 [(conj cur-seq cur-num) max-seq]
                                 [(list cur-num) (longest-seq cur-seq max-seq)]
                                 ))
                             [(list f) ()]
                             r)]
    (reverse (longest-seq last-seq max-seq))))

(find-max-seq '(2 3 4 6 8 1))  ; ==> (2 3 4) 
(find-max-seq '(3 2 3 4 6 8 9 10 11)) ; ==> (8 9 10 11)