Clojure: trovare elementi sequenziali da una sequenza

Question

In un programma Clojure, ho una sequenza di numeri:

(2 3 4 6 8 1)

Voglio trovare la più lunga sotto-sequenza in cui gli elementi sono sequenziali:

(2 3 4)

Io parto dal presupposto che coinvolgerà (take-while ...) o (reduce ...).

Tutte le idee?

Chiarimento : Ho bisogno la più lunga lista iniziale di elementi sequenziali. Molto più facile, ne sono sicuro. Grazie per le soluzioni al problema più difficile inizialmente ho posto.

Answer 1

Se si è interessati solo nella sequenza iniziale più lunga, è un 1-liner:

(defn longest-initial-sequence [[x :as s]]
  (take-while identity (map #(#{%1} %2) s (iterate inc x))))

Answer 2

Tenendo conto commento del PO sulla questione - che cambia completamente il gioco! - questo può essere scritto in modo molto semplice:

(let [doubletons (partition 2 1 [1 2 3 5 6])
      increment? (fn increment? [[x y]]
                   (== (inc x) y))]
  (cons (ffirst doubletons)
        (map second (take-while increment? doubletons))))

;; returns (1 2 3)

Si noti che questo è in realtà pigro. Mi aspetto che non tenere sulla testa del doubletons grazie alla gente del posto di compensazione. Un'altra versione:

(cons (first [1 2 3 5 6])
      (map second (take-while increment? (partition 2 1 [1 2 3 5 6]))))

La versione originale della questione è più divertente, però! :-) Un super-semplice soluzione a questo potrebbe essere costruito utilizzando il sopra, ma, naturalmente, che sarebbe molto meno performante rispetto all'utilizzo reduce. Vado a vedere se ho qualcosa sostanzialmente differente dalle soluzioni di dnolen zmila di e - eppure ancora abbastanza performante - da aggiungere a quella parte di questa discussione in seguito. (Non molto probabile, credo.)

Answer 3

Risposta al originale:

(defn conj-if-sequential
  ([] [])
  ([a] a)
  ([a b] (let [a (if (vector? a) a [a])]
           (if (= (inc (last a)) b)
             (conj a b)
             a))))

(reduce conj-if-sequential [2 3 4 6 8 1])

Una soluzione più generica per coloro che sono interessati:

(defn sequential-seqs
  ([] [])
  ([a] a)
  ([a b] (let [n (last (last a))]
           (if (and n (= (inc n) b))
             (update-in a [(dec (count a))] conj b)
             (conj a [b])))))

(defn largest
  ([] nil)
  ([a] a)
  ([a b] (if (> (count b) (count a)) b a)))

(reduce largest (reduce sequential-seqs [] [2 3 4 6 8 1 4 5 6 7 8 9 13]))

Credo che questo è molto meglio.

Answer 4

(defn find-max-seq [lst]
  (let [[f & r] lst, 
        longest-seq (fn [a b] (if (> (count a) (count b)) a b)),
        [last-seq max-seq] (reduce 
                             (fn [ [[prev-num & _ :as cur-seq] max-seq] cur-num ]
                               (if (== (inc prev-num) cur-num) 
                                 [(conj cur-seq cur-num) max-seq]
                                 [(list cur-num) (longest-seq cur-seq max-seq)]
                                 ))
                             [(list f) ()]
                             r)]
    (reverse (longest-seq last-seq max-seq))))

(find-max-seq '(2 3 4 6 8 1))  ; ==> (2 3 4) 
(find-max-seq '(3 2 3 4 6 8 9 10 11)) ; ==> (8 9 10 11)